poj 2777 Count Color 线段树

题意/Description：

    Chosen Problem Solving and Program design as an optional course, you are required to solve all kinds of problems. Here, we get a new problem. 
    There is a very long board with length L centimeter, L is a positive integer, so we can evenly divide the board into L segments, and they are labeled by 1, 2, ... L from left to right, each is 1 centimeter long. Now we have to color the board - one segment with only one color. We can do following two operations on the board: 
  1. "C A B C" Color the board from segment A to segment B with color C. 
  2. "P A B" Output the number of different colors painted between segment A and segment B (including). 
    In our daily life, we have very few words to describe a color (red, green, blue, yellow…), so you may assume that the total number of different colors T is very small. To make it simple, we express the names of colors as color 1, color 2, ... color T. At the beginning, the board was painted in color 1. Now the rest of problem is left to your. 

 

读入/Input：

    First line of input contains L (1 <= L <= 100000), T (1 <= T <= 30) and O (1 <= O <= 100000). Here O denotes the number of operations. Following O lines, each contains "C A B C" or "P A B" (here A, B, C are integers, and A may be larger than B) as an operation defined previously.

 

输出/Output：

    Ouput results of the output operation in order, each line contains a number.

 

题解/solution：

  我用线段树做，这题位运算结合到了一起。因为颜色数量很少，而且父结点的颜色正好是两个子结点颜色的按位或，因此可以用位运算。最后ans的个数就是不同颜色的个数。

  每个节点有如下参数：

    l，r 表示区间。

    color表示颜色，对于颜色要用位运算。

    cover表示节点的状况

 

  插入算法：微改，第二个判断解释，如果某个非叶子节点是cover，但是此时更新他的叶子节点，然后递归回来更新父节点的时候即会得到错误的结果。本质上就是说之前因为省时间我们不需要更新到每个叶子节点，但是如果某个父节点是cover的，那涉及到它的子节点更新时候他的所有子节点都要更新。

  统计算法：差不多不改，见程序。

 

代码/Code：

<strong>type
  arr=record
    l,r,color:longint;
    cover:boolean;
  end;
var
  tree:array [0..400001] of arr;
  n,t,m,ans,tk:longint;
procedure cre(p,b,e:longint);
var
  m:longint;
begin
  with tree[p] do
    begin
      l:=b; r:=e; color:=color or 1;
      if l=r then exit;
      m:=(b+e) div 2;
      cre(p*2,b,m);
      cre(p*2+1,m+1,e);
    end;
end;

procedure ins(p,b,e,c:longint);
var
  m:longint;
begin
  with tree[p] do
    begin
      if (l=b) and (r=e) then
        begin
          color:=1 shl (c-1);
          cover:=true;
          exit;
        end;
      if cover then
        begin
          cover:=false;
          tree[p*2].cover:=true;
          tree[p*2].color:=color;
          tree[p*2+1].cover:=true;
          tree[p*2+1].color:=color;
        end;
      m:=(l+r) div 2;
      if e<=m then ins(p*2,b,e,c) else
        if b>m then ins(p*2+1,b,e,c) else
          begin
            ins(p*2,b,m,c);
            ins(p*2+1,m+1,e,c);
          end;
      color:=tree[p*2].color or tree[p*2+1].color;
    end;
end;

procedure count(p,b,e:longint);
var
  m:longint;
begin
  with tree[p] do
    begin
      if (cover) or (b=l) and (r=e) then
        begin
          tk:=tk or color;
          exit;
        end;
      m:=(l+r) div 2;
      if e<=m then count(p*2,b,e) else
        if b>m then count(p*2+1,b,e) else
          begin
            count(p*2,b,m);
            count(p*2+1,m+1,e);
          end;
    end;
end;

procedure main;
var
  i,j,x,y,c,k:longint;
  ch:char;
begin
  readln(n,t,m);
  cre(1,1,n);
  for i:=1 to m do
    begin
      read(ch,x,y);
      if x>y then
        begin
          k:=x; x:=y; y:=k;
        end;
      if ch='C' then
        begin
          readln(c);
          ins(1,x,y,c);
        end else
        begin
          readln;
          ans:=0; tk:=0;
          count(1,x,y);
          for j:=1 to t do
            if tk and (1 shl (j-1))>0 then
              inc(ans);
          writeln(ans);
        end;
    end;
end;

begin
  main;
end.</strong>