VBA中方法传参

将变量做为参数传递给方法

Sub Test()
Dim a As Integer
    a = 1
Add a
Debug.Print a      '引用传递，a的值发生了变化，输出101
End Sub

Function Add(a As Integer)
   a = a + 100
End Function

   结论：VB传参时默认是引用传递byRef。

使用byVal关键字强制形参为值传递

Sub Test()
Dim a As Integer
    a = 1
Add a
Debug.Print a      '值传递，a的值没有变化，输出1
End Sub

Function Add(ByVal a As Integer)
   a = a + 100
End Function

调用一个有返回值函数

Sub Test()
Dim a As Integer
    a = 1
Dim sum As Integer
    sum = Add(a)
Debug.Print sum      '引用传递，输出101
End Sub

Function Add(a As Integer) As Integer
  Add = a + 100
End Function

  认识“（）”

Sub Test()
Dim a As Integer
    a = 1
    Add (a)
Debug.Print a                 'a的值没有变化，输出1
End Sub

Function Add(ByRef a As Integer) As Integer
  a = a + 100
End Function

    解释：

    1、Add只有一个参数，并且是“过程式调用”方式的时候，VBE“偷偷”把代码自动改为了Add   (a)。注意，Add和(a)之间有个“空格”

    2、()在此有完全不同的意义，可以理解它是一个运算符。(a)生成了一个临时变量，a的一个副本，然后将这个临时变量(a)传递给Add

    3、a本身并没有传递给Add方法，所以a的值并不会有任何变化。

将一个数组做为参数传递给方法：

Sub Test()
Dim arr(2) As Integer
    arr(0) = 1
    arr(1) = 2
    arr(2) = 3

    showArray arr
Dim i As Integer
    For i = 0 To 2
          Debug.Print arr(i)        '输出101，102，103
    Next i
End Sub

Function showArray(arr() As Integer)
Dim i As Integer
    For i = 0 To 2
       arr(i) = arr(i) + 100
    Next i
End Function

和()有关的一个常见错误和保留问题：

Sub Test()
Dim arr(2) As Integer
    arr(0) = 1
    arr(1) = 2
    arr(2) = 3

    showArray (arr)                 '编译时报错：缺少数组或用户定义类型
Dim i As Integer
    For i = 0 To 2
          Debug.Print arr(i)
    Next i
End Sub

Function showArray(arr() As Integer)
Dim i As Integer
    For i = 0 To 2
       arr(i) = arr(i) + 100
    Next i
End Function

      编译报错：缺少数组或用户定义类型，除了()生成了一个临时变量之外，与此有关的原因暂不明。。       

如果形参是arr而不是arr()

Sub Test()
Dim arr(2) As Integer
    arr(0) = 1
    arr(1) = 2
    arr(2) = 3

    showArray (arr)
Dim i As Integer
    For i = 0 To 2
          Debug.Print arr(i)           '输出1,2,3
    Next i
End Sub

Function showArray(arr)
Dim sum As Integer, i As Integer
    For i = 0 To 2
       arr(i) = arr(i) + 100
    Next i
End Function