BZOJ2124: 等差子序列

2124: 等差子序列

Time Limit: 3 Sec  Memory Limit: 259 MB
Submit: 365  Solved: 151
[Submit][Status]

Description

给一个1到N的排列{Ai}，询问是否存在1<=p1=3），使得Ap1,Ap2,Ap3,…ApLen是一个等差序列。

Input

输入的第一行包含一个整数T，表示组数。下接T组数据，每组第一行一个整数N，每组第二行为一个1到N的排列，数字两两之间用空格隔开。

Output

对于每组数据，如果存在一个等差子序列，则输出一行“Y”，否则输出一行“N”。

Sample Input

2
3
1 3 2
3
3 2 1

Sample Output

N
Y

HINT

对于100%的数据，N<=10000，T<=7

Source

题解：

这题的思路比较巧妙

从左到右扫描，维护01序列，表示到当前这个点，每个值是否出现过

当且仅当 这个点向左和向右不论扩展多长，01序列都相同时，才表示这个点不会作为等差中项（a[i]-x,a[i]+x的出现情况相同，说明都未出现或都已出现）

判断两个字符串是否相等可以用hash

然后就变成单点修改，区间查询了---线段树

代码：

{$inline on}
const base=3;p=100000007;maxn=10000+10;
type node=record
     l,r,mid,s:longint;
     v1,v2:int64
     end;
var t:array[0..6*maxn] of node;
    a:array[0..maxn] of longint;
    b:array[0..maxn] of int64;
    i,n,x,y,cs:longint;
    xx,yy:longint;
    function min(x,y:longint):longint;inline;
     begin
       if x<y then exit(x) else exit(y);
     end;

procedure build(k,x,y:longint);inline;
 begin
   with t[k] do
     begin
       l:=x;r:=y;mid:=(l+r)>>1;s:=r-l+1;v1:=0;v2:=0;
       if l=r then exit;
       build(k<<1,l,mid);
       build(k<<1+1,mid+1,r);
     end;
 end;
procedure change(k,x,y:longint);inline;
 begin
   with t[k] do
     begin
      if l=r then
       begin
         v1:=y;v2:=y;;exit;
       end;
      if x<=mid then change(k<<1,x,y)
      else change(k<<1+1,x,y);
      v1:=(t[k<<1].v1*b[t[k<<1+1].s]+t[k<<1+1].v1) mod p;
      v2:=(t[k<<1+1].v2*b[t[k<<1].s]+t[k<<1].v2) mod p;
     end;
 end;
function query1(k,x,y:longint):int64;inline;
 begin
   with t[k] do
     begin
      if (l=x) and (r=y) then exit(v1);
      if y<=mid then exit(query1(k<<1,x,y))
      else if x>mid then exit(query1(k<<1+1,x,y))
      else exit(((query1(k<<1,x,mid)*b[(y-mid)]+query1(k<<1+1,mid+1,y))) mod p);
     end;
 end;
function query2(k,x,y:longint):int64;inline;
 begin
   with t[k] do
     begin
      if (l=x) and (r=y) then exit(v2);
      if y<=mid then exit(query2(k<<1,x,y))
      else if x>mid then exit(query2(k<<1+1,x,y))
      else exit(((query2(k<<1+1,mid+1,y)*b[(mid-x+1)]+query2(k<<1,x,mid))) mod p);
     end;
 end;
procedure init;
 begin
   readln(n);
   for i:=1 to n do read(a[i]);readln;
   build(1,1,n);
 end;
function check:boolean;inline;
 begin
   if n<=2 then exit(false);
   for i:=1 to n do
    begin
      x:=a[i];
      y:=min(n-a[i],a[i]-1);
      if (a[i]<>1) and (a[i]<>n) then
        begin
          xx:=query1(1,x-y,x-1);yy:=query2(1,x+1,x+y);
          if xx<>yy then exit(true);
        end;
      change(1,a[i],1);
    end;
   exit(false);
 end;
begin
  assign(input,'input.txt');assign(output,'output.txt');
  reset(input);rewrite(output);
  readln(cs);
  b[1]:=base;
  for i:=2 to maxn do b[i]:=b[i-1]*base mod p;
  while cs>0 do
   begin
     dec(cs);
     init;
     if check then writeln('Y') else writeln('N');
   end;
  close(input);close(output);
end.
         

（吐槽：wikioi数据真心弱？在wikioi上1A，结果在bzoj上就WA了，把数据类型改了改就A了。。。）