BZOJ1877: [SDOI2009]晨跑

1877: [SDOI2009]晨跑

Time Limit: 4 Sec  Memory Limit: 64 MB
Submit: 1024  Solved: 540
[Submit][Status]

Description

Elaxia最近迷恋上了空手道，他为自己设定了一套健身计划，比如俯卧撑、仰卧起坐等 等，不过到目前为止，他坚持下来的只有晨跑。 现在给出一张学校附近的地图，这张地图中包含N个十字路口和M条街道，Elaxia只能从 一个十字路口跑向另外一个十字路口，街道之间只在十字路口处相交。Elaxia每天从寝室出发 跑到学校，保证寝室编号为1，学校编号为N。 Elaxia的晨跑计划是按周期（包含若干天）进行的，由于他不喜欢走重复的路线，所以 在一个周期内，每天的晨跑路线都不会相交（在十字路口处），寝室和学校不算十字路 口。Elaxia耐力不太好，他希望在一个周期内跑的路程尽量短，但是又希望训练周期包含的天 数尽量长。 除了练空手道，Elaxia其他时间都花在了学习和找MM上面，所有他想请你帮忙为他设计 一套满足他要求的晨跑计划。

Input

第一行：两个数N,M。表示十字路口数和街道数。 接下来M行，每行3个数a,b,c，表示路口a和路口b之间有条长度为c的街道（单向）。

Output

两个数，第一个数为最长周期的天数，第二个数为满足最长天数的条件下最短的路程长 度。

Sample Input

7 10
1 2 1
1 3 1
2 4 1
3 4 1
4 5 1
4 6 1
2 5 5
3 6 6
5 7 1
6 7 1

Sample Output

2 11

HINT

对于30%的数据，N ≤ 20，M ≤ 120。
对于100%的数据，N ≤ 200，M ≤ 20000。

Source

Day1

题解：

不废话，裸费用流

代码：

const inf=maxlongint;
type node=record
     from,go,next,v,c:longint;
     end;
var e:array[0..2000000] of node;
    pre,head,q,d:array[0..1000000] of longint;
    v:array[0..1000000] of boolean;
    i,j,n,m,s,t,l,r,mincost,tot,x,y,z,maxflow:longint;
function min(x,y:longint):longint;
 begin
 if x<y then exit(x) else exit(y);
 end;
procedure ins(x,y,z,w:longint);
 begin
 inc(tot);
 with e[tot] do
  begin
  from:=x;go:=y;v:=z;c:=w;next:=head[x];head[x]:=tot;
  end;
 end;
procedure insert(x,y,z,w:longint);
 begin
 ins(x,y,z,w);ins(y,x,0,-w);
 end;
function spfa:boolean;
 var i,x,y:longint;
 begin
 fillchar(v,sizeof(v),false);
 for i:=s to t do d[i]:=inf;
 l:=0;r:=1;q[1]:=s;d[s]:=0;v[s]:=true;
 while l<r do
  begin
  inc(l);if l=1000000 then l:=0;
  x:=q[l];v[x]:=false;
  i:=head[x];
  while i<>0 do
   begin
   y:=e[i].go;
   if (e[i].v<>0) and (d[x]+e[i].c<d[y]) then
    begin
    d[y]:=d[x]+e[i].c;
    pre[y]:=i;
    if not(v[y]) then
     begin
     v[y]:=true;
     inc(r);if r=1000000 then r:=0;
     q[r]:=y;
     end;
    end;
   i:=e[i].next;
  end;
 end;
 exit(d[t]<>inf);
 end;
procedure mcf;
 var i,tmp:longint;
 begin
 mincost:=0;maxflow:=0;
 while spfa do
  begin
  tmp:=inf;
  i:=pre[t];
  while i<>0 do
   begin
   tmp:=min(tmp,e[i].v);
   i:=pre[e[i].from];
   end;
  inc(mincost,tmp*d[t]);
  inc(maxflow,tmp);
  i:=pre[t];
  while i<>0 do
   begin
   dec(e[i].v,tmp);
   inc(e[i xor 1].v,tmp);
   i:=pre[e[i].from];
   end;
  end;
 end;
procedure init;
 begin
 tot:=1;
 readln(n,m);
 for i:=1 to m do
  begin
  readln(x,y,z);
  insert(x+n,y,1,z);
  end;
 for i:=2 to n-1 do insert(i,i+n,1,0);
 s:=1;t:=2*n;
 insert(s,s+n,inf,0);insert(n,t,inf,0);
 end;
procedure main;
 begin
 mincost:=0;
 mcf;
 writeln(maxflow,' ',mincost);
 end;
begin
 assign(input,'input.txt');assign(output,'output.txt');
 reset(input);rewrite(output);
 init;
 main;
 close(input);close(output);
end.