线性规划与网络流9 方格取数

算法实现题 8-9 方格取数问题（习题 8-20）
?问题描述：
在一个有 m*n 个方格的棋盘中，每个方格中有一个正整数。现要从方格中取数，使任
意 2 个数所在方格没有公共边，且取出的数的总和最大。试设计一个满足要求的取数算法。
?编程任务：
对于给定的方格棋盘，按照取数要求编程找出总和最大的数。
?数据输入：
由文件 input.txt 提供输入数据。文件第 1 行有 2 个正整数 m和 n，分别表示棋盘的行数
和列数。接下来的 m行，每行有 n 个正整数，表示棋盘方格中的数。
?结果输出:
程序运行结束时，将取数的最大总和输出到文件 output.txt 中。
输入文件示例
输出文件示例
input.txt
output.txt
3 3
1 2 3
3 2 3
2 3 1
11

题解：

最大点权独立集=总点权-最小点权覆盖集=总点权-最小割 over……

代码：

const inf=maxlongint;
type node=record
     from,go,next,v:longint;
     end;
var  tot,i,j,n,m,maxflow,l,r,s,t,x,y,sum:longint;
     h,head,q,cur:array[0..1000] of longint;
     e:array[0..50000] of node;
     num:array[0..50,0..50] of longint;
     function min(x,y:longint):longint;
      begin
      if x<y then exit(x) else exit(y);
      end;
procedure ins(x,y,z:longint);
 begin
 inc(tot);
 e[tot].from:=x;e[tot].go:=y;e[tot].v:=z;e[tot].next:=head[x];head[x]:=tot;
 end;
procedure insert(x,y,z:longint);
 begin
 if y>100000 then exit;
 ins(x,y,z);ins(y,x,0);
 end;
function bfs:boolean;
 var i,x,y:longint;
 begin
 fillchar(h,sizeof(h),0);
 l:=0;r:=1;q[1]:=s;h[s]:=1;
 while l<r do
  begin
  inc(l);
  x:=q[l];
  i:=head[x];
  while i<>0 do
   begin
   y:=e[i].go;
   if (e[i].v<>0) and (h[y]=0) then
    begin
     h[y]:=h[x]+1;
     inc(r);q[r]:=y;
    end;
   i:=e[i].next;
   end;
  end;
 exit (h[t]<>0);
 end;
function dfs(x,f:longint):longint;
 var i,y,used,tmp:longint;
 begin
 if x=t then exit(f);
 used:=0;
 i:=cur[x];
 while i<>0 do
  begin
  y:=e[i].go;
  if (h[y]=h[x]+1) and (e[i].v<>0) then
   begin
   tmp:=dfs(y,min(e[i].v,f-used));
   dec(e[i].v,tmp);if e[i].v<>0 then cur[x]:=i;
   inc(e[i xor 1].v,tmp);
   inc(used,tmp);
   if used=f then exit(f);
   end;
  i:=e[i].next;
  end;
 if used=0 then h[x]:=-1;
 exit(used);
 end;
procedure dinic;
 begin
 while bfs do
  begin
  for i:=s to t do cur[i]:=head[i];
  inc(maxflow,dfs(s,inf));
  end;
 end;
procedure init;
 begin
 tot:=1;
 readln(n,m);sum:=0;s:=0;t:=n*m+1;
 fillchar(num,sizeof(num),60);
 for i:=1 to n do for j:=1 to m do num[i,j]:=(i-1)*m+j;
 for i:=1 to n do
  begin
   for j:=1 to m do
    begin
     read(x);inc(sum,x);
     if odd(i+j) then insert(s,num[i,j],x) else insert(num[i,j],t,x);
    end;
  readln;
  end;
 end;
procedure main;
 begin
 for i:=1 to n do
  for j:=1 to m do
   if odd(i+j) then
    begin
     insert(num[i,j],num[i,j+1],inf);
     insert(num[i,j],num[i,j-1],inf);
     insert(num[i,j],num[i-1,j],inf);
     insert(num[i,j],num[i+1,j],inf);
    end;
 maxflow:=0;
 dinic;
 writeln(sum-maxflow);
 end;
begin
 assign(input,'grid.in');assign(output,'grid.out');
 reset(input);rewrite(output);
 init;
 main;
 close(input);close(output);
end.