[UnityShader]说厌了的遮挡显示

首先是效果

这个其实有相当多的地方在说了,我就不嚼舌根了

大概原理:一个Shader两个Pass,第一个Pass不管深度,都渲染,但是不写入深度,第二个Pass几乎没有改动,因为后执行,会覆盖掉第一个Pass本就该渲染的地方(因为第一个Pass没有写入深度),而第一个Pass不该渲染的地方则不会做处理,因为此Pass的深度测试未通过

结合上面那张图来说就是第一个Pass不管模型有没有被绿色遮挡都渲染成全白,因为深度测试都通过,而第二个Pass会进行正常的深度测试,绿色部分是不会通过的,但是被绿色部分遮住以外的部分会通过,那么就覆盖了第一个pass的白色

ps:第二个Pass可以用unity内置的shader替代

// Upgrade NOTE: replaced '_World2Object' with 'unity_WorldToObject'

// Upgrade NOTE: replaced 'mul(UNITY_MATRIX_MVP,*)' with 'UnityObjectToClipPos(*)'

Shader "Custom/RoleMaskShader"
{
    Properties
    {
        _MainTex ("Texture", 2D) = "white" {}
        _MainColor("MainColor", COLOR) = (1,1,1,1)
        _ShadowColor("Color", COLOR) = (1,1,1,1)
        _DiffuseScale("DiffuseScale", float) = 0.5
    }
    SubShader
    {
        //Tags { "RenderType"="Opaque" }
        //LOD 100

        Pass//第一个pass
        {
            Tags{"RenderType" = "Transparent" "Queue" = "Transparent"}
            ZWrite off//关掉深度写入
            ZTest greater//深度大于的通过,这里直接关掉也行
            Blend SrcAlpha OneMinusSrcAlpha//混合,必须要开
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCg.cginc"

            v2f_img vert(appdata_base a2v)
            {
                v2f_img o;
                o.pos = UnityObjectToClipPos(a2v.vertex);
                o.uv = a2v.texcoord;
                return o;
            }
            fixed4 _ShadowColor;
            fixed4 frag(v2f_img i) : SV_TARGET0
            {
                return _ShadowColor;//被挡住可以做描边等等
            }

            ENDCG
        }
        Pass//第二个pass,随意,这里写的是一个halfLambert
        {
            Tags{"RenderType" = "Transparent" "Queue" = "Transparent"}
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCg.cginc"
            #include "Lighting.cginc"

            struct v2f
            {
                float4 pos : POSITION;
                fixed2 uv : TEXCOORD0;
                float3 normal : TEXCOORD1;
            };

            v2f vert(appdata_base a2v)
            {
                v2f o;
                o.pos = UnityObjectToClipPos(a2v.vertex);
                o.uv = a2v.texcoord;
                o.normal = mul(a2v.normal, (float3x3)unity_WorldToObject).xyz;
                return o;
            }
            fixed4 _MainColor;
            sampler2D _MainTex;
            float _DiffuseScale;
            fixed4 frag(v2f i) : SV_TARGET0
            {
                fixed4 texColor = tex2D(_MainTex, i.uv);
                float halfLambert = saturate(dot(normalize(i.normal), normalize(_WorldSpaceLightPos0.xyz))) * _DiffuseScale + (1 - _DiffuseScale);
                fixed3 diffuseColor = _LightColor0.rgb * texColor.rgb * halfLambert * _MainColor;
                return fixed4(diffuseColor, 1);
            }

            ENDCG
        }
    }

    FallBack "VertexLit"//影子,和unity渲染阴影机制有关,shadowCaster

}

over~废话结束