常用oracle可重复执行的脚本模板

为保证脚本的可重复执行以及丢失,涉及到数据库环境的移植等,就会使用可重复执行脚本,此处仅提供相关一些模板

说明下:该脚本需要在命令窗口执行,而不是在SQL窗口执行

创建序的脚本

/**
 *  作者：zkongbai
 *  时间：11-30 09:22:10
 *  描述：创建序列【SEQ_ZZ_DOUBLE_RANDOM_TASK】
 *  脚本可重复执行
 */
PROMPT SEQ_ZZ_DOUBLE_RANDOM_TASK  双随机事件脚本 创建序列
DECLARE
    FLAG_NUM NUMBER;
BEGIN
    SELECT COUNT(*) INTO FLAG_NUM
    FROM USER_SEQUENCES ASQ
    WHERE ASQ.SEQUENCE_NAME = UPPER('SEQ_ZZ_DOUBLE_RANDOM_TASK');
    IF FLAG_NUM = 0 THEN 
        EXECUTE IMMEDIATE 'CREATE SEQUENCE SEQ_ZZ_DOUBLE_RANDOM_TASK MINVALUE 1 MAXVALUE 999999999 START WITH 1 INCREMENT BY 1 CACHE 20'; 
    END IF;
END;
/
COMMIT;

创建表的脚本

/**
 *  作者：zkongbai
 *  时间：11-21 09:22:10
 *  描述：创建表【双随机任务,序:SEQ_ZZ_DOUBLE_RANDOM_TASK】
 *  脚本可重复执行
 */
PROMPT T_ZZ_DOUBLE_RANDOM_TASK 创建表
DECLARE
    FLAG_NUM NUMBER;
BEGIN
    SELECT COUNT(*) INTO FLAG_NUM
    FROM USER_TABLES ATS
    WHERE ATS.TABLE_NAME = UPPER('T_ZZ_DOUBLE_RANDOM_TASK');
    IF FLAG_NUM = 0 THEN
        EXECUTE IMMEDIATE 'CREATE TABLE T_ZZ_DOUBLE_RANDOM_TASK
            (
                ID              NUMBER(8) not null,
                EVENT_ID        NUMBER(8),
                JUDGE_COMMENT   VARCHAR2(500),
                JUDGE_RESULE    CHAR(1),
                JUDGE_PERSON    NUMBER(8),
                CREATE_TIME     DATE,
                STATUS          CHAR(1),
                UPDATE_TIME     DATE,
                CREATE_USER_ID  NUMBER(8),
                CREATE_ORG_CODE VARCHAR2(32),
                CONSTRAINT PK_T_ZZ_DOUBLE_RANDOM_TASK PRIMARY KEY (ID)
            )';
        -- ADD COMMENTS TO THE TABLE 
        EXECUTE IMMEDIATE 'COMMENT ON TABLE T_ZZ_DOUBLE_RANDOM_TASK IS ''双随机任务,序:SEQ_ZZ_DOUBLE_RANDOM_TASK'''; 
        -- ADD COMMENTS TO THE COLUMNS 
        EXECUTE IMMEDIATE 'COMMENT ON COLUMN T_ZZ_DOUBLE_RANDOM_TASK.EVENT_ID  IS ''事件ID''';
        EXECUTE IMMEDIATE 'COMMENT ON COLUMN T_ZZ_DOUBLE_RANDOM_TASK.JUDGE_COMMENT  IS ''评价意见''';
        EXECUTE IMMEDIATE 'COMMENT ON COLUMN T_ZZ_DOUBLE_RANDOM_TASK.JUDGE_RESULE  IS ''评价结果(1:合格,2:不合格)''';
        EXECUTE IMMEDIATE 'COMMENT ON COLUMN T_ZZ_DOUBLE_RANDOM_TASK.JUDGE_PERSON  IS ''评价人''';
        EXECUTE IMMEDIATE 'COMMENT ON COLUMN T_ZZ_DOUBLE_RANDOM_TASK.STATUS  IS ''状态.1:有效,0:无效''';
        EXECUTE IMMEDIATE 'COMMENT ON COLUMN T_ZZ_DOUBLE_RANDOM_TASK.CREATE_USER_ID  IS ''创建人''';
        EXECUTE IMMEDIATE 'COMMENT ON COLUMN T_ZZ_DOUBLE_RANDOM_TASK.CREATE_ORG_CODE  IS ''创建组织''';
    END IF;
END;
/
COMMIT;

修改字段的脚本

/**
 *  作者：zkongbai
 *  时间：2018/1/11
 *  描述：双随机任务添加字段 TASK_TYPE
 *  脚本可重复执行
 */
PROMPT T_ZZ_DOUBLE_RANDOM_TASK 双随机任务添加字段 TASK_TYPE
DECLARE
  FLAG_NUM NUMBER;
BEGIN
  SELECT COUNT(*) INTO FLAG_NUM
  FROM USER_TABLES ATS
  WHERE ATS.TABLE_NAME = UPPER('T_ZZ_DOUBLE_RANDOM_TASK');
  IF FLAG_NUM > 0 THEN
    SELECT COUNT(*) INTO FLAG_NUM FROM USER_TAB_COLUMNS T 
    WHERE T.TABLE_NAME = UPPER('T_ZZ_DOUBLE_RANDOM_TASK') AND T.COLUMN_NAME = UPPER('TASK_TYPE');
    IF FLAG_NUM=0 THEN
      EXECUTE IMMEDIATE 'ALTER TABLE T_ZZ_DOUBLE_RANDOM_TASK ADD TASK_TYPE CHAR(1)';
      -- ADD COMMENTS TO THE COLUMNS 
      EXECUTE IMMEDIATE 'COMMENT ON COLUMN T_ZZ_DOUBLE_RANDOM_TASK.TASK_TYPE  IS ''任务类型: 1或空:市级双随机任务,2:镇街级随机任务''';
    END IF;
  END IF;
END;
/
COMMIT;