根据表或者视图自动生成分页语句的存储过程，适用于Sql Server 2005及以上版本

原创。如果使用本文源代码，请保留作者信息。谢谢

对于一向尽力避免拼Sql语句执行的人，看到同事们在数据库中都利用拼Sql语句的形式进行分页操作。不仅写起来复杂，容易出错，而且各个表和视图都要重复的去写，于是萌生了写一个生成分页语句的存储过程的想法，而且分页不使用拼Sql语句的形式。用这个存储过程生成语句之后，再加上特定业务逻辑的Where条件之后，就可以用了。比较方便。

存储过程需要的参数有2个，即表或者视图的名称，以及需要显示和排序的列名组成的字符串，比如：

L_spCreatePagingScript 'vw_Person'
L_spCreatePagingScript 'vw_Person','FirstName,LastName,MiddleName'

生成的语句类似以下代码：

/*
DECLARE @OrderByColumnName VARCHAR(128)
DECLARE @PageSize INT
DECLARE @PageIndex INT -- started from 1
DECLARE @IsDesc BIT    -- 0 or 1

SET @OrderByColumnName = ''
SET @PageSize = 10
SET @PageIndex = 1
SET @IsDesc = 0
 */
 WITH DataTable AS
(
    SELECT Row_Number() 
        OVER (
            ORDER BY
                (CASE @OrderByColumnName + Cast(@IsDesc AS VARCHAR(1))
                    When 'FirstName0' Then FirstName
                    When 'LastName0' Then LastName
                    When 'MiddleName0' Then MiddleName End) ASC,
                (CASE @OrderByColumnName + Cast(@IsDesc AS VARCHAR(1))
                    When 'FirstName1' Then FirstName
                    When 'LastName1' Then LastName
                    When 'MiddleName1' Then MiddleName End) DESC
) AS RowNumber
        , FirstName,LastName,MiddleName
    FROM vw_Person
    -- TODO: WHERE clauses here
)
SELECT *
FROM DataTable
WHERE RowNumber BETWEEN @PageSize * (@PageIndex - 1) + 1 AND @PageSize * @PageIndex

以下是源代码：

CREATE PROCEDURE L_spCreatePagingScript
(
    @TableName VARCHAR(128)
    , @ColumnNames VARCHAR(8000) = NULL    -- divided by ','
)
AS
-- Create By Ricky Lin, 2/18/2011, ricky81317.cnblogs.com
SET NOCOUNT ON
CREATE TABLE #ColumnNames
(
    ColumnName VARCHAR(128)
)

IF @ColumnNames IS NULL OR Len(@ColumnNames) = 0
BEGIN
    -- let's generate all column names
    INSERT INTO #ColumnNames
    SELECT [Name] FROM Sys.Columns WHERE [Object_ID] = Object_ID(@TableName)
    
    SET @ColumnNames = ''
    SELECT @ColumnNames = @ColumnNames + ', ' + ColumnName FROM #ColumnNames
    IF Len(@ColumnNames) > 0 
        SET @ColumnNames = Right(@ColumnNames, Len(@ColumnNames) - 2)
END
ELSE
BEGIN
    INSERT INTO #ColumnNames
    SELECT Item FROM dbo.K_fnStringSplit(@ColumnNames, ',', 0)
END

-- SELECT * FROM #ColumnNames
-- PRINT @ColumnNames

DECLARE @CaseStr VARCHAR(8000)
DECLARE @AscStr VARCHAR(8000)
DECLARE @DescStr VARCHAR(8000)
SET @CaseStr = '
                (CASE @OrderByColumnName + Cast(@IsDesc AS VARCHAR(1))'
SET @AscStr = ''
SET @DescStr = ''

DECLARE @ColName VARCHAR(128)
DECLARE colCur CURSOR FAST_FORWARD FOR SELECT ColumnName FROM #ColumnNames
OPEN colCur
FETCH NEXT FROM colCur INTO @ColName
WHILE @@Fetch_Status = 0
BEGIN
    SET @AscStr = @AscStr + '
                    When ''' + @ColName + '0'' Then ' + @ColName
    SET @DescStr = @DescStr + '
                    When ''' + @ColName + '1'' Then ' + @ColName
    FETCH NEXT FROM colCur INTO @ColName
END
CLOSE colCur
DEALLOCATE colCur

SET @AscStr = @CaseStr + @AscStr + ' End) ASC,'
SET @DescStr = @CaseStr + @DescStr + ' End) DESC
'

DROP TABLE #ColumnNames

-- PRINT @OrderByStr

DECLARE @Sql VARCHAR(MAX)
SET @Sql = '
/*
DECLARE @OrderByColumnName VARCHAR(128)
DECLARE @PageSize INT
DECLARE @PageIndex INT -- started from 1
DECLARE @IsDesc BIT    -- 0 or 1

SET @OrderByColumnName = ''''
SET @PageSize = 10
SET @PageIndex = 1
SET @IsDesc = 0
*/
WITH DataTable AS
(
    SELECT Row_Number() 
        OVER (
            ORDER BY' + @AscStr + @DescStr + ') AS RowNumber
        , ' + @ColumnNames + '
    FROM ' + @TableName + '
    -- TODO: WHERE clauses here
)
SELECT *
FROM DataTable
WHERE RowNumber BETWEEN @PageSize * (@PageIndex - 1) + 1 AND @PageSize * @PageIndex'

PRINT @Sql

SET NOCOUNT OFF