POJ 3264

POJ： 3264

题目大意：给出n个数，给出一个区间[x,y]，求这个区间的最大最小值。

解：可以用rmq的st算法，有空去切一下，这里用了线段树，入门，练习了构树和查询，不过自己对于左右端点的掌握还是需要犹豫。

看到别人写了一个树状数组的写法，挺神的，有空写下，刷刷排名。研究了一下，对于修改删除的题不适用，改过则必须重新初始化。或者自己写一个链表？可能可以对付删除情况？

//poj 3264
const
        maxn=51111;
        inf='1.txt';
type
        data=record
          l, r, st, ed, mid, max, min: longint;
        end;
var
        tree: array[1..maxn*4]of data;
        a: array[1..maxn]of longint;
        ansmax, ansmin, n, q: longint;
procedure build(s, e, k: longint);
begin
  with tree[k] do begin
    min := maxlongint; max := 0;
    st := s; ed := e;
    mid := (s+e)>>1;
    if s=e then begin
      max := a[s]; min := a[s];
      exit;
    end;
      l := k<<1; build(st, mid, l);
      if min>tree[l].min then min := tree[l].min;
      if max<tree[l].max then max := tree[l].max;
      r := k<<1 + 1; build(mid+1, ed, r);
      if min>tree[r].min then min := tree[r].min;
      if max<tree[r].max then max := tree[r].max;
  end;
end;

function askmin(s, e, k: longint): longint;
var
        tmp: longint;
begin
  askmin := maxlongint; tmp := maxlongint;
  with tree[k] do begin
    if (s<=st)and(ed<=e) then exit(tree[k].min);
    if s<=mid then askmin := askmin(s, e, l);
    if e>mid then tmp := askmin(s, e, r);
    if tmp<askmin then askmin := tmp;
  end;
end;

function askmax(s, e, k: longint): longint;
var
        tmp: longint;
begin
  askmax := 0; tmp := 0;
  with tree[k] do begin
    if (s<=st)and(ed<=e) then exit(tree[k].max);
    if s<=mid then askmax := askmax(s, e, l);
    if e>mid then tmp := askmax(s, e, r);
    if tmp>askmax then askmax := tmp;
  end;
end;

procedure init;
var
        i: longint;
begin
  readln(n, q);
  for i := 1 to n do readln(a[i]);
  build(1, n, 1);
end;

procedure main;
var
        i, x, y: longint;
begin
  for i := 1 to q do begin
    readln(x, y);
    writeln(askmax(x, y, 1)-askmin(x, y, 1));
  end;
end;

begin
//  assign(input,inf); reset(input);
  init;
  main;
end.