[erlang] Erlang TCP(gen_tcp)

-module(socket_example).
-compile(export_all).

nano_get_url() ->
    nano_get_url("www.google.com").

nano_get_url(URL) ->
    {ok,Socket} = gen_tcp:connect(URL,80,[binary,{packet,0}]),
    ok = gen_tcp:send(Socket,"GET / HTTP/1.0\r\n\r\n"),
    receive_data(Socket,[]).

receive_data(Socket,SoFar) ->
    receive
        {tcp,Socket,Bin} ->
            receive_data(Socket,[Bin|SoFar]);
        {tcp_closed,Socket} ->
            list_to_binary(lists:reverse(SoFar))
    end.

start_nano_server() ->
    %% 返回 {ok,Socket} 或 error,Why
    case gen_tcp:listen(2345,[binary,{packet,4}, %% 每个应用程序消息都从一个4字节长的头部开始
                                       {reuseaddr,true},  %% 
                                       {active,true}]) of %% {active,true} 创建一个主动套字节(非阻塞)　
                                                             %% {active,false} 创建一个被动套字节(阻塞) 
                                                          %% {active,once} 创建一个主动套字节仅接收一条消息,如想接收下一条必须再次激活(半阻塞)
        {ok,Listen} ->
            case gen_tcp:accept(Listen) of %% 等待暂停并等待一个连接
                {ok,Socket} ->
                    gen_tcp:close(Listen), %% 关闭监听,服务器不会继续处于监听状态,也无法建立任何新的连接 
                    loop(Socket);
                {error,Why} ->
                    io:format("~p~n",[Why])
            end;
        {error,Why} ->
            io:format("~p~n",[Why])
    end.

loop(Socket) ->
    receive
        {tcp,Socket,Bin} ->
            io:format("Server received binary = ~p~n",[Bin]),
            Str = binary_to_term(Bin),
            io:format("Server (unpacked) ~p~n",[Str]),
            Reply = Str,
            timer:sleep(5000),
            %%Reply = lib_misc:string2value(Str),
            io:format("Server replying = ~p~n",[Reply]),
            gen_tcp:send(Socket,term_to_binary(Reply)),
            loop(Socket);
        {tcp_closed,Socket} ->
            io:format("Server socket closed~n")
    end.

nano_client_eval(Str) ->
    {ok,Socket} = gen_tcp:connect("localhost",2345,[binary,{packet,4}]),
    ok = gen_tcp:send(Socket,term_to_binary(Str)),
    receive
        {tcp,Socket,Bin} ->
            io:format("Client received binary = ~p~n",[Bin]),
            Val = binary_to_term(Bin),
            io:format("Client result = ~p~n",[Val]),
            gen_tcp:close(Socket)
    end.

%% 顺序型服务器(一个服务器一次只接收一个连接)
start_seq_server() ->
    case gen_tcp:listen(2345,[binary,{packet,4}, %% 每个应用程序消息都从一个4字节长的头部开始
                                       {reuseaddr,true},  %% 
                                       {active,true}]) of
        {ok,Listen} ->
            seq_loop(Listen);
        {error,Why} ->
            io:format("~p~n",[Why])
    end.

seq_loop(Listen) ->
    case gen_tcp:accept(Listen) of %% 等待暂停并等待一个连接
        {ok,Socket} ->
            loop(Socket),
            seq_loop(Listen);
        {error,Why} ->
            io:format("~p~n",[Why])
    end.

%% 并行服务器
start_parallel_server() ->
    case gen_tcp:listen(2345,[binary,{packet,4}, %% 每个应用程序消息都从一个4字节长的头部开始
                                       {reuseaddr,true},  %% 
                                       {active,true}]) of
        {ok,Listen} ->
            spawn(fun()-> par_connect(Listen) end);
        {error,Why} ->
            io:format("~p~n",[Why])
    end.

par_connect(Listen) ->
    case gen_tcp:accept(Listen) of %% 等待暂停并等待一个连接
        {ok,Socket} ->
            spawn(fun() -> par_connect(Listen) end),
            loop(Socket);
        {error,Why} ->
            io:format("~p~n",[Why])
    end.

TCP服务器结果

server

Eshell V5.8.4  (abort with ^G)
1> c(socket_example).
{ok,socket_example}
2> socket_example:start_nano_server().
Server received binary = <<131,107,0,4,49,50,51,52>>
Server (unpacked) "1234"
Server replying = "1234"
Server socket closed
ok
>３

client

Eshell V5.8.4  (abort with ^G)
1> c(socket_example).
{ok,socket_example}     
2> socket_example:nano_client_eval("1234").
Client received binary = <<131,107,0,4,49,50,51,52>>
Client result = "1234"

顺序服务器

server

Eshell V5.8.4  (abort with ^G)
1> socket_example:start_seq_server().
Server received binary = <<131,107,0,4,49,50,51,52>>
Server (unpacked) "1234"
Server replying = "1234"
Server socket closed
Server received binary = <<131,107,0,4,52,51,50,49>>
Server (unpacked) "4321"
Server replying = "4321"
Server socket closed

client1

Eshell V5.8.4  (abort with ^G)
1> socket_example:nano_client_eval("1234").
Client received binary = <<131,107,0,4,49,50,51,52>>
Client result = "1234"
ok
2>

client2

Eshell V5.8.4  (abort with ^G)
1> socket_example:nano_client_eval("4321").
Client received binary = <<131,107,0,4,52,51,50,49>>
Client result = "4321"
ok
2> 

并行服务器

server

Eshell V5.8.4  (abort with ^G)
1> socket_example:start_parallel_server().
<0.34.0>
Server received binary = <<131,107,0,4,49,50,51,52>>
Server (unpacked) "1234"
Server received binary = <<131,107,0,4,52,51,50,49>>
Server (unpacked) "4321"
Server replying = "1234"
Server socket closed
Server replying = "4321"
Server socket closed
2>

client1

Eshell V5.8.4  (abort with ^G)
1> socket_example:nano_client_eval("1234").
Client received binary = <<131,107,0,4,49,50,51,52>>
Client result = "1234"
ok
2>

client2

Eshell V5.8.4  (abort with ^G)
1> socket_example:nano_client_eval("4321").
Client received binary = <<131,107,0,4,52,51,50,49>>
Client result = "4321"
ok
2>