Poj_1741_Tree

Description

给一个有n个顶点的树，每个边都有一个长度（正整数小于1001）。
定义dist（u，v）=节点u和v之间的最小距离。
给出一个整数k，当且仅当dist（u，v）不超过k时，每个对（u，v）的顶点都被称为有效。
编写一个程序，计算对给定树有效的对数。

 

Input

输入包含几个测试用例。 每个测试用例的第一行包含两个整数n，k。 （n <= 10000）以下n-1行各包含三个整数u，v，l，这意味着在节点u和v之间存在长度为l的边。
最后一个测试用例后跟两个零。

 

Output

对于每个测试用例，在单行上输出答案。

 

Solution

裸的点分。

细节：注意不能同一个子树的对数不能算。

 

代码

type
  arr=record
    y,w,next:longint;
  end;
var
  n,s,e,nm,dt,ans,min:longint;
  a:array [0..200001] of arr;
  ls,size,v,d,deep:array [0..100001] of longint;
procedure add(x,y,z:longint);
begin
  inc(nm);
  a[nm].y:=y; a[nm].w:=z;
  a[nm].next:=ls[x]; ls[x]:=nm;
end;

procedure init;
var
  i,x,y,z:longint;
begin
  nm:=0;
  for i:=1 to n-1 do
    begin
      readln(x,y,z);
      add(x,y,z); add(y,x,z);
    end;
  ans:=0;
end;

procedure dfs1(x,last:longint);
var
  i:longint;
begin
  size[x]:=1; i:=ls[x];
  while i<>0 do
    begin
      if (v[a[i].y]=1) or (a[i].y=last) then
        begin
          i:=a[i].next;
          continue;
        end;
      dfs1(a[i].y,x);
      size[x]:=size[x]+size[a[i].y];
      i:=a[i].next;
    end;
end;

function dfs2(x,last,tot:longint):longint;
var
  i:longint;
begin
  i:=ls[x];
  while i<>0 do
    begin
      if (v[a[i].y]=1) or (a[i].y=last) or (size[a[i].y]*2<tot) then
        begin
          i:=a[i].next;
          continue;
        end;
      exit(dfs2(a[i].y,x,tot));
      i:=a[i].next;
    end;
  exit(x);
end;

procedure gd(x,last:longint);
var
  i:longint;
begin
  inc(dt); d[dt]:=deep[x];
  i:=ls[x];
  while i<>0 do
    begin
      if (a[i].y=last) or (v[a[i].y]=1) then
        begin
          i:=a[i].next;
          continue;
        end;
      deep[a[i].y]:=deep[x]+a[i].w;
      gd(a[i].y,x);
      i:=a[i].next;
    end;
end;

procedure qsort(l,r:longint);
var
  mid,i,j,k:longint;
begin
  if l>r then exit;
  i:=l; j:=r;
  mid:=d[(l+r) div 2];
  repeat
    while d[i]<mid do inc(i);
    while d[j]>mid do dec(j);
    if i<=j then
      begin
        k:=d[i]; d[i]:=d[j]; d[j]:=k;
        inc(i); dec(j);
      end;
  until i>j;
  qsort(i,r);
  qsort(l,j);
end;

function js(x,cz:longint):longint;
var
  i,j,num:longint;
begin
  num:=0;
  dt:=0; deep[x]:=cz;
  gd(x,0);
  qsort(1,dt);
  j:=dt; i:=1;
  while i<j do
    if (d[i]+d[j]<=e) then
      begin
        num:=num+j-i;
        inc(i);
      end else dec(j);
  exit(num);
end;

procedure main(x:longint);
var
  i:longint;
begin
  ans:=ans+js(x,0);
  v[x]:=1;
  i:=ls[x];
  while i<>0 do

    begin
      if v[a[i].y]=1 then
        begin
          i:=a[i].next;
          continue;
        end;
      ans:=ans-js(a[i].y,a[i].w);
      dfs1(a[i].y,0);
      main(dfs2(a[i].y,0,size[a[i].y]));
      i:=a[i].next;
    end;
end;

begin
  readln(n,e);
  while (n<>0) and (e<>0) do
    begin
      fillchar(ls,sizeof(ls),0);
      fillchar(v,sizeof(v),0);
      init;
      dfs1(1,0);
      main(dfs2(1,0,n));
      write(ans);
      readln(n,e);
    end;
end.