并查集基础练习

1．团伙(group.pas/c/cpp)

AYYZOJ p1948

题目分析：

题目大意是有n个人求最多可能有几个团伙，由题意很容易想到用并查集解决。我们可以先假设每个人都不认识，在这一前提下可以保证团伙最多。在处理朋友的时候，把所有是朋友的人加入同一团伙；处理两人是敌人的时候，需要事先记录下每个人的敌人，然后依次把敌人的敌人加入同一团伙。最后统计有多少个团伙即可。

var d:array[0..1000,0..1000] of longint;  //d[i][j]存储第i个人的第j个敌人
    f:array[0..1000] of longint;
    i,j,m,n,x,y,k,fx,fy,ans:longint;
function get_father(x:longint):longint;
begin
 if f[x]=0 then
  begin
   get_father:=x;
  end      else
  begin
   get_father:=get_father(f[x]);
   f[x]:=get_father;
  end;
end;

begin
fillchar(f,sizeof(f),0);
  fillchar(d,sizeof(d),0);
 readln(n,m);
 for i:=1 to m do
  begin
   readln(k,x,y);
   fx:=get_father(x); fy:=get_father(y);
   if k=0 then                            //如果x,y是朋友则合并。
    begin
     if fx<>fy then f[y]:=fx;
    end;
   if k=1 then
    begin
     inc(d[x,0]); d[x,d[x,0]]:=y;            //d[x,0]记录x的敌人数
     inc(d[y,0]); d[y,d[y,0]]:=x;            //d[y,0]记录y的敌人数
//如果x，y是敌人，则把x并入y的所有敌人中，y并入x的敌人中
     for j:=1 to d[y,0] do
      if fx<>get_father(d[y,j]) then f[d[y,j]]:=fx;        
     for j:=1 to d[x,0] do
      if fy<>get_father(d[x,j]) then f[d[x,j]]:=fy;
    end;
  end;
ans:=0;
 for i:=1 to n do
  if f[i]=0 then inc(ans);            //如果自己就是树的根表明是一个集合
writeln(ans);
end.

var
 a:array[1..1000,0..1000]of longint;
 i,j,k,n,m,t,s:longint;
 fa:array[1..1000]of longint;
function getfa(x:longint):longint;
begin
 if fa[x]=0 then getfa:=x
            else
             begin
              fa[x]:=getfa(fa[x]);
              getfa:=fa[x];
             end;
end;
procedure union(x,y:longint);
var i,j:longint;
begin
 i:=getfa(x);
 j:=getfa(y);
 if i<>j then fa[i]:=j;
end;
begin
 readln(n,m);
 for i:=1 to m do
 begin
  readln(j,k,t);
  if j=0 then union(k,t)
          else begin
                inc(a[k,0]);
                a[k,a[k,0]]:=t;
                inc(a[t,0]);
                a[t,a[t,0]]:=k;
               end;
 end;
 for i:=1 to n do
  for j:=1 to a[i,0] do
   union(a[i,1],a[i,j]);
 for i:=1 to n do
  if getfa(i)=i then inc(s);
  writeln(s);
end.

我比较倾向于参考程序2,程序1有点不理解。

2．打击犯罪(black.pas/c/cpp)

AYYZOJ p1949

分析：

因为打击犯罪的顺序为由前到后依次打击，很容易想到可以倒序合并(为什么我想不到，太弱了。。)，一旦某一团伙的危险程度>n/2，停止输出即可。

至于团伙的危险等级的确认，可以新建一个count数组，在合并时累加即可。

下面分析为转载：来源

此题首先要理解题意，题意意思是按顺序删点，如果删掉k点后，1~k-1的点也被删掉这样就好解决了，那怎么和并查集联系起来呢？我们可以这样理解，我从1开始删点如当前删了点k这对大于k的点进行并查集，并得时候更新根节点的节点数，如果最大的节点数大于(n+1)/2则继续删点，直到最大集合节点数小于等于(n+1)/2为止，但这样做每删一个点，并查集就得重新计算一次，那我们换一个思路，我们倒过来，我们不删点，我们求删点完后剩下的图组成的集合，我假设删点删到了k那剩下的图就是由k~n之间的的点组成如果他们组成的结合最大子图节点数不大(n+1)/2则说明k不该删，则继续往前推。

var
  i,j,k,l,m,n:longint;
  f,c:array[1..1000] of longint;      //count数组
  g:array[1..1000] of boolean;
  a:array[0..1000,0..1000] of longint;
function getfa(x:longint):longint;
begin
  if f[x]=0 then exit(x);
  f[x]:=getfa(f[x]);
  getfa:=f[x];
end;
procedure together(x,y:longint);
var i,j:longint;
begin
  i:=getfa(x);
  j:=getfa(y);
  if i<>j then
  begin
    f[i]:=j;
    c[j]:=c[i]+c[j];
    c[i]:=0;
  end;
end;
begin
  readln(n);
  for i:=1 to n do c[i]:=1;
  for i:=1 to n do
   begin
     read(a[i,0]);
     for j:=1 to a[i,0] do read(a[i,j]);
   end;
  for i:=n downto 1 do
   begin
     for j:=1 to a[i,0] do
      if a[i,j]>i then
       together(i,a[i,j]);
     l:=0;
     for j:=1 to n do if c[j]>n div 2 then l:=1;
     if l=1 then
      begin
        writeln(i);
        break;
      end;
   end;
end.