1055: [HAOI2008]玩具取名

Description

某人有一套玩具，并想法给玩具命名。首先他选择WING四个字母中的任意一个字母作为玩具的基本名字。然后他会根据自己的喜好，将名字中任意一个字母用“WING”中任意两个字母代替，使得自己的名字能够扩充得很长。现在，他想请你猜猜某一个很长的名字，最初可能是由哪几个字母变形过来的。
Input

第一行四个整数W、I、N、G。表示每一个字母能由几种两个字母所替代。接下来W行，每行两个字母,表示W可以用这两个字母替代。接下来I行，每行两个字母,表示I可以用这两个字母替代。接下来N行，每行两个字母,表示N可以用这两个字母替代。接下来G行，每行两个字母,表示G可以用这两个字母替代。最后一行一个长度不超过Len的字符串。表示这个玩具的名字。
Output

一行字符串，该名字可能由哪些字母变形而得到。（按照WING的顺序输出）如果给的名字不能由任何一个字母变形而得到则输出“The name is wrong!”
Sample Input
1 1 1 1
II
WW
WW
IG
IIII

Sample Output
IN

HINT

W可以变成II所以IIII可以缩成WW IN均能变成WW所以WW又可以缩成I或者N 所以最终答案应该按照“WING”的顺序输出IN [数据范围] 30%数据满足Len<=20，W、I、N、G<=6 100%数据满足Len<=200，W、I、N、G<=16

直接dp，f[i,j,k]表示i到j是否能表示成k（bool型的）

const
    maxn=205;
var
    num:array[1..4]of longint;
    w:array[1..4,0..30]of string;
    f:array[0..maxn,0..maxn,0..4]of boolean;
    len:longint;

function calc(ch:char):longint;
begin
    case ch of
      'W':exit(1);
      'I':exit(2);
      'N':exit(3);
      'G':exit(4);
      else exit(0);
    end;
end;

function calc(ch:longint):char;
begin
    case ch of
      1:exit('W');
      2:exit('I');
      3:exit('N');
      4:exit('G');
      else exit(' ');
    end;
end;

procedure init;
var
    i,j:longint;
    s:char;
    str:string;
begin
    for i:=1 to 4 do
      read(num[i]);
    readln;
    for i:=1 to 4 do
      for j:=1 to num[i] do
        readln(w[i,j]);
    readln(str);
    len:=length(str);
    for i:=1 to len do
      f[i,i,calc(str[i])]:=true;
end;

procedure dp;
var
    i,j,k,d,l,r:longint;
begin
    for i:=1 to len-1 do
      for j:=1 to len-i do
        for k:=1 to 4 do
          for d:=j to j+i-1 do
            begin
              for l:=1 to num[k] do
                if (f[j,d,calc(w[k,l][1])]) and (f[d+1,j+i,calc(w[k,l][2])]) then
                begin
                  f[j,j+i,k]:=true;
                  break;
                end;
              if f[j,j+i,k] then break;
            end;
    for i:=1 to 4 do
      if f[1,len,i] then write(calc(i));
    for i:=1 to 4 do
      if f[1,len,i] then exit;
    write('The name is wrong!');
end;

begin
    init;
    dp;
end.