[codevs2152]滑雪

题目来源

http://www.tyvj.cn/p/1004

http://www.luogu.org/problem/show?pid=1434#

http://codevs.cn/problem/2152/

题目描述

Michael喜欢滑雪。这并不奇怪，因为滑雪的确很刺激。可是为了获得速度，滑的区域必须向下倾斜，而且当你滑到坡底，你不得不再次走上坡或者等待升降机来载你。Michael想知道在一个区域中最长的滑坡。区域由一个二维数组给出。数组的每个数字代表点的高度。下面是一个例子：
1   2   3   4   5
16  17  18  19   6
15  24  25  20   7
14  23  22  21   8
13  12  11  10   9
一个人可以从某个点滑向上下左右相邻四个点之一，当且仅当高度减小。在上面的例子中，一条可行的滑坡为24－17－16－1（从24开始，在1结束）。当然25－24－23―┅―3―2―1更长。事实上，这是最长的一条。

输入输出格式

输入格式：

输入的第一行为表示区域的二维数组的行数R和列数C（1≤R，C≤100）。下面是R行，每行有C个数，代表高度(两个数字之间用1个空格间隔)。

输出格式：

输出区域中最长滑坡的长度。

输入输出样例

输入样例#1：

5 5
1 2 3 4 5
16 17 18 19 6
15 24 25 20 7
14 23 22 21 8
13 12 11 10 9

输出样例#1：

25       

分析

　　　　 记忆化搜索。算法分析：由于一个人可以从某个点滑向上下左右向相邻的四个点之一，如上所示。而且仅当高度减小，对于任意一点[i,j]，当他的高度小于与之相邻的四个点的高度时，这四个点可以滑向[i,j]，用f[i,j]表示到[i,j]为止的最大的长度,f[i,j]=max{f(i+a,j+b)}+1,其坐标增量{(a,b)=[(1,0),(-1,0),(0,1),(0,-1)],0<i+a<=r,0<j+b<=c,high[i,j]<high[i+a,j+b]}。
        为了保证满足条件的f[i+a,j+b]在f[i,j]前算出，需要对高度排一次序，然后从大到小规划（高度）。最后再比较一下所有f[i,j]{0<i<=r,0<j<=c}，找出其中最长的一条路线。我们还可以用记忆化搜索的方法，他的有点事不需要进行排序，按照行的顺序，利用递归逐点求出区域中到达此点的最长路径，每个点的最长路径只求一次。

const dx:array[1..4] of longint=(-1,0,1,0);
    dy:array[1..4] of longint=(0,1,0,-1);

var m,f:array[1..100,1..100] of longint;
    r,c,i,j,p,t,ans:longint;

function search(x,y:longint):longint;
var i,t,tmp,nx,ny:longint;
begin
    if f[x,y]>0 then
        begin
            search:=f[x,y];
            exit;
        end;
    t:=1;
    for i:=1 to 4 do
        begin
            nx:=x+dx[i];
            ny:=y+dy[i];
            if (nx>=1)and(nx<=r)and(ny>=1)and(ny<=c)and(m[x,y]<m[nx,ny]) then
                begin
                    tmp:=search(nx,ny)+1;
                    if tmp>t then t:=tmp;
                end;
        end;
    f[x,y]:=t;
    search:=t;
end;
begin
    readln(r,c);
    ans:=0;
    for i:=1 to r do
        for j:=1 to c do
            read(m[i,j]);
    for i:=1 to r do
        for j:=1 to c do
            begin
                t:=search(i,j);
                f[i,j]:=t;
                if t>ans then ans:=t;
            end;
    writeln(ans);
end.