[小明学Shader]11.圆角

原文连接:http://blog.csdn.net/mobanchengshuang/article/details/38731035

1.代码

Shader"Custom/圆角"{
    properties{
        _MainTex("Base(RGB)",2D)="white"{}
        _Value("Cut Value",range(0,0.25))=0.1
    }
    CGINCLUDE
    #include "UnityCG.cginc"
    
            sampler2D _MainTex;
            float _Value;
    
            struct v2f {
                float4 pos:SV_POSITION;
                float2 uv:TEXCOORD;
            };
    
            v2f vert(appdata_full v){
                v2f o;
                o.pos=mul(UNITY_MATRIX_MVP,v.vertex);
                o.uv=v.texcoord;
                return o;
            }
    
            float4 frag(v2f i):COLOR{
                float4 c=tex2D(_MainTex,i.uv);
                
                //计算圆角
                float2 uv=i.uv-0.5;
                float remain=0.5-_Value;
                //计算当前uv是不是在四个边角
                float mx=step(remain,abs(uv[0]));
                float my=step(remain,abs(uv[1]));
                //计算当前uv在四个边角的相对uv
                float rx = fmod(uv.x, remain); 
                float ry = fmod(uv.y, remain);     
                //若在边角,且距离顶点的距离大于value值,则不显示
                float fillAlpha=1-mx*my*step(_Value*_Value,rx*rx+ry*ry);
                
                c.a=fillAlpha;
                
                return c;
            }
    ENDCG
    
    subshader{
        Tags{"Queue"="Transparent"}
        Blend SrcAlpha OneMinusSrcAlpha
        pass{
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            
            ENDCG
        }
    }
    
    FallBack "Diffuse"
}

2.效果

3.原理

计算出下图所示中紫色区域内点距离两个绿色点的距离,大于目标值的不显示即可.在计算相对于交点的坐标时,通过求莫的方式即可获得(fmod不会改变符号).所以本方法所能画的最大半径是0.25.