洛谷_P1144_最短路计数

题目大意：

给出一个 N 个顶点 M 条边的无向无权图，顶点编号为 1-N。问从顶点 1 开始，到其他每个点的最短路有几条。

题解：

更新边长的时候如果大于号就覆盖，有相同最短路径就相加。

代码：

const
  mo=100003;
type
  arr=record
    y,next:longint;
  end;
var
  n,m,nm:longint;
  a:array [0..4000001] of arr;
  ls,d,ans,list,v:array [0..1000001] of longint;
procedure add(x,y:longint);
begin
  inc(nm);
  a[nm].y:=y; a[nm].next:=ls[x]; ls[x]:=nm;
end;

procedure init;
var
  i,x,y:longint;
begin
  readln(n,m);
  for i:=1 to m do
    begin
      readln(x,y);
      add(x,y); add(y,x);
    end;
end;

procedure spfa;
var
  head,tail,i,x:longint;
begin
  fillchar(d,sizeof(d),63);
  head:=0; tail:=1;
  list[1]:=1; d[1]:=0; ans[1]:=1;
  repeat
    inc(head);
    x:=list[head];
    i:=ls[x];
    while i<>0 do
      with a[i] do
        begin
          if d[x]+1<d[y] then
            begin
              d[y]:=d[x]+1;
              ans[y]:=ans[x];
              if v[y]=0 then
                begin
                  inc(tail);
                  list[tail]:=y;
                  v[y]:=1;
                end;
            end else
            if d[y]=d[x]+1 then
              ans[y]:=(ans[y]+ans[x]) mod mo;
          i:=next;
        end;
    v[x]:=0;
  until head>tail;
end;

procedure print;
var
  i:longint;
begin
  for i:=1 to n do
    writeln(ans[i]);
end;

begin
  init;
  spfa;
  print;
end.