[CODEVS1258]关路灯

 题目描述 Description

多瑞卡得到了一份有趣而高薪的工作。每天早晨他必须关掉他所在村庄的街灯。所有的街灯都被设置在一条直路的同一侧。

多瑞卡每晚到早晨5点钟都在晚会上，然后他开始关灯。开始时，他站在某一盏路灯的旁边。

每盏灯都有一个给定功率的电灯泡，因为多端卡有着自觉的节能意识，他希望在耗能总数最少的情况下将所有的灯关掉。

多端卡因为太累了，所以只能以1m/s的速度行走。关灯不需要花费额外的时间，因为当他通过时就能将灯关掉。

编写程序，计算在给定路灯设置，灯泡功率以及多端卡的起始位置的情况下关掉所有的灯需耗费的最小能量。

输入描述 Input Description

输入文件的第一行包含一个整数N，2≤N≤1000，表示该村庄路灯的数量。

第二行包含一个整数V，1≤V≤N，表示多瑞卡开始关灯的路灯号码。

接下来的N行中，每行包含两个用空格隔开的整数D和W，用来描述每盏灯的参数，其中0≤D≤1000，0≤W≤1000。D表示该路灯与村庄开始处的距离(用米为单位来表示)，W表示灯泡的功率，即在每秒种该灯泡所消耗的能量数。路灯是按顺序给定的。

输出描述 Output Description

输出文件的第一行即唯一的一行应包含一个整数，即消耗能量之和的最小值。注意结果小超过1,000,000,000。

样例输入 Sample Input

4

3

2 2

5 8

6 1

8 7

样例输出 Sample Output

56

思路

对于小数据来说，爆搜可以过，n<=50，然而对于大的数据，当n<=1000时，只能过7个点。

设f[i,j,k](k=1或2)表示已经关过的MM区间为[i,j]，k=1表示当前在左端点i位置，k=2表示当前在右端点j位置。

   f[i,j,0]=min{ f[i+1,j,1] + (w[i] + (w[n] - w[j]))*(d[i+1] - d[i]),

 　    　　　　  f[i+1,j,2] + (w[i]+ (w[n] - w[j]))*(d[i+1] - d[i]) }

 　f[i,j,2]=min{ f[i,j-1,1] + (w[i-1] + (w[n] - w[j-1]))*(d[j] - d[i]),

　   　　　　　　f[i,j-1,2] + (w[i-1] + (w[n] - w[j-1]))*(d[j] - d[j-1]) }

　初始状态：f[s,s,1]=s[s,s,2]=0

　目标状态：min{ f[1,n,1] , f[1,n,2] }

　时间复杂度：O(n^2)

DFS

var
  n,c,ans,total:longint;
  dis,w:array[0..60]of longint;
  f:array[0..60]of boolean;

procedure init;
begin
  assign(input,'power.in');
  assign(output,'power.out');
  reset(input);
  rewrite(output);
end;

procedure terminate;
begin
  close(input); close(output);
  halt;
end;

procedure dfs(t,tot,total,t1:longint);
var
  i:longint;
begin
  for i:=t-1 downto 1 do
    if f[i] then
      begin
        if tot+(dis[t]-dis[i])*(total-w[t])<ans then
          begin
            f[i]:=false;
            dfs(i,tot+(dis[t]-dis[i])*(total-w[t]),total-w[t],t1+1);
            f[i]:=true;
            break;
          end;
      end;
  for i:=t+1 to n do
    if f[i] then
      begin
        if tot+(dis[i]-dis[t])*(total-w[t])<ans then
          begin
            f[i]:=false;
            dfs(i,tot+(dis[i]-dis[t])*(total-w[t]),total-w[t],t1+1);
            f[i]:=true;
            break;
          end;
      end;
  if t1=n then
    if tot<ans then
      begin
        ans:=tot;
        exit;
      end;
end;

procedure main;
var
  i:longint;
begin
  readln(n,c);
  total:=0;
  for i:=1 to n do
    begin
      readln(dis[i],w[i]);
      f[i]:=true;
      total:=total+w[i];
    end;
  ans:=maxlongint;
  f[c]:=false;
  dfs(c,0,total,1);
  writeln(ans);
end;

begin
  init;
  main;
  terminate;
end.

DP

program CloseTheLight;
uses math;
var n,c,i,p,j,k,v1,a:longint;
    v,s:array[0..1000] of longint;
    f:array[0..1000,0..1000,0..1] of longint;
begin
    read(n,c);
    for i:=1 to n do
    begin
        read(v[i],a);
        s[i]:=s[i-1]+a;
    end;
    filldword(f,sizeof(f) div 4,maxlongint);
    f[c,c,1]:=0;
    f[c,c,0]:=0;
    for p:=0 to n-1 do
        for i:=1 to n-p do
        begin
            j:=i+p;
            for k:=0 to 1 do
            begin
                if k=0 then v1:=i else v1:=j;
                if f[i,j,k]<maxlongint then
                begin
                    if i>0 then f[i-1,j,0]:=min(f[i-1,j,0],
                                            f[i,j,k]+(s[i-1]+s[n]-s[j])*(v[v1]-v[i-1]));
                    if j<n then f[i,j+1,1]:=min(f[i,j+1,1],
                                            f[i,j,k]+(s[i-1]+s[n]-s[j])*(v[j+1]-v[v1]));
                end;
            end;
        end;
    writeln(min(f[1,n,0],f[1,n,1]));
end.