1015: [JSOI2008]星球大战starwar

Description

很久以前，在一个遥远的星系，一个黑暗的帝国靠着它的超级武器统治者整个星系。某一天，凭着一个偶然的机遇，一支反抗军摧毁了帝国的超级武器，并攻下了星系中几乎所有的星球。这些星球通过特殊的以太隧道互相直接或间接地连接。 但好景不长，很快帝国又重新造出了他的超级武器。凭借这超级武器的力量，帝国开始有计划地摧毁反抗军占领的星球。由于星球的不断被摧毁，两个星球之间的通讯通道也开始不可靠起来。现在，反抗军首领交给你一个任务：给出原来两个星球之间的以太隧道连通情况以及帝国打击的星球顺序，以尽量快的速度求出每一次打击之后反抗军占据的星球的连通快的个数。（如果两个星球可以通过现存的以太通道直接或间接地连通，则这两个星球在同一个连通块中）。
Input

输入文件第一行包含两个整数，N (1 <= N <= 2M) 和M (1 <= M <= 200,000)，分别表示星球的数目和以太隧道的数目。星球用0~N-1的整数编号。接下来的M行，每行包括两个整数X, Y，其中（0<=X<>Y
Output

输出文件的第一行是开始时星球的连通块个数。接下来的N行，每行一个整数，表示经过该次打击后现存星球的连通块个数。
Sample Input
8 13
0 1
1 6
6 5
5 0
0 6
1 2
2 3
3 4
4 5
7 1
7 2
7 6
3 6
5
1
6
3
5
7
Sample Output
1
1
1
2
3
3

用并查集维护联通块的信息，逆序处理摧毁的操作，因为并查集是用来合并的

先把一直没有被摧毁星球之间的边连起来，作为最后一个操作的回答

然后逆序加点，计算联通块个数

const
    maxn=400010;
    maxm=200010;
var
    f,ans,s:array[0..maxn]of longint;
    flag:array[0..maxn]of boolean;
    first,last,next:array[0..maxn*2]of longint;
    n,m,q,num,tot:longint;
 
procedure insert(x,y:longint);
begin
    inc(tot);
    last[tot]:=y;
    next[tot]:=first[x];
    first[x]:=tot;
end;
 
function find(x:longint):longint;
begin
    if f[x]=x then exit(x);
    f[x]:=find(f[x]);
    exit(f[x]);
end;
 
procedure init;
var
    i,j,x,y:longint;
begin
    read(n,m);
    for i:=1 to n do
      f[i]:=i;
    for i:=1 to m do
      begin
        read(x,y);
        insert(x+1,y+1);
        insert(y+1,x+1);
      end;
    read(q);
    for i:=1 to q do
      begin
        read(s[i]);
        inc(s[i]);
        if flag[s[i]]=false then flag[s[i]]:=true
        else s[i]:=n+1;
      end;
    ans[q]:=n;
    for i:=1 to n do
      if flag[i]=false then
      begin
        j:=first[i];
        while j<>0 do
          begin
            if flag[last[j]]=false then
            begin
              if find(i)<>find(last[j]) then
              begin
                dec(ans[q]);
                f[f[i]]:=f[last[j]];
              end;
            end;
            j:=next[j];
          end;
      end
      else dec(ans[q]);
end;
 
procedure work;
var
    i,j:longint;
begin
    for i:=q downto 1 do
      if (flag[s[i]])and(s[i]<=n) then
      begin
        ans[i-1]:=ans[i]+1;
        j:=first[s[i]];
        while j<>0 do
          begin
            if flag[last[j]]=false then
            if find(s[i])<>find(last[j]) then
            begin
              dec(ans[i-1]);
              f[f[s[i]]]:=f[last[j]];
            end;
            j:=next[j];
          end;
        flag[s[i]]:=false;
      end
      else ans[i-1]:=ans[i];
    for i:=0 to q do
      writeln(ans[i]);
end;
 
begin
    init;
    work;
end.