serverSocket与socket的使用

1、使用serverSocket建立服务端：

   首先创建一个 serverSocket(一定要是个全局变量)

      private var server:ServerSocket;

   绑定到指定的本地址和端口

      server.bind( 6666, "119.138.64.241" );

   侦听绑定的IP地址和端口上的TCP连接 

      server.listen();

    当有客户端连接时（当客户端尝试连接到服务器套接字时，ServerSocket 对象调度 ServerSocketConnectEvent 对象）

      server.addEventListener(ServerSocketConnectEvent.CONNECT, onConnect);

<?xml version="1.0" encoding="utf-8"?>
<mx:WindowedApplication xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute">
    
    <mx:Script>
        <![CDATA[

            private var server:ServerSocket;
            
            [Bindable]
            private var isRunning:Boolean = false;

            protected function start(event:MouseEvent):void
            {
                if( !server )
                {
                    server = new ServerSocket();
                }
                if( isRunning )
                {
                    server.close();
                    server = null;
                }
                else
                {
                    try
                    {
                        //绑定到指定的本地地址和端口
                        server.bind( 6666, "119.138.64.241" );
                        //侦听绑定的 IP 地址和端口上的 TCP 连接
                        server.listen();
                        server.addEventListener(ServerSocketConnectEvent.CONNECT, onConnect);
                    }
                    catch(e:*)
                    {
                        trace( e );
                    }
                }
                isRunning = !isRunning;
            }
            
            protected function onConnect(event:ServerSocketConnectEvent):void
            {
                //trace( "connect..." );
                var socket:Socket = event.socket;
                socket.addEventListener(ProgressEvent.SOCKET_DATA, onReceive);
                
                outputTxt.text += "connect..." +"
";
            }
            
            protected function onReceive(event:ProgressEvent):void
            {
                var socket:Socket = event.target as Socket;
                //socket.readUTF();
                var str:String = socket.readUTF();
                
                outputTxt.text += str + "
";
                
                //回发已收到的消息
                socket.writeUTF( "Message received: " + str );
                socket.flush();
            }
            
        ]]>
    </mx:Script>
    <mx:ApplicationControlBar left="10" right="10" top="10" bottom="415" horizontalAlign="right">
        <mx:Button id="startBT" label="{isRunning?'Stop':'Start'}" click="start(event)"/>
    </mx:ApplicationControlBar>
    <mx:TextArea id="outputTxt" left="10" right="10" top="59" bottom="10"/>
    
</mx:WindowedApplication>

2、使用socket建立客户端
    创建 scoket 对象

    private var socket:Socket;

    socket = new Socket();

   连接服务端（地址和端口要和服务端一到致）

   socket.connect( "119.138.64.241", 6666 );

   侦听socket的连接

   socket.addEventListener(Event.CONNECT, onConnect );   

<?xml version="1.0" encoding="utf-8"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute">
    
    <mx:Script>
        <![CDATA[
            import mx.events.FlexEvent;

            private var socket:Socket;
            protected function connectServer(event:MouseEvent):void
            {
                socket = new Socket();
                socket.connect( "119.138.64.241", 6666 );
                socket.addEventListener(Event.CONNECT, onConnect );    
                socket.addEventListener(ProgressEvent.SOCKET_DATA, receiveServerMsg);
            }
            
            protected function onConnect(event:Event):void
            {
                outputTxt.text += "connect..." + "
";
            }
            
            protected function sendMsg(event:FlexEvent):void
            {
                if( socket.connected )
                {
                    socket.writeUTF( inputTxt.text );
                    socket.flush();
                }
            }
            
            /**
             * 接收服务器回发的消息
             * 
             **/
            protected function receiveServerMsg(event:ProgressEvent):void
            {
                var socket:Socket = event.target as Socket;
                var str:String = socket.readUTF();
                outputTxt.text += str + "
";
            }
            
        ]]>
    </mx:Script>
    
    <mx:ApplicationControlBar left="10" right="10" top="10" bottom="415" horizontalAlign="right">
        <mx:Label text="ID"/>
        <mx:TextInput id="idInput" text="kft"/>
        <mx:Button id="connectBT" label="connect" click="connectServer(event)"/>
    </mx:ApplicationControlBar>
    <mx:TextArea id="outputTxt" left="11" right="9" top="67" bottom="40"/>
    <mx:TextInput id="inputTxt" left="10" right="10" bottom="10" height="22" enter="sendMsg(event)"/>
</mx:Application>