BZOJ1036: [ZJOI2008]树的统计Count

1036: [ZJOI2008]树的统计Count

Time Limit: 10 Sec  Memory Limit: 162 MB
Submit: 4980  Solved: 2095
[Submit][Status]

Description

一棵树上有n个节点，编号分别为1到n，每个节点都有一个权值w。我们将以下面的形式来要求你对这棵树完成一些操作： I. CHANGE u t : 把结点u的权值改为t II. QMAX u v: 询问从点u到点v的路径上的节点的最大权值 III. QSUM u v: 询问从点u到点v的路径上的节点的权值和 注意：从点u到点v的路径上的节点包括u和v本身

Input

输入的第一行为一个整数n，表示节点的个数。接下来n – 1行，每行2个整数a和b，表示节点a和节点b之间有一条边相连。接下来n行，每行一个整数，第i行的整数wi表示节点i的权值。接下来1行，为一个整数q，表示操作的总数。接下来q行，每行一个操作，以“CHANGE u t”或者“QMAX u v”或者“QSUM u v”的形式给出。 对于100％的数据，保证1<=n<=30000，0<=q<=200000；中途操作中保证每个节点的权值w在-30000到30000之间。

Output

对于每个“QMAX”或者“QSUM”的操作，每行输出一个整数表示要求输出的结果。

Sample Input

4
1 2
2 3
4 1
4 2 1 3
12
QMAX 3 4
QMAX 3 3
QMAX 3 2
QMAX 2 3
QSUM 3 4
QSUM 2 1
CHANGE 1 5
QMAX 3 4
CHANGE 3 6
QMAX 3 4
QMAX 2 4
QSUM 3 4

Sample Output

4
1
2
2
10
6
5
6
5
16

 

题解：

原来抄着别人的代码稀里糊涂的过了一遍，什么也没懂。。。

好几次尝试理解树链剖分都失败了。。。

今天又看发现好水，也许是学了splay之后对数据结构又有兴趣了吧。。。

查询的时候借鉴了proverbs的方法，不求LCA，直接往上提，代码量也比较少 

http://www.cnblogs.com/proverbs/archive/2013/01/18/2867092.html

代码：

{$M 10000000,0,maxlongint}
const maxn=30000+100;
type node1=record
     go,next:longint;
     end;
     node2=record
     l,r,mid,mx,sum:longint;
     end;

var  e:array[0..2*maxn] of node1;
     t:array[0..4*maxn] of node2;
     p,a,v,fa,s,head,dep,son,top:array[0..maxn] of longint;
     i,n,m,x,y,xx,yy,sz,ans,tot:longint;
     ch:char;
     procedure swap(var x,y:longint);
      var t:longint;
      begin
        t:=x;x:=y;y:=t;
      end;
     procedure insert(x,y:longint);
      begin
        inc(tot);
        e[tot].go:=y;e[tot].next:=head[x];head[x]:=tot;
      end;
     function min(x,y:longint):longint;
      begin
        if x<y then exit(x) else exit(y);
      end;
     function max(x,y:longint):longint;
      begin
        if x>y then exit(x) else exit(y);
      end;

procedure dfs1(x:longint);
 var i,j,y:longint;
 begin
   j:=0;s[x]:=1;
   i:=head[x];
   while i<>0 do
    begin
     y:=e[i].go;
     if dep[y]=0 then
      begin
        dep[y]:=dep[x]+1;
        fa[y]:=x;
        dfs1(y);
        inc(s[x],s[y]);
        if s[y]>s[j] then j:=y;
      end;
     i:=e[i].next;
    end;
   son[x]:=j;
 end;
procedure dfs2(x,chain:longint);
 var i,y:longint;
 begin
   inc(sz);p[x]:=sz;top[x]:=chain;
   if son[x]<>0 then dfs2(son[x],chain);
   i:=head[x];
   while i<>0 do
     begin
      y:=e[i].go;
      if (p[y]=0) and (y<>son[x]) then dfs2(y,y);
      i:=e[i].next;
     end;
 end;
procedure pushup(k:longint);
 begin
    t[k].mx:=max(t[k<<1].mx,t[k<<1+1].mx);
    t[k].sum:=t[k<<1].sum+t[k<<1+1].sum;
 end;

procedure build(k,x,y:longint);
 begin
   with t[k] do
    begin
     l:=x;r:=y;mid:=(l+r)>>1;
     if l=r then begin mx:=a[l];sum:=a[l];exit;end;
     build(k<<1,l,mid);build(k<<1+1,mid+1,r);
     pushup(k);
    end;
 end;
procedure change(k,x,y:longint);
 begin
   with t[k] do
    begin
     if l=r then begin mx:=y;sum:=y;exit;end;
     if x<=mid then change(k<<1,x,y)
     else change(k<<1+1,x,y);
     pushup(k);
    end;
 end;

function getmx(k,x,y:longint):longint;
 begin
   with t[k] do
    begin
     if (l=x) and (r=y) then exit(mx);
     if y<=mid then exit(getmx(k<<1,x,y))
     else if x>mid then exit(getmx(k<<1+1,x,y))
     else exit(max(getmx(k<<1,x,mid),getmx(k<<1+1,mid+1,y)));
    end;
 end;
function getsum(k,x,y:longint):longint;
 begin
   with t[k] do
    begin
     if (l=x) and (r=y) then exit(sum);
     if y<=mid then exit(getsum(k<<1,x,y))
     else if x>mid then exit(getsum(k<<1+1,x,y))
     else exit(getsum(k<<1,x,mid)+getsum(k<<1+1,mid+1,y));
    end;
 end;

procedure init;
 begin
   readln(n);
   for i:=1 to n-1 do begin readln(x,y);insert(x,y);insert(y,x);end;
   dep[1]:=1;
   dfs1(1);
   dfs2(1,1);
   for i:=1 to n do read(v[i]);
   for i:=1 to n do a[p[i]]:=v[i];
   build(1,1,n);
 end;
procedure solvemx;
 begin
   ans:=-maxlongint;
   while ch<>' ' do read(ch);
   readln(x,y);
   while top[x]<>top[y] do
     begin
      if dep[top[x]]<dep[top[y]] then swap(x,y);
      ans:=max(ans,getmx(1,p[top[x]],p[x]));
      x:=fa[top[x]];
     end;
   if dep[x]>dep[y] then swap(x,y);
   ans:=max(ans,getmx(1,p[x],p[y]));
   writeln(ans);
 end;
procedure solvesum;
 begin
   ans:=0;
   while ch<>' ' do read(ch);
   readln(x,y);
     while top[x]<>top[y] do
     begin
      if dep[top[x]]<dep[top[y]] then swap(x,y);
      inc(ans,getsum(1,p[top[x]],p[x]));
      x:=fa[top[x]];
     end;
   if dep[x]>dep[y] then swap(x,y);
   inc(ans,getsum(1,p[x],p[y]));
   writeln(ans);
 end;

procedure main;
 begin
   readln(m);
   for i:=1 to m do
    begin
     read(ch);
     if ch='C' then
      begin
       while ch<>' ' do read(ch);readln(x,y);
       change(1,p[x],y);
      end
     else
      begin
       read(ch);
       if ch='M' then solvemx else solvesum;
       end;
    end;
 end;

begin
  assign(input,'input.txt');assign(output,'output.txt');
  reset(input);rewrite(output);
  init;
  main;
  close(input);close(output);
end.