利用awk处理学生成绩问题（难度较大）

学生成绩表单如下：

Name,Team,First Test, Second Test, Third Test
Tom,Red,5,17,22
Joe,Green,3,14,22
Maria,Blue,6,18,21
Fred,Blue,2,15,23
Carlos,Red,-1,15,24
Phuong,Green,7,19,21
Enrique,Green,3,16,20
Nancy,Red,9,12,24

编写一个awk脚本用来计算每个人的平均成绩，每次测试的平均成绩和没组队的平均成绩。如果某次成绩为负数，则表示此人错过了测试，那计算平均成绩时排除此人再计算。输出的格式如下，在名字的列表中，名字是10个宽度且左对齐（提示printf中使用%-10s格式），而平均值是7个字符宽度，右边两个右对齐的小数。

Name       Average
----       -------
Tom          14.67
Joe          13.00
Maria        15.00
Fred         13.33
Carlos       19.50
Phuong       15.67
Enrique      13.00
Nancy        15.00
------------------
Average for Test 1 : 5
Average for Test 2 : 15.75
Average for Test 3 : 22.125
-------------------
Average for Red Team: 16
Average for Blue Team: 14.1667
Average for Green Team: 13.8889

脚本如下：

awk -F, 'BEGIN{
printf "%-10s %s
","Name","Average"
printf "%-10s %s
","----","-------"
}
NR>1{
sum=0
n=0
for (i=3;i<=5;i++){
if ($i>0){
n++
sum=sum+$i
testcount[i-2]++
testtotal[i-2]+=$i
teamcount[$2]++
teamtotal[$2]+=$i
}
}
printf "%-10s %7.2f
",$1,sum/n
}
END{
print "------------------"
for (j=1;j<=3;j++){
print "Average for Test "j" : "testtotal[j]/testcount[j]
}
print "-------------------"
for (t in teamcount){
print "Average for "t" Team: "teamtotal[t]/teamcount[t]
}
}'  teamlist.txt

 解析：

1.awk的BEGIN语句输出表的两个列名。

2.NR>1表示只处理从第二行开始的数据。

3.sum=0,n=0,初始化三个测试总成绩和参加的次数。

4.定义一个for循环，循环处理三次测试数据。

5.判断成绩大于0才处理此次测试。

6.为计算每个人的平均成绩，用变量n记录测试次数，变量sum累计三次的成绩，接着下面用printf格式化输出每个人的平均成绩；为计算三个测试中每次的平均成绩，以i-2作为索引（即i-2次测试），数组testcount记录某次测试参加的人数，数组testtotal记录某次测试的总成绩；为计算每个组的平均成绩，以第二列组名做为索引，数组teamcount记录某组参加测试的人数，数组teamtotal记录某组的总成绩。

7.在END语句中用两个for循环语句分别输出每次测试及每组测试的平均成绩。