POJ 2299

POJ 2299 Ultra-QuickSort

(开头愤怒一句：你妹的下次记得估值范围啊，int64啊！！！)

题目大意：给出一个序列，问用冒泡排序要交换多少次才能使之变成升序?

解法：首先分析题目性质，将之转化为求一个数左侧有多少个数小于它，亦转化为一个逆序对的问题。

因为本题n最大去到50w，所以n^2是万万不能的，所以这里用到一个树状数组求逆序对的问题（也可以用归并排序的做法做）。

而这里有一个重点：离散化，注意将值一样大的数视为一样大。然后快排，同时记录他的初始位置，然后用数据a（下标同初始位置）记录大小。

树状数组做法：从最后一个开始，up(a[i], 1);然后ans := ans + getsum(a[i]-1){sum(1, a[i]-1)}因为是从后往前推，所以我只要知道右侧有多少个小于a[i]的数已出现便可直接找到。

{a[i]表示有多少个是小于I 的，跟线段覆盖有点像？}

const
        maxn=500000;
var
        ans, n: longint;
        tree, a, d, p: array[1..maxn+10]of longint;
procedure qsort(b, e: longint);
var
        i, j, k, x: longint;
begin
  i := b;
  j := e;
  x := d[(i+j)shr 1];
  repeat
    while d[i]<x do inc(i);
    while d[j]>x do dec(j);
    if i<=j then
      begin
        k := p[i];
        p[i] := p[j];
        p[j] := k;
        k := d[i];
        d[i] := d[j];
        d[j] := k;
        inc(i);
        dec(j);
      end;
  until i>j;
  if j>b then qsort(b, j);
  if i<e then qsort(i, e);
end;

function lowbit(x: longint): longint;
begin
  exit(x and (-x));
end;

procedure up(x, s: longint);
begin
  while x<=n do
    begin
      tree[x] := tree[x] + s;
      x := x + lowbit(x);
    end;
end;

function getsum(x: longint): longint;
begin
  getsum := 0;
  while x>=1 do
    begin
      getsum := getsum + tree[x];
      x := x - lowbit(x);
    end;
end;

procedure main;
var
        i, now: longint;
begin
  readln(n);
  while n<>0 do
    begin
      for i := 1 to n do
        begin
          readln(d[i]);
          p[i] := i;
        end;
      qsort(1, n);
      for i := 1 to n do
        a[p[i]] := i;
      fillchar(tree, sizeof(tree), 0);
      ans := 0;
      now := 0;
      for i := 1 to n do
        begin
          if (i=1)or(d[i]<>d[i-1]) then inc(now);
          a[p[i]] := now;
        end;
      for i := n downto 1 do
        begin
          up(a[i], 1);
          ans := ans + getsum(a[i]-1);
        end;
      writeln(ans);
      readln(n);

    end;
end;

begin
  assign(input,'test.in'); reset(input);
  assign(output,'test.out'); rewrite(output);

  main;

  close(input); close(output);
end.