[NOIP2011] 观光公交（贪心）

题目描述

风景迷人的小城Y 市，拥有n 个美丽的景点。由于慕名而来的游客越来越多，Y 市特意安排了一辆观光公交车，为游客提供更便捷的交通服务。观光公交车在第 0 分钟出现在 1号景点，随后依次前往 2、3 、4 ……n 号景点。从第 i 号景点开到第 i+1 号景点需要 Di 分钟。任意时刻，公交车只能往前开，或在景点处等待。

设共有m 个游客，每位游客需要乘车1 次从一个景点到达另一个景点，第i 位游客在Ti 分钟来到景点 Ai ，希望乘车前往景点Bi （Ai<B

i ）。为了使所有乘客都能顺利到达目的地，公交车在每站都必须等待需要从该景点出发的所有乘客都上车后才能出发开往下一景点。

假设乘客上下车不需要时间。

一个乘客的旅行时间，等于他到达目的地的时刻减去他来到出发地的时刻。因为只有一辆观光车，有时候还要停下来等其他乘客，乘客们纷纷抱怨旅行时间太长了。于是聪明的司机ZZ给公交车安装了 k 个氮气加速器，每使用一个加速器，可以使其中一个 Di 减1 。对于同一个Di 可以重复使用加速器，但是必须保证使用后Di 大于等于0 。

那么ZZ该如何安排使用加速器，才能使所有乘客的旅行时间总和最小？

输入输出格式

输入格式：

输入文件名为bus.in。

第1 行是3 个整数n, m, k ，每两个整数之间用一个空格隔开。分别表示景点数、乘客数和氮气加速器个数。

第2 行是n-1 个整数，每两个整数之间用一个空格隔开，第i 个数表示从第i 个景点开往第i+1 个景点所需要的时间，即 Di 。

第3 行至m+2 行每行3 个整数 Ti, Ai, Bi，每两个整数之间用一个空格隔开。第 i+2 行表示第i 位乘客来到出发景点的时刻，出发的景点编号和到达的景点编号。

输出格式：

输出文件名为bus.out。共一行，包含一个整数，表示最小的总旅行时间。

输入输出样例

输入样例#1：

3 3 2
1 4
0 1 3
1 1 2
5 2 3

输出样例#1：

10

说明

【输入输出样例说明】

对D2 使用2 个加速器，从2 号景点到 3 号景点时间变为 2 分钟。

公交车在第1 分钟从1 号景点出发，第2 分钟到达2 号景点，第5 分钟从2 号景点出发，第7 分钟到达 3 号景点。

第1 个旅客旅行时间 7-0 = 7 分钟。

第2 个旅客旅行时间 2-1 = 1 分钟。

第3 个旅客旅行时间 7-5 = 2 分钟。

总时间 7+1+2 = 10分钟。

【数据范围】

对于10% 的数据，k=0 ；

对于20% 的数据，k=1 ；

对于40% 的数据，2 ≤ n ≤ 50，1 ≤ m ≤ 1,000，0 ≤ k ≤ 20，0 ≤ Di ≤ 10，0 ≤ T i ≤ 500；

对于60% 的数据，1 ≤ n ≤ 100，1 ≤ m ≤ 1,000，0 ≤ k ≤ 100 ，0 ≤ Di ≤ 100，0 ≤ T i ≤ 10,000 ；

对于100%的数据，1 ≤ n ≤ 1,000，1 ≤ m ≤ 10,000 ，0 ≤ k ≤ 100,000，0 ≤ Di ≤ 100 ，0 ≤ T i ≤ 100,000。

noip2011提高组day2第3题

• NOIP2011 d2t3 贪心题。
• t[i]表示车到达某站的最晚时间，f[i]表示从某站出发的最早时间，可知f[i]已确定，f[i]=max(time[j]),start[j]=i；
• t[i]可用递推求出，即：t[i]=max(t[i-1],f[i-1])+d[i-1];
• 所以对于某种情况，每个乘客到达目的地的时间是一定的。
• 对于某一条道路，使用加速器会造成的影响的距离不同。
• 对于每个加速器，我们必须使这个加速器获得最大的效益，即使尽可能多的乘客旅行时间-1。如果我们在i到i+1间使用加速器的话，那么到i+1站的乘客的旅行时间都会减一，但是如果t[i+1]小于f[i+1]的话，车就要在i+1站等到t[i+1]所有的乘客上车，在i+1站以后下车的乘客的时间是一样的，也就是说这个加速器对后面下车的乘客没有影响。我们可以用递推求出每个i最远能影响的车站，设g[i]表示该车站能影响到的最远的车站，g[i]=i+1,(t[i+1]<=f[i+1]) g[i]=g[i+1],(t[i+1]>f[i+1])。
• 所以，每个加速器选取能影响最多人数的道路，并且维护g[i]及t[i]。
• 平均时间复杂度O(kn)，期望得分100分。

var
    n,m,k,i,j                                    :longint;
    f,g,t,d,sum                                    :array[0..100050] of longint;
    time,from,too                                :array[0..100050] of longint;    
    ans                                            :int64;
    cur,x                                        :longint;
    
function max(x,y:longint):longint;
begin
    if x>y then exit(x) else exit(y);
end;
    
begin
    read(n,m,k);
    for i:=1 to n-1 do read(d[i]);
    for i:=1 to m do
    begin
        read(time[i],from[i],too[i]);
        f[from[i]]:=max(f[from[i]],time[i]);
        inc(sum[too[i]]);
    end;
    for i:=1 to n do sum[i]:=sum[i-1]+sum[i];
    for i:=2 to n do t[i]:=max(t[i-1],f[i-1])+d[i-1];
    for i:=1 to m do ans:=ans+t[too[i]]-time[i];
    while (k>0) do
    begin
        g[n]:=n;
        g[n-1]:=n;
        for i:=n-2 downto 1 do if t[i+1]<=f[i+1] then g[i]:=i+1 else g[i]:=g[i+1];
        cur:=0;
        for i:=1 to n do
        begin
            if (cur<sum[g[i]]-sum[i]) and (d[i]>0) then 
            begin
                cur:=sum[g[i]]-sum[i];
                x:=i;
            end;
        end;
        if (cur=0) then break;
        dec(ans,cur);
        dec(d[x]);
        dec(k);
        t[1]:=0;
        for i:=2 to n do t[i]:=max(t[i-1],f[i-1])+d[i-1];
    end;
    writeln(ans);
end.