旅行 jzoj 1281

Description

　　今天又是个神圣的日子，因为LHX教主又要进行一段长途旅行。但是教主毕竟是教主，他喜欢走自己的路，让别人目瞪口呆。为什么呢，因为这条路线高低不平，而且是相当的严重。
　　但是教主有自己的办法，他会魔法。
　　这段路可以用一个长度为n的序列A[i]来表示，A[i]表示了第i这段路的高度。毕竟教主即使会使用魔法他还是个人，教主如果想穿越这条路线，他必须从第1段路开始走，走到第n段，从第i段走到第i+1段路需要消耗|A[i+1]-A[i]|点体力。为了节省体力，教主使出了他另一种神奇的魔法。教主的魔法可以交换相邻两段路的高度，并且这种魔法不需要花费额外的体力。但是第二次使用魔法开始，交换的两段路在路线中的位置需位于之前交换的两段路之后。即如果某次交换了A[j]和A[j+1]，那么下次交换A[k]和A[k+1]必须满足j＜k。
　　接着，LHX教主想规划下如何调整路段高度后穿越，使得体力消耗最小。

Input

　　输入的第1行为一个正整数n，表示了这条路线的长度。
　　第2行有n个正整数，相邻两个正整数用空格隔开，描述了A[i]这个序列。

Output

　　输出仅包括一个非负整数，为最小的体力消耗。

题解

f[i][0]=min(f[i+1][0]+dis(i,i+1),f[i+1][1]+dis(i,i+2))
f[i][1]=min(f[j+1][0]+dis(i,j+1),f[j+1][1]+dis(i,j+2))+dis(i,j)+sum(i+1,j)
j=n的特殊情况
f[i][1]=min(f[i][1],sum(i+1,n)+dis(n,i))

方程已出，此题已结。

代码

var
  n:longint;
  sum,a:array [0..2001] of longint;
  f:array [0..2001,0..1] of longint;
function min(o,p:longint):longint;
begin
  if o<p then exit(o);
  exit(p);
end;

procedure init;
var
  i:longint;
begin
  fillchar(f,sizeof(f),$7f);
  fillchar(sum,sizeof(sum),0);
  readln(n);
  for i:=1 to n do
    read(a[i]);
  a[n+1]:=a[n];
  for i:=2 to n do
    sum[i]:=sum[i-1]+abs(a[i]-a[i-1]);
end;

procedure main;
var
  i,j:longint;
begin
  f[n,0]:=0; f[n,1]:=0;
  for i:=n-1 downto 1 do
    begin
      f[i,0]:=min(f[i+1,0]+abs(a[i]-a[i+1]),f[i+1,1]+abs(a[i]-a[i+2]));
      for j:=i+1 to n-1 do
        f[i,1]:=min(f[i,1],min(f[j+1,0]+abs(a[i]-a[j+1]),f[j+1,1]+abs(a[i]-a[j+2]))+abs(a[i]-a[j])+sum[j]-sum[i+1]);
      f[i,1]:=min(f[i,1],sum[n]-sum[i+1]+abs(a[n]-a[i]));
    end;
end;

begin
  init;
  main;
  write(min(f[1,0],f[1,1]));
end.