delphi实现电脑屏幕旋转（电脑屏幕，不是手机屏幕）

相关资料：

注意：是电脑屏幕，不是手机屏幕

实例代码：

unit Unit10;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls;

type
  TForm10 = class(TForm)
    ComboBox1: TComboBox;
    Label1: TLabel;
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;
const
  DM_DISPLAYORIENTATION = $00800000;
  ENUM_CURRENT_SETTINGS =-1;
  DMDO_DEFAULT : DWORD  = 0;
       DMDO_90 : DWORD  = 1;
      DMDO_180 : DWORD  = 2;
      DMDO_270 : DWORD  = 3;
var
  Form10: TForm10;

implementation

{$R *.dfm}
procedure ChangeOrientation(NewOrientation: DWORD);
var
  dm: TDeviceMode;
  dwTemp: DWORD;
  dmDisplayOrientation : DWORD;
begin
   ZeroMemory(@dm, sizeof(dm));
   dm.dmSize := sizeof(dm);
   if EnumDisplaySettings(nil, DWORD(ENUM_CURRENT_SETTINGS), dm) then
   begin
      Move(dm.dmScale,dmDisplayOrientation, SizeOf(dmDisplayOrientation));
      // swap width and height
      if Odd(dmDisplayOrientation) <> Odd(NewOrientation) then
      begin
       dwTemp := dm.dmPelsHeight;
       dm.dmPelsHeight := dm.dmPelsWidth;
       dm.dmPelsWidth := dwTemp;
      end;
      if dmDisplayOrientation <> NewOrientation then
      begin
        Move(NewOrientation, dm.dmScale, SizeOf(NewOrientation));
        if (ChangeDisplaySettings(dm, 0) <> DISP_CHANGE_SUCCESSFUL) then
         RaiseLastOSError;
      end;
   end;
end;

procedure TForm10.Button1Click(Sender: TObject);
begin
  try
    case ComboBox1.ItemIndex of
      0: begin
        ChangeOrientation(DMDO_180);
        ShowMessage('旋转180度');
      end;
      1: begin
        ChangeOrientation(DMDO_270);
        ShowMessage('旋转270度');
      end;
      2: begin
        ChangeOrientation(DMDO_90);
        ShowMessage('旋转90度');
      end;
      3: begin
        ChangeOrientation(DMDO_DEFAULT);
        ShowMessage('默认值');
      end;
    end;
  except
    on E: Exception do
      ShowMessage(E.ClassName + ':' +E.Message);
  end;
end;

end.