POJ 1062

POJ1062

题目大意：求从0到1的最短路。

解：将题意拆解见图的推理不难，故在此省略。卡住我的主要是等级问题，我也读不是很懂，最后上网搜题解才发现自己原来的判断有问题，并不是距离酋长为m的 一个2m区间，而直接是一个包含酋长的区间m（竟然有比酋长还高级的人）所以枚举区间直接ac，for a[1]-k to a[1] if   i<=pow[x]<=i+k;

const
        maxn=100;
        bilibili=maxlongint >> 1;
type
        data=record
          dest, cost, next: longint;
        end;
var
        edge: array[1..(maxn+1)*(maxn+1)]of data;
        vect, dist, pow: array[0..maxn]of longint;
        i, ans, m, n, tot: longint;
procedure add(x, y, z: longint);
begin
  inc(tot);
  with edge[tot] do
    begin
      dest := y;
      cost := z;
      next := vect[x];
      vect[x] := tot;
    end;
end;

procedure init;
var
        i, j, x, y, z, tmp: longint;
begin
  ans := maxlongint;
  tot := 0;
  fillchar(vect, sizeof(vect), 0);
  fillchar(pow, sizeof(pow), 0);
  pow[0] := maxlongint;
  readln(m, n);
  for i := 1 to n do
    begin
      readln(x, y, tmp);
      add(0, i, x);
      pow[i] := y;
      for j := 1 to tmp do
        begin
          readln(x, y);
          add(x, i, y);
        end;
    end;
end;

procedure spfa(b, e, key: longint);
var
        q: array[1..maxn+10]of longint;
        visit: array[0..maxn]of boolean;
        head, tail, i, u: longint;
begin
  fillchar(visit, sizeof(visit), 0);
  filldword(dist, sizeof(dist)>>2, bilibili);
  dist[b] := 0;
  head := 0;
  tail := 1;
  q[1] := b;
  visit[b] := true;
  while head<>tail do
    begin
      head := head mod (maxn+10)+1;
      u := q[head];
      i := vect[u];
      while i<>0 do
        with edge[i] do
          begin
            if ((pow[dest]>=key)and(pow[dest]<=key+m)) then
              begin
                if dist[u] + cost < dist[dest] then
                  begin
                    dist[dest] := dist[u] + cost;
                    if not visit[dest] then
                      begin
                        visit[dest] := true;
                        tail := tail mod (maxn+10) +1;
                        q[tail] := dest;
                      end;
                  end;
              end;
            i := next;
          end;
      visit[u] := false;
    end;
  if dist[1]<ans then ans := dist[1];
end;

procedure print;
begin
  writeln(ans);
end;

begin
  assign(input,'aaa.in'); reset(input);
  init;
  for i := pow[1]-m to pow[1] do spfa(0, 1, i);
  print;
end.