SAP ABAP / 4 基础知识学习
数据类型
C ：字符串
D ：日期型格式为 YYYYMMDD 例：'1999/12/03'
F : 浮点数长度为8
I ：整数
N ：数值组成的字符串 如：011，'302'
P : PACKED数用于小数点数值 如：12.00542
T : 时间格式为：HHMMSS 如：'14:03:00'
X : 16进制数 如：'1A03'
*-------------------------------------------------------------------------------------*
变量声明
DATA <F> [<Length>] <type> [<value>][decimals]
<F> 变量名称
<length><type> 变量类型及长度
<value> 初值
<decimals> 小数位数
exp:
DATA : COUNTER TYPE P DECIMALS 3.
NAME(10) TYPE C VALUE 'DELTA'.
S_DATE TYPE D VALUE '19991203'.
exp:
DATA : BEGIN OF PERSON,
NAME(10) TYPE C,
AGE TYPE I,
WEIGHT TYPE DECIMALS 2,
END OF PERSON.
另外,有关DATA声明的指令还有: CONSTANTS(声明常数)、STATICS(临时变量声明).
exp:
CONSTANTS PI TYPE P DECIMALS 5 VALUE '3.14159'.
STATICS 关键字
声明的变量仅在目前的程序中使用, 结束后会自动释放
语法:
STATICS <c> [<length>] <type> [<value>] [<decimals>]
系统专用变量说明
系统内部专门创建了SYST这个STRUCTURE,里面的栏位存放系统变量,常用的系统变量有:
SY-SUBRC: 系统执行某指令后,表示执行成功与否的变量，'0'表示成功
SY-UNAME: 当前使用者登入SAP的USERNAME;
SY-DATUM: 当前系统日期;
SY-UZEIT: 当前系统时间;
SY-TCODE: 当前执行程序的Transaction code
SY-INDEX: 当前LOOP循环过的次数
SY-TABIX: 当前处理的是internal table 的第几笔
SY-TMAXL: Internal table的总笔数
SY-SROWS: 屏幕总行数;
SY-SCOLS: 屏幕总列数;
SY-MANDT: CLIENT NUMBER
SY-VLINE: 画竖线
SY-ULINE: 画横线
TYPE 关键字
用来指定资料型态或声明自定资料型态
Example:
TYPES: BEGIN OF MYLIST,
NAME(10) TYPE C,
NUMBER TYPE I,
END OF MYLIST.
DATA LIST TYPE MYLIST.
LIKE 关键字
跟TYPE关键字使用格式相同, 如
DATA TRANSCODE LIKE SY-TCODE.
不同的是 LIKE 用在已有值的资料项, 如系统变量, 而TYPE关键字则是用在指定资料型态。
TABLES 关键字
用来声明 Table Work Area 的数据, 对应至 ABAP/4 资料文件(Dictionary Object), 由SQL 指令加载所需数据
语法:
TABLES <dbtab>
Example:
TABLES: SPFL.
SELECT * FROM SPFL.
WRITE: SPFL-MANDT, SPFL-CARRID,SPFL-CONNECTION.
ENDSELECT.
从ABAP/4 Dictionary 的 SPFL 档载入MANDT,CARRID,CONNECTION 三个字段至SPFL 此Table Work Area
*-------------------------------------------------------------------------------------*
输出
一. WRITE 语句
ABAP/4用来在屏幕上输出资料的指令是WRITE指令,例如:
WRITE: 'USER NAME IS:', SY-UNAME.
二. 指定屏幕输出位置
指定输出位置的语句格式为:
WRITE: [AT] [ / ] [<pos>] [(<len>)] 资料项 [<par>]
其中: / : 在下一行输出
<pos>: 指定输出的行号;
(<len>):指定输出位数(长度)
<par>: 指定显示格式参数,参数有:
LEFT-JUSTIFIED 资料*左对齐
CENTERED 资料*中间对齐
RIGHT-JUSTIFIED 资料*右对齐
UNDER <g> 正对在资料项<g>的下面显示
NO-GAP 紧接着显示,不留空格
USING EDIT MASK <m>: 使用内嵌子元显示, 如 12:03:20
USING NO EDIT MASK: 不使用内嵌子元
NO-ZER 数字前面 0 的部分不显示
NO-SIGN: 不显示正负号
DECIMALS <d>: 显示 <d> 位小数
EXPOENT <e>: F(浮点数)指数的值
ROUND <r>: 四舍五入至小数点后<r>位
CURRENCY <c>: 币别显示
DD/MM/YY : 日期显示格式
MM/DD/YY:
YY/MM/DD:
YY/DD/MM
MM/DD/YYYY:
DD/MM/YYYY
YYYY/MM/DD:
YYYY/DD/MM:
例如1: WRITE: /10(6) 'ABCDEFGHIJK'.
输出结果为: ABCDEF
例如2: DATA: X TYPE I VALUE '11:20:30',
A(5) TYPE C VALUE 'AB CDE'.
WRITE: / X USING EDIT MASK '__:__:__'.
WRITE: / X USING EDIT MASK '$___,___'.
WRITE: / Y NO-GAP.
输出结果为:
11:20:30
$112,030
ABCDEF
例如3: DATA: LEN TYPE I VALUE 10,
POS TYPE I VALUE 11,
TEXT(10) VALUE '1234567890'
WRITE 'The text ------------ appears in the text.'.
WRITE AT POS(LEN) TEXT.
WRITE TO 语句的基本 形式
要将值(文字)或源字段内容写入目标字段，可以使用 WRITE TO 语句：
语法
WRITE <F1> TO <F2> [<option>].
DATA: NUMBER TYPE F VALUE '4.3',
TEXT(10),
FLOAT TYPE F,
PACK TYPE P DECIMALS 1.
WRITE NUMBER.
WRITE NUMBER TO TEXT EXPONENT 2.
WRITE / TEXT.
WRITE NUMBER TO FLOAT.
WRITE / FLOAT.
WRITE NUMBER TO PACK.
WRITE / PACK.
MOVE NUMBER TO PACK.
WRITE / PACK.
exp:
DATA: NAME(10) VALUE 'SOURCE',
SOURCE(10) VALUE 'Antony',
TARGET(10).
...
WRITE (NAME) TO TARGET.
WRITE: TARGET.
exp :
DATA: COUNTER TYPE I.
COMPUTE COUNTER = COUNTER + 1.
COUNTER = COUNTER + 1.
ADD 1 TO COUNTER.
在此，三条运算语句进行相同算术运算
输出屏幕上的线和空行
用下列语法，可以在输出屏幕上生成水平线：
语法
ULINE [AT [/][<pos>][(<len>)]].
它等同于
WRITE [AT [/][<pos>][(<len>)]] SY-ULINE.
AT 后的格式规范，与在在屏幕上定位 WRITE 输出(页 28)中为 WRITE 语句说明的格式规范完全一样。
如果没有格式规范，系统则开始新的一行，并用水平线填充该行。否则，只按指定输出水平线。
生成水平线的另一种方法，是在 WRITE 语句中键入恰当数量的连字符，如下所示：
WRITE [AT [/][<pos>][(<len>)]] '-----...'.
垂直线
用下列语法 ，可以在输出屏幕上生成垂直线：
语法
WRITE [AT [/][<pos>]] SY-VLINE.
或
WRITE [AT [/][<pos>]] '|'.
空行
用下列语法 ，可以在输出屏幕上生成空行：
语法
SKIP [<n>].
该语句从当前行开始，在输出屏幕上生成 <n> 个空行。如果没有指定 <n> 的值，就输出一个空行 。
要将输出定位在屏幕的指定行上，请使用：
语法
SKIP TO LINE <n>.
该语句允许将输出位置向上或向下移动。
四. 显示图示:
语法: WRITE: <symbol-name> AS SYMBOL.
WRITE: <icon-name> AS ICON.
例如: INCLUDE <SYMBOL>.
INCLUDE <ICON>.
WRITE: / 'Phone symbol:', SYM_PHONE AS SYMBOL.
WRITE: / 'Alarm Icon:', ICON_VOICE_OUTPUT AS ICON.
要查看系统所提供有那些符号及图示,可选择'EDIT'下的'Insert Statement',选择'Write',接下来选择要查看的群组,如SYMBOL 或ICON, 接下来按'Display'即可.
*-------------------------------------------------------------------------------------*
一. Internal Table 的声明
ABAP/4中的Internal Table是一种Data Structure,类似于其他语言中的STRUTURE,它可以由几个不同类型的栏位(field)组成,用来表示具有不同属性的某一事物,单独一笔资料表示某个事物,多笔资料表示具有相同属性的多个事物.
Internal table 的定义有以下几种格式:
格式一. DATA: BEGIN OF <internal table> OCCURS <n>,
<field 1> TYPE <type1>,
[<field 2> TYPE <type 2>,
<field 3> TYPE <type 3>,
… ]
END OF <internal table>.
语法:
DATA <f> <type> OCCURS <n> [WITH HEADER LINE]
Example:
DATA VECTOR TYPE I OCCURS 10 WITH HEADER LINE.
格式二. TYPES: BEGIN OF <work area>,
<field 1> TYPE <type1>,
[<field 2> TYPE <type 2>,
<field 3> TYPE <type 3>,
… ]
END OF <work area>.
TYPES <internal table> TYPE <work area> OCCURS <n>.
格式三. DATA: BEGIN OF <work area>.
INCLUDE STRUCTURE <table name>.
DATA: END OF <work area>.
DATA: <internal table> LIKE <work area> OCCURS <n>.
exp:
TYPES VECTOR TYPE I OCCURS 10.
TYPES: BEGIN OF LINE,
COLUMN1 TYPE I,
COLUMN2 TYPE I,
COLUMN3 TYPE I,
END OF LINE.
TYPES ITAB TYPE LINE OCCURS 10.
TYPES: BEGIN OF DEEPLINE,
TABLE1 TYPE VECTOR,
TABLE2 TYPE ITAB,
END OF DEEPLINE.
TYPES DEEPTABLE TYPE DEEPLINE OCCURS 10.
本示例创建与上例相同的内表数据类型(VECTOR 和 ITAB)。然后创建数据类型 DEEPLINE 作为字段串，包含这些内表作为组件。通过该字段串，数据类型 DEEPTABLE 被创建为内表。因此该内表的元素本身就是内表。
exp :
TYPES: BEGIN OF LINE,
COLUMN1 TYPE I,
COLUMN2 TYPE I,
COLUMN3 TYPE I,
END OF LINE.
TYPES ITAB TYPE LINE OCCURS 10.
DATA TAB1 TYPE ITAB.
DATA TAB2 LIKE TAB1 WITH HEADER LINE.
同创建内表数据类型(页 99)中所示，该示例创建数据类型 ITAB 作为内表。通过使用 DATA 语句的 TYPE 参数引用 ITAB，使数据对象 TAB1 与 ITAB 结构相同。通过使用 DATA 语句的 LIKE 参数引用 TAB1，使数据对象 TAB2 结构相同。创建的 TAB2 带表头行。因此，可以在程序中使用 TAB2-COLUMN1、TAB2-COLUMN2 和 TAB2-COLUMN3 等定位表格工作区域 TAB2。
exp :
DATA FLIGHT_TAB LIKE SFLIGHT OCCURS 10.
本示例创建数据对象 FLIGHT_TAB， 其结构与数据库表格 SFLIGHT 相同。
本示例介绍 如何采用两种不同的步骤创建同一内表。
TYPES VECTOR_TYPE TYPE I OCCURS 10.
DATA VECTOR TYPE VECTOR_TYPE WITH HEADER LINE.
在此创建一个内表数据类型 VECTOR_TYPE，其行包含首先创建的基本类型 I 字段。然后，通过引用 VECTOR_TYPE 创建数据对象 VECTOR。通过使用 WITH HEADER LINE 选项还创建表格工作区域 VECTOR。在这种情况下，表格工作区域包含一种类型 I 字段，可以通过名称 VECTOR 定位。
DATA VECTOR TYPE I OCCURS 10 WITH HEADER LINE.
在这种情况下，通过直接在 DATA 语句中使用 OCCURS 选项创建完全一样的数据类型 VECTOR。
*-------------------------------------------------------------------------------------*
1. TYPES type.
2. TYPES type(len).
3. TYPES: BEGIN OF structype ...
END OF structype.
4. TYPES itabtype {TYPE tabkind OF linetype LIKE tabkind OF lineobj}
[WITH [UNIQUE|NON-UNIQUE] keydef] [INITIAL SIZE n].
5. TYPES itabtype TYPE RANGE OF type.
TYPES itabtype LIKE RANGE OF f.
6. TYPES itabtype {TYPE linetype|LIKE lineobj} OCCURS n.
*-------------------------------------------------------------------------------------*
APPEND LINE
格式：APPEND <work area> TO <internal table>
举例一：(使用WORK AREA)
DATA : BEGIN OF LINE,
COL1 TYPE I,
COL2 TYPE I,
END OF LINE.
DATA ITAB LIKE LINE OCCURS 10.
DO 2 TIMES.
LINE-COL1 = SY-INDEX.
LINE-COL2 = SY-INDEX ** 2.
APPEND LINE TO ITAB.
ENDDO.
LOOP AT ITAB INTO LINE.
WRITE : / LINE-COL1,LINE-COL2.
ENDLOOP.
举例二 (不使用WORK AREA)
DATA : BEGIN OF ITAB OCCURS 10,
COL1 TYPE I,
COL2 TYPE I,
END OF ITAB.
DO 2 TIMES.
ITAB-COL1 = SY-INDEX.
ITAB-COL2 = SY-INDEX ** 2.
APPEND ITAB.
ENDDO.
LOOP AT ITAB.
WRITE : / ITAB-COL1,ITAB-COL2.
ENDLOOP.
exp:
DATA: BEGIN OF ITAB OCCURS 10,
COL1 TYPE C,
COL2 TYPE I,
END OF ITAB.
DO 3 TIMES.
APPEND INITIAL LINE TO ITAB.
ITAB-COL1 = SY-INDEX. ITAB-COL2 = SY-INDEX ** 2.
APPEND ITAB.
ENDDO.
LOOP AT ITAB.
WRITE: / ITAB-COL1, ITAB-COL2.
ENDLOOP.
举例三. (加入另一个Internal table的元素)
格式: APPEND LINES OF <itab1> [FROM <n1> ] [TO <n2>] TO <itab2>.
将<itab1>的元素加入至<itab2>中,可选取自<n1>至<n2>的范围.
APPEND LINES OF ITAB TO JTAB.
COLLECT LINE
COLLECT 指令也是将元素加入Internal table中，与APPEND 的区别是: COLLECT指令在非数值栏位相同的情况下，将数值栏位汇总.
格式: COLLECT [<work area> INTO ] <itab>
DATA: BEGIN OF ITAB OCCURS 3,
COL1(3) TYPE C,
COL2 TYPE I,
END OF ITAB.
ITAB-COL1 = 'ABC'. ITAB-COL2 = 10.
COLLECT ITAB.
ITAB-COL1 = 'XYZ'. ITAB-COL2 = 20.
COLLECT ITAB.
ITAB-COL1 = 'ABC'. ITAB-COL2 = 80.
COLLECT ITAB.
此时, internal table中放的是2笔数据, 分别为:
ITAB-COL1 ITAB-COL2
'ABC' 90
'XYZ' 20
*-------------------------------------------------------------------------------------*
INSERT LINE
将元素插入在指定的internal table位置之前.
格式: INSERT [<wa> INTO] [INITIAL LINE INTO ] <itab> [INDEX <idx>]
或者: INSERT LINES OF <itab1> [FROM <n1> TO <n2>] INTO <itab2> INDEX <idx>
其中: <wa>即work area,工作区中的元素.
[INITIAL LINE INTO] :插入一笔初始化的记录.
<itab>: internal table
[INDEX <idx>]: internal table 的记录号.(新加入的元素放在此记录前面)
Example:
DATA: BEGIN OF LINE,
COL1 TYPE I,
COL2 TYPE I,
END OF LINE.
DATA ITAB LIKE LINE OCCURS 10.
DO 3 TIMES.
LINE-COL1 = SY-INDEX *10.
LINE-COL2 = SY-INDEX *20.
APPEND LINE INTO ITAB.
ENDDO.
LINE-COL1=100.
LINE-COL2=200.
INSERT LINE INTO ITAB INDEX 2. "插入在位置2之前
LOOP AT ITAB INTO LINE.
WRITE: / SY-TABIX,LINE-COL1,LINE-COL2. "SY-TABIX为Table位置
ENDLOOP.
执行结果:
1 10 20
2 100 200 "插入的元素
3 20 40
4 30 60
插入另一Internal Table元素
语法:
INSERT LINES OF <itab1> [FROM <n1> TO <n2>] TO <itab2> INDEX <idx>
将<itab1>的元素插入至<itab2>中, 位置在 <idx>之前, 可选取自<n1>至<n2>的范围
Example:
APPEND LINES OF ITAB TO JTAB INDEX 3.
将ITAB所有元素插入JTAB中, 位置在第三个元素之前
*-------------------------------------------------------------------------------------*
读取internal table
格式一:
LOOP AT <itab> [INTO <wa>][FROM <n1> TO <n2>][WHERE <conditions>]
<statement>
ENDLOOP.
Example:
LOOP AT ITAB INTO LINE WHERE COL1 >100.
WRITE: / SY-TABIX,LINE-COL1.
ENDLOOP.
仅读取 COL1 > 100 的元素
格式二:
READ TABLE <itab> [INTO <wa>] [INDEX <idx> / WITH KEY <conditions>]
举例. (格式二)
DATA: BEGIN OF ITAB OCCURS 10,
COL1 TYPE I,
COL2 TYPE I,
END OF ITAB.
DO 10 TIMES.
ITAB-COL1 = SY-INDEX.
ITAB-COL2 = SY-INDEX * 2.
APPEND ITAB.
ENDDO.
READ TABLE ITAB INDEX 3.
(或者: READ TABLE ITAB WITH KEY COL1 = 3.)
WRITE: / 'ITAB-COL1 = ', ITAB-COL1, 'ITAB-COL2 = ', ITAB-COL2.
执行结果同样是:
ITAB-COL1 = 3
ITAB-COL2 = 6.
Example:
READ TABLE ITAB INTO LINE INDEX 5
读取 ITAB的第5个元素资料, 放入 LINE的栏位中
根据栏位内容寻找
语法:
READ TABLE <itab> INTO <wa>
Example:
ITAB-COL1 = 'ABC'.
READ TABLE ITAB INTO LINE.
找出ITAB 中 COL1 栏位内容是 ABC 的元素, 找到的值放入 LINE 中
若找到 SY-SUBRC传回0, 找不到则传回 4, <itab>必须声明有 work area
*-------------------------------------------------------------------------------------*
修改internal table 中的值
格式: MODIFY <itab> [FROM <wa>][INDEX <idx>][TRANSPORTING <f1><f2>…][WHERE <conditions>]
举例一. READ TABLE ITAB INDEX 3.
LINE-COL1 = 29.
MODIFY ITAB FROM LINE TRANSPORTING COL1.
将第三笔记录的COL1栏位的值修改为29.
举例二. T_SALARY - salary = 50.
MODIFY T_SALARY TRANSPORTING salary WHERE birthday = '1999/12/06'.
DELETE internal table中的栏位
格式: DELETE <itab> INDEX <idx>.
或: DELETE <itab>[FROM <n1> TO <n2>] [WHERE <conditions>]
Internal table 排序
SORT <itab> [<order way>][BY <f1><f2>…]
其中:<order way> 有DESCENDING 和ASCENDING, Default 为ASCENDING.
<f1>: 为指定排序的栏位.
Example:
SORT ITAB DESCENDING BY COL2.
将 ITAB 根据 COL2栏位递减排序
*-------------------------------------------------------------------------------------*
确定内表属性
如果在处理过程中想知道内表一共包含多少行，或者想知道定义的 OCCURS 参数的大小，请使用 DESCRIBE 语句，用法如下：
语法
DESCRIBE TABLE <itab> [LINES <lin>] [OCCURS <occ>].
如果使用 LINES 参数，则将填充行的数量写入变量 <lin>。如果使用 OCCURS 参数，则将行的初始号写入变量 <occ>。
DATA: BEGIN OF LINE,
COL1 TYPE I,
COL2 TYPE I,
END OF LINE.
DATA ITAB LIKE LINE OCCURS 10.
DATA: LIN TYPE I, OCC TYPE I.
DESCRIBE TABLE ITAB LINES LIN OCCURS OCC.
WRITE: / LIN, OCC.
DO 1000 TIMES.
LINE-COL1 = SY-INDEX.
LINE-COL2 = SY-INDEX ** 2.
APPEND LINE TO ITAB.
ENDDO.
DESCRIBE TABLE ITAB LINES LIN OCCURS OCC.
WRITE: / LIN, OCC.
其输出为：
0 10
1.000 10
在此创建内表 ITAB。在填充表格前后执行 DESCRIBE 语句。更改当前行号，但无法更改初始行号。
*-------------------------------------------------------------------------------------*
加总
SUM.
总和计算存放与work area中,但只能在LOOP 中使用.
例: LOOP AT ITAB INTO LINE.
SUM.
ENDLOOP.
WRITE: / LINE-COL1, LINE-COL2.
LINE-COL1 和 LINE-COL2 存数值总和初始化internal table
REFRESH <itab>. 清空<itab>中的值.使用在没有 HEADER LINE 的 Internal Table中, 清除所有元素
CLEAR <itab>. 清空<itab>的Header Line.使用在有 HEADER LINE 的 Internal Table中, 清除所有元素
FREE <itab>. 释放内存空间.释放(Release) Internal Table所占的内存空间, 用在 REFRESH和 CLEAR指令之后
将值重置为 默认值
可以用 CLEAR 语句重置任何数据对象值，如下所示：
语法
CLEAR <f>.
exp:
DATA NUMBER TYPE I VALUE '10'.
WRITE NUMBER.
CLEAR NUMBER.
WRITE / NUMBER.
输出为：
10
0
CLEAR 语句将字段 NUMBER 的内容从10 重置为默认值 0。
*-------------------------------------------------------------------------------------*
添加字段顺序并将结果赋给另一个字段
语法
ADD <n1> THEN <n2> UNTIL <nz> GIVING <m>.
如果 <n1>、 <n2>、 ... 、 <nz> 是在内存中相同类型和长度的等距字段序列，则进行求和计算并将结果赋给 <m>
添加字段顺序并将结果添加到另一个字段的内容中
语法
ADD <n1> THEN <n2> UNTIL <nz> TO <m>.
该语句除了将字段总和添加到 <m> 的旧内容中之外，与上面语句的工作方式相同 。
有关其它相似变体的信息，参见有关 ADD 语句的关键字文档。
DATA: BEGIN OF SERIES,
N1 TYPE I VALUE 10,
N2 TYPE I VALUE 20,
N3 TYPE I VALUE 30,
N4 TYPE I VALUE 40,
N5 TYPE I VALUE 50,
N6 TYPE I VALUE 60,
END OF SERIES.
DATA SUM TYPE I.
ADD SERIES-N1 THEN SERIES-N2 UNTIL SERIES-N5 GIVING SUM.
WRITE SUM.
ADD SERIES-N2 THEN SERIES-N3 UNTIL SERIES-N6 TO SUM.
WRITE / SUM.
输出如下：
150
350
在此，将 N1 到 N5 组件内容求和并将其值赋给字段 SUM。然后，将 N2 到 N6 组件求和并将其添加到 SUM 的值中。
*-------------------------------------------------------------------------------------*
屏幕输入命令
在ABAP/4中要从屏幕输入变量, 使用的命令是 PARAMETERS 及SELECTION-OPTIONS:
1. PARAMETER: 输入一个变量或栏位内容
2. SELECTION-OPTIONS: 使用条件筛选画面来输入数据
PARAMETERS 指令
基本的输入命令, 类似如BASIC的INPUT命令, 但无法使用F格式(浮点数)
语法:
PARAMETERS <p> [DEFAULT <f>] [LOWER CASE]
[OBLIGATORY] [AS CHECKBOX]
[RADIOBUTTON GROUP <rad>]
Example:
PARAMETERS: NAME(8),
AGE TYPE I,
BIRTH TYPE D.
执行结果:
在日期的输入格式上为 MM/DD/YY , MM/DD/YYYY, MMDDYY或MMDDYYYY , 如输入 020165 表 1965年02月01日, 与02/01/65的输入是一样的, 日期输入范围为西元1950年至2049年
1. DEFAULT
设定输入的预设值
Example:
PARAMETERS: COMPANY(20) DEFAULT 'DELTA',
BIRTH TYPE D DEFAULT '19650201'.
2. LOWER CASE
ABAP/4预设是将字串输入值自动转换为大写, 加上此参数会将输入的资料转成小写,
3. OBLIGATORY
强制要求输入, 屏幕上会出现一个 ? , 使用者必须要输入才可.
4. AS CHECKBOX
输入 CHECKBOX的格式
Example:
PARAMETERS: TAX AS CHECKBOX DEFAULT 'X',
NTD AS CHECKBOX.
执行结果:
5. RADIOBUTTON GROUP <rad>
输入 RADIO BUTTON GROUP 的方式
Example:
PARAMETERS: BOY RADIOBUTTON GROUP SEX DEFAULT 'X',
GIRL RADIOBUTTON GROUP SEX.
exp :
TABLES SPLFI.
PARAMETERS: LOW LIKE SPFLI-CARRID,
HIGH LIKE SPFLI-CARRID.
SELECT * FROM SPLFI WHERE CARRID BETWEEN LOW AND HIGH.
........
ENDSELECT.
*-------------------------------------------------------------------------------------*
SELECTION-OPTIONS
SELECTION-OPTIONS所输入的值实际上是放在internal table中的,该Internal table 有四个栏位,分别是:SIGN,OPTION,LOW,HIGH.. 条件筛选检查条件输入画面指令, 输入条件后可配合SELECT指令自TABLE读取符合条件的资料, 直接执行或放入 Internal Table中, 条件有四个参数:
1. SIGN:
I: 表筛选条件符合的资料
E: 表筛选条件不符合的资料
2. OPTION: 比较的条件符号
EQ(等于),NE(不等于),GT(大于),LE(小于),CP(包含),NP(不包含)
3. LOW: 最小值
4. HIGH: 最大值
语法:
SELECTION-OPTIONS <check-option> FOR <table-field>
Example:
TABLES SPFLI.
SELECT-OPTIONS AIRLINE FOR SPFLI-CONNID.
将条件的输入值存放入 AIRLINE, 筛选选择为SPFLI中的CONNID栏位
改变条件输入格式
1. DEFAULT <begin> TO <end>
设定开始结束范围输入预设值
Example:
SELECT-OPTIONS AIRLINE FOR SPFLI-CONNID DEFAULT '2042' TO '4555'.
2. NO-EXTENSION
设定不要Multi-Option输入画面
3. NO INTERVALS
设定不要区间范围输入画面
4. LOWER CASE
输入转换成大写
5. OBLIGATORY
强制要求输入
*-------------------------------------------------------------------------------------*
配合 SELECT 命令
条件输入完后要将符合条件的资料筛选出来, 可配合使用 SELECT 指令
1.使用WHERE <条件式>
Example:
TABLES SPFLI.
SELECT-OPTIONS AIRLINE FOR SPFLI-CONNID.
SELECT * FROM SPFLI WHERE CONNID IN AIRLINE.
WRITE: / SPFLI-CONNID,SPFLI-CITYFROM,SPFLI-CITYTO.
ENDSELECT.
2.使用CHECK参数
Example:
TABLES SPFLI.
SELECT-OPTIONS AIRLINE FOR SPFLI-CONNID.
SELECT * FROM SPFLI.
CHECK AIRLINE.
WRITE: / SPFLI-CONNID,SPFLI-CITYFROM,SPFLI-CITYTO.
ENDSELECT.
*
exp:
TABLES SPFLI.
SELECT-OPTIONS: S_CARRID FOR SPFLI-CARRID,
S_CITYFR FOR SPFLI-CITYFROM,
S_CITYTO FOR SPFLI-CITYTO,
S_CONNID FOR SPFLI-CONNID.
SELECT * FROM SPFLI.
CHECK: SPFLI-CARRID IN S_CARRID,
SPFLI-CITYFR IN S_CITYFR,
SPFLI-CITYTO IN S_CITYTO,
SPFLI-CONNID IN S_CONNID.
WRITE: / SPFLI-CARRID, SPFLI-CONNID,
SPFLI-CITYFROM, SPFLI-CITYTO.
ENDSELECT.
3.使用 IF … IN 关键字
Example:
SELECT-OPTIONS AIRLINE FOR SPFLI-CONNID.
SELECT * FROM SPFLI.
IF SPFLI-CONNID IN AIRLINE.
WRITE: / SPFLI-CONNID,SPFLI-CITYFROM,SPFLI-CITYTO.
ENDIF.
ENDSELECT.
*-------------------------------------------------------------------------------------*
SELECTION-SCREEN
1.产生空白列
语法:
SELECTION-SCREEN SKIP [<n>]
Example:
SELECTION-SCREEN SKIP 2.
产生两列空白列
2.产生底线
语法:
SELECTION-SCREEN ULINE / <pos>(length)
Example:
SELECTION-SCREEN ULINE /10(30).
自第10格开始产生长度30的底线
3.印出备注说明
语法:
SELECTION-SCREEN COMMENT / <pos>(length) <name>
Example:
REMARK = 'Pls enter your name'.
SELECTION-SCREEN COMMENT /10(30) REMARK.
4. 同一列中输入数个资料项
语法:
SELECTION-SCREEN BEGIN OF LINE.
……
SELECTION-SCREEN END OF LINE.
Example:
SELECTION-SCREEN BEGIN OF LINE.
SELECTION-SCREEN POSITION 20.
PARAMETERS NAME(10).
SELECTION-SCREEN POSITION 40.
PARAMETERS BIRTH TYPE D.
SELECTION-SCREEN END OF LINE.
在20格输入NAME内容, 40格输入 BIRTH的内容
5. 绘出BLOCK PANEL
语法:
SELECTION-SCREEN BEGIN OF BLOCK <block>
[WITH FRAME [TITLE <title>].
…….
SELECTION-SCREEN END OF BLOCK <block>.
Example:
SELECTION-SCREEN BEGIN OF BLOCK RADIO WITH FRAME .
PARAMETER R1 RADIOBUTTON GROUP GR1.
PARAMETER R2 RADIOBUTTON GROUP GR1.
PARAMETER R3 RADIOBUTTON GROUP GR1.
SELECTION-SCREEN END OF BLOCK RADIO.
*-------------------------------------------------------------------------------------*
SQL语法
我们在编写ABAP4程序的时候,经常需要从TABLE中根据某些条件读取数据,读取数据最常用的方法就是通过SQL语法实现的。ABAP/4中可以利用SQL语法创建或读取TABLE，SQL语法分为DDL(DATA DEFINE LANGUAGE)语言和DML(DATA MULTIPULATION LANGUAGE)语言，DDL语言是指数据定义语言，例如CREATE等, DML语言是数据操作语言，例如SELECT, INSERT等语句。SQL语句有OPEN SQL语句和NATIVE SQL语句。 OPEN SQL语句不是标准SQL语句，是ABAP/4语言，利用OPEN SQL语句能在Databases 和 Command 之间产生一个BUFFER，所以它有一个语言转换的过程。而NATIVE SQL语句则是标准的SQL语句, 它直接针对Databases操作。
OPEN SQL
SELECT语句
语法格式:
SELECT <result> [INTO <target>] [FROM <source>] [WHERE <condition>]
[GROUP BY <fields>] [ORDER BY <sort order>]
其中: <result>指定要抓取的栏位
<target>将读取的记录存放在work area中
<source>指定从那个TABLE中读取资料
<condition>抓取资料的条件
<fields>指定按那些栏位分组
<sort order>排序的栏位及方式
相关的系统变量:
SY-SUBRC = 0 表示读取数据成功
<> 0 表示未找到符合条件的记录
SY-DBLNT: 被处理过的记录的笔数.
相关的命令:
EXIT. 退出循环.
CHECK <logistic statement>.如果逻辑表达式成立，则继续执行，否则，开始下一次循环。
利用循环方式读取所有记录
SELECT ….ENDSELECT.是循环方式读取记录的。
例如:
TABLES MARD.
SELECT [DISTINCT] * FROM MARD WHERE MATNR = '3520421700'.
<Statements>.
ENDSELECT.
(从MARD中抓取所有料号=3520421700的资料)
◆读取一笔资料
Example:
TABLES SPFLI.
SELECT SINGLE * FROM SPFLI
WHERE PLANT ='CHUNGLI' AND TEL='4526174'.
WRITE: / SPFLI-COMPANY,SPFLI-PLANT,SPFLI-TEL.
◆将读取的记录放在work area中,并且加入Internal table 中.
格式有:
... INTO <work area>
... INTO CORRESPONDING FIELDS OF <work area>
... INTO (f1, ..., fn) 变量组.
... INTO TABLE <internal table>
... INTO CORRESPONDING FIELDS OF TABLE <internal table>
... APPENDING TABLE <internal table>
... APPENDING CORRESPONDING FIELDS OF TABLE <internal table>
举例一:
TABLES MARD.
DATA: BEGIN OF ITAB OCCURS 10,
MATNR LIKE MARD-MATNR,
WERKS LIKE MARD-WERKS,
LGORT LIKE MARD-LGORT,
LABST LIKE MARD-LABST,
END OF ITAB.
SELECT MATNR WERKS LGORT LABST
INTO CORRESPONDING FIELDS OF ITAB
FROM MARD
WHERE MATNR = '3520421700'.
APPEND ITAB.
CLEAR ITAB.
ENDSELECT.
(将读取的结果放在Internal table ITAB中)
DATA: BEGIN OF WA,
LINE(240),
END OF WA.
DATA NAME(10).
NAME = 'SPFLI'.
SELECT * FROM (NAME) INTO WA.
WRITE: / WA-LINE.
ENDSELECT.
数据库表名称 SPFLI 被赋给字符字段 NAME。SELECT 语句将所有的行从 SPFLI 中读到目标区 WA 中。在该示例中，WA 与 SPFLI 的结构并不相同，每一行都将自动地转换成字符字段.
举例二.
TABLES MARD.
SELECT MATNR MTART MAKTX INTO (t_matnr, t_mtart, maktx)
FROM MARD
WHERE MATNR = '3520421700'.
<Statements>.
ENDSELECT.
(从MARD中抓取料号=3520421700的料号、类型和描述,放在变量t_matnr, t_mtart, maktx中)。
Example:
TABLES SPFLI.
DATA WA LIKE TABLES.
SELECT * FROM SPFLI INTO WA.
WRITE: / WA-COMPANY,WA-PLANT.
ENDSELECT.
逐笔写入WA 工作区中
举例三.
将读取的资料写入 Initial Table 中
语法:
SELECT .. INTO TABLE <itab>
Example:
TABLES SPFLI.
DATA ITAB LIKE SPFLI OCCURS 10 WITH HEADER LINE.
SELECT * FROM SPFLI INTO ITAB.
一次读10笔(Initial Table的长度)记录存入 ITAB 中
SELECT .. INTO TABLE <itab> PACKAGE SIZE <n>
一次读取 <n> 笔记录至 <itab>中
Example:
TABLES SPFLI.
DATA ITAB LIKE SPFLI OCCURS 10 WITH HEADER LINE.
SELECT * FROM SPFLI INTO ITAB PACKAGE SIZE 5.
一次读取 5 笔记录
exp :
TABLES SPFLI.
DATA: BEGIN OF WA,
NUMBER TYPE I VALUE 1,
CITYFROM LIKE SPFLI-CITYFROM,
CITYTO LIKE SPFLI-CITYTO,
END OF WA.
SELECT * FROM SPFLI INTO CORRESPONDING FIELDS OF WA.
WRITE: / WA-NUMBER, WA-CITYFROM, WA-CITYTO.
ENDSELECT.
输出如下所 示：
在该示例中，系统只将数据库表 SPFLI 中选定行的列 CITYFROM 和 CITYTO 传送到 WA 中。WA 中的组件 NUMBER 保持不变。
*-------------------------------------------------------------------------------------*
按指定的栏位排序
TABLES SBOOK.
SELECT * FROM SBOOK WHERE CARRID = 'LH' AND
CONNID = '0400' AND
FLDATE = '19950228'
ORDER BY BOOKID ASCENDING.
WRITE: / SBOOK-BOOKID, SBOOK-CUSTOMID,
SBOOK-CUSTTYPE, SBOOK-SMOKER,
SBOOK-LUGGWEIGHT, SBOOK-WUNIT,
SBOOK-INVOICE.
ENDSELECT.
(利用参数ORDER BY所指定的栏位排序)
*-------------------------------------------------------------------------------------*
◆ 抓取数据的条件关键字
(1) BETWEEN <g1> AND <g2>
例如: WHERE YEAR BETWEEN 1995 AND 2000.
(2) LIKE <g>
例如: WHERE NAME LIKE 'MIKE%'.
('%'是通配符号)
(3) IN (<g1>…<gn>)
是<g1>…<gn>里面的任意一个值即可.
例如: WHERE PLANT IN ('CHUNGLI', 'TAOYUAN','LIUTU').
(表示PLANT 只要是'CHUNGLI'或'TAOYUAN'或'LIUTU'都可以).
(4) ORDER BY 关键字
指定排序的栏位或顺序
(1). ..ORDER BY PRIMARY KEY.
根据 PRIMARY KEY 递增排序
(2)…ORDER BY <f1> [DESCENDING] <f2> [DESCENDING]
Example:
SELECT * FROM IM ORDER BY PART .
*-------------------------------------------------------------------------------------*
INSERT 语句
◆从work area 加入到Internal Table中
格式: INSERT INTO <database> VALUES <work area>
例如:
DATA: BEGIN OF WA,
CODE(6) TYPE C,
NAME(30) TYPE C,
END OF WA.
DATA: VEN LIKE WA OCCURS 10.
…
WA-CODE = '530120'.
WA-NAME = 'XINGDA ELECTRONICS CO.,LTD'.
INSERT INTO VEN VALUES WA .
如果work area的名称就是internal table的名称,可以直接写成:
INSERT <internal table>
例如:
DATA: BEGIN OF WA OCCURS 10,
CODE(6) TYPE C,
NAME(30) TYPE C,
END OF WA.
…
WA-CODE = '530120'.
WA-NAME = 'XINGDA ELECTRONICS CO., LTD'.
INSERT WA.
◆从另外一个Internal table中INSERT 资料
格式:
INSERT <itab1> FROM TABLE <itab2> [ACCEPTING DUPLICATE KEY]
将<itab2>中非NULL的资料加入<itab1>中,加上[ACCEPTING DUPLICATE KEY]能限制相同PRIMARY KEY不重复加入.
加入一笔记录至资料库
1.自 Work Area 工作区
语法:
INSERT INTO <database> VALUES <wa>
Example:
TABLES SPFLI.
DATA WA LIKE SPFLI.
WA-NO = '34051920'.
WA-COMPANY='DELTA'.
INSERT SPFLI VALUES WA.
将 ITAB 资料加入 SPFLI中, 也可写成 INSERT SPFLI FROM ITAB.
SPFLI-NO='34299876'.
SPFLI-COMPANY='HP'.
INSERT SPFLI FROM SPFLI.
将Work Area SPFLI中的资料加入资料库档案 SPFLI中
因Work Area SPFLI的结构与资料档 SPFLI一样, 所以也可
写成 INSERT SPFLI.
2.自 Internal Table
语法:
INSERT <database> FROM TABLE <itab> [ACCEPTING DUPLICATE KEY]
将 <itab>中非 NULL的资料加入 <database>中, 加上 [ACCEPTING DUPLICATE
KEY]能检查不加入有重覆primary key, 若有重覆则 SY-SUBRC 会传回 4
Example:
TABLES SPFLI.
DATA ITAB LIKE SPFLI OCCURS 10 WITH HEADER LINE.
ITAB-NO = '34051920'.
ITAB-COMPANY = 'DELTA'.
APPEND ITAB.
….
INSERT SPFLI FROM TABLE ITAB
ACCEPTING DUPLICATE KEY.
*-------------------------------------------------------------------------------------*
UPDATE 指令
异动已存在的记录内容
1.使用 Primary Key
语法:
UPDATE <database> FROM <wa>
Example:
TABLES SPFLI.
DATA WA LIKE SPFLI.
WA-NO='34051920'.
WA-COMPANY='DELTA'.
UPDATE SPFLI FROM WA.
如 SPFLI 的 Primary Key是 NO, 则会找到 NO='34051920'的记录, 将其 COMPANY栏位异动为 DELTA
2.使用条件式
语法:
UPDATE <database> SET < f1>=<values>… WHERE <condition>
根据条件式异动符合条件式的记录
Example:
UPDATE SPFLI SET NO ='34051920'
COMPANY = 'DELTA'
WHERE TEL = '4526107'.
*-------------------------------------------------------------------------------------*
3. MODIFY 语法
MODIFY <internal table> [FROM <work area>].
根据 Primary Key 寻找资料档中符合的记录, 若找到则更新异动, 若找不到则新增记录
语法:
MODIFY <database> FROM <wa>
Example:
WA-NO='34051920'.
WA-COMPANY='DELTA'.
MODIFY SPFLI FROM WA.
4. DELETE 语法
DELETE <internal table> [FROM <work area>].
或: DELETE <internal table> [WHERE <conditions>]
删除资料档的记录
1.使用 Primary Key
语法:
DELETE <database> FROM <wa>
Example:
TABLES SPFLI.
DATA WA LIKE SPFLI.
WA-NO='34051920'.
WA-COMPANY='DELTA'.
DELETE SPFLI FROM WA.
如 SPFLI 的 Primary Key是 NO, 则会找到 NO='34051920'的记录, 找到后将此笔删除
2.使用条件式
语法:
DELETE FROM <database> WHERE <condition>
根据条件式删除符合条件式的记录
Example:
DELETE FROM SPFLI WHERE AREA = 'AMERICAN'.
*-------------------------------------------------------------------------------------*
5. DATABASE CURSOR
Database Cursor是一个资料库暂存区, 将经SELECT指令读取的记录存放至此暂存区, 再由此暂存区放至Work Area中, 可减少资料库读取的次数.
1.开启 Database Cursor
语法:
OPEN CURSOR <c> FOR SELECT … WHERE <condition>
Example:
TABLES SPFLI.
DATA: WA LIKE SPFLI,
C1 TYPE CURSOR.
OPEN CURSOR C1 FOR SELECT * FROM SPFLI
WHERE AREA ='TAIWAN'.
2.读取 Database Cursor的资料存入 Work Area
语法:
FETCH NEXT CURSOR <c> INTO <wa>
Example:
FETCH NEXT CURSOR C1 INTO WA.
读取下一笔Cursor位置的资料存入WA, 如果已无资料可读, SY-SUBRC <>0.
关闭 Database Cursor
语法:
CLOSE CURSOR <c>
Example:
CLOSE CURSOR C1.
*-------------------------------------------------------------------------------------*
COMMIT WORK & ROLLBACK WORK
要确定资料成功写入资料库，可使用COMMIT WORK指令，如:
COMMIT WORK.
相反的，如果反悔要复原，可使用 ROLLBACK WORK, 可复原在上个COMMIT WORK指令之后的资料, 如:
ROLLBACK WORK.
*-------------------------------------------------------------------------------------*
使用NATIVE SQL指令
语法格式:
EXEC SQL [PERFORMING <form>].
<statements>
ENDEXEC.
举例一.
EXEC SQL.
CREATE TABLE AVERI_CLNT (
CLIENT CHAR(3) NOT NULL,
ARG1 CHAR(3) NOT NULL,
ARG2 CHAR(3) NOT NULL,
FUNCTION CHAR(10) NOT NULL,
PRIMARY KEY (CLIENT, ARG1, ARG2)
)
ENDEXEC.
举例二.
DATA: F1(3), F2(3), F3(3).
F3 = ' 1 '
EXEC SQL.
SELECT CLIENT, ARG1 INTO :F1, :F2 FROM AVERI_CLNT
WHERE ARG2 = :F3
ENDEXEC
PERFORMING <form name>的使用:
如果NATIVE SQL的SELECT命令执行结果是抓到多笔记录，我们想要逐笔记录处理时，就用PERFORMING 参数，这个FORM能被逐次调用。如果想中止调用，就用EXIT FORM SQL结束调用。
例如:
DATA: F1(3), F2(3), F3(3).
F3 = '010'
EXEC SQL PERFORMING WRITE_AVERI_CLNT.
SELECT CLIENT, ARG1 INTO :F1, :F2 FROM AVERI_CLNT
WHERE ARG2 = :F3
ENDEXEC.
FORM WRITE_AVERI_CLNT.
WRITE: / F1, F2.
ENDFORM.
DATA: BEGIN OF WA,
NAME(8),
AGE TYPE I,
END OF WA.
DATA F1 TYPE I.
FI = 20.
EXEC SQL PERFORMING OUTPUT.
SELECT NAME,AGE INTO :WA FROM NAME_TABLE
WHERE AGE >= :F1.
ENDEXEC..
FORM OUTPUT.
WRITE: / WA-NAME,WA-AGE.
ENDFORM.
注意:
a. NATIVE SQL把TABLE中的MANDT(client)栏位当作一般栏位使用,所以在抓取资料时必须指定特定的Client;
b. NATIVE SQL中的SELECT语句没有CHECK权限的功能;
c. 在登入SAP R/3系统时,我们已经自动与Database连接,所以在执行NATIVE SQL时并不需要CONNECT语句;
d. 一条NATIVE SQL语句可以以分号;结束,一般情况下是以句号.结束.
e. 某些数据库系统对TABLE名字和FIELD名字有大小写区别,要正确书写.
f. 在NATIVE SQL中,双引号"不表示注释.
*-------------------------------------------------------------------------------------*
结果语句
条件述叙
1. IF 述叙
语法:
IF <Condition1>.
<Statement 1 >
ELSEIF <Condition2>.
<Statement 2>
ELSEIF <Condition3>.
<Stetement 3>
…..
ELSE.
<else Statement >
ENDIF.
(1).在每个判断关键字之后要加上 .
(2).在巢状循环之中无法使用 ELSE 关键字, ELSE 关键字属 IF 关键字
Example:
IF 3 > 8.
WRITE / '3 is less than 8'.
ENDIF.
2. CASE 关键字
语法:
CASE <变量f>.
WHEN <Value1>.
<Statement1>
WHEN <Value2>.
<Statement2>
….
WHEN OTHERS.
<others Statement>
ENDCASE.
Example:
S = 'A'.
CASE S.
WHEN 'X'.
WRITE / 'String is X'.
WHEN OTHERS.
WRITE / 'String is not X'.
ENDCASE.
循环关键字
1.计次循环
语法:
DO [n TIMES] [VARYING <f> FROM <start> TO <end>.
<loop block>
ENDDO.
Example:
DO 2 TIMES.
WRITE / 'X'.
ENDDO.
执行结果:
X
X
DO VARYING I FROM 1 TO 10.
S = S + I.
ENDDO.
WRITE: / ,'1+2+3+…+10=',S
执行结果: 1+2+3+…+10=55
2.条件循环
语法:
WHILE <Condition>.
<Statement Block>
ENDWHILE
Example:
I = 1.
S=0.
WHILE I <= 10.
S = S+I.
I=I+1.
ENDWHILE.
WRITE: / ' 1+2+3+…+10=',S.
执行结果为: 1+2+3+…+10=55
循环控制关键字
1. CONTINUE
跳至循环的下一次
Example:
DO 3 TIMES.
IF SY-INDEX = 2.
CONTINUE.
WRITE / SY-INDEX.
ENDDO.
执行结果:
1
3
2. CHECK <Condition>
CHECK 之后条件成立才继续往下执行循环
Example:
DO 5 TIMES.
CHECK SY-INDEX BETWEEN 2 AND 4.
WRITE / SY-INDEX.
ENDDO.
执行结果:
2
3
4
3. EXIT
跳离循环关键字
Example:
DO 10 TIMES.
IF SY-INDEX = 4.
EXIT.
ENDIF
WRITE / SY-INDEX.
ENDDO.
执行结果:
1
2
3
无穷循环
DO .
<Statement Block>
ENDDO.
无穷循环必须配合 EXIT 关键字来执行
*-------------------------------------------------------------------------------------*
搜索字符串
要搜索特定模式的字符串，请使用 SEARCH 语句，用法如下：
语法
SEARCH <c> FOR <str> <options>.
该语句在字段 <c> 中搜索<str> 中的字符串。如果成功，则将 SY-SUBRC 的返回代码值设置为0并将 SY-FDPOS 设置为字段 <c> 中该字符串的偏移量。否则将 SY-SUBRC 设置为4。
搜索串 <str> 可为下列格 之一：
<str> 目 的
<pattern> 搜索 <pattern>( 任何字符顺序)。忽略尾部空格。
.<pattern>. 搜索 <pattern> ，但是不忽略尾部空格 。
*<pattern> 搜索以 <pattern> 结尾的词。
<pattern>* 搜索以 <pattern> 开始的词。
单词之间用空格、逗号、句号、分号、冒号、问号、叹号、括号、斜杠、加号和等号等分隔 。
DATA STRING(30) VALUE 'This is a little sentence.'.
WRITE: / 'Searched', 'SY-SUBRC', 'SY-FDPOS'.
ULINE /1(26).
SEARCH STRING FOR 'X'.
WRITE: / 'X', SY-SUBRC UNDER 'SY-SUBRC',
SY-FDPOS UNDER 'SY-FDPOS'
SEARCH STRING FOR 'itt '.
WRITE: / 'itt ', SY-SUBRC UNDER 'SY-SUBRC',
SY-FDPOS UNDER 'SY-FDPOS'
SEARCH STRING FOR '.e .'.
WRITE: / '.e .', SY-SUBRC UNDER 'SY-SUBRC',
SY-FDPOS UNDER 'SY-FDPOS'.
SEARCH STRING FOR '*e'.
WRITE: / '*e ', SY-SUBRC UNDER 'SY-SUBRC',
SY-FDPOS UNDER 'SY-FDPOS'.
SEARCH STRING FOR 's*'.
WRITE: / 's* ', SY-SUBRC UNDER 'SY-SUBRC',
SY-FDPOS UNDER 'SY-FDPOS'.
该过程的输 出如下：
SEARCHED SY-SUBRC SY-FDPOS
X 4 0
itt 0 11
.e . 0 15
*e 0 10
s* 0 17
搜索字符字段 <c> 的各种选项 (<options>)如下
ABBREVIATED
在字段 <c> 中搜索包含 <str> 中指定字符串的单词， 其中字符可能被其它字符隔开。单词和字符串的第一个字母必须相同 。
STARTING AT <n1>
在字段 <c> 中搜索从 <n1> 开始的 <str>。结果 SY-FDPOS 参照相对于 <n1> 的偏移量而不是字段的开始。
ENDING AT <n2>
在字段 <c> 搜索 <str> 直到位置 <n2>。
AND MARK
如果找到搜索串，则将搜索串中的所有字符(和使用 ABBREVIATED 时的所有字符)转换为大写形式。
DATA: STRING(30) VALUE 'This is a fast first example.',
POS TYPE I,
OFF TYPE I.
WRITE / STRING.
SEARCH STRING FOR 'ft' ABBREVIATED.
WRITE: / 'SY-FDPOS:', SY-FDPOS.
POS = SY-FDPOS + 2.
SEARCH STRING FOR 'ft' ABBREVIATED STARTING AT POS AND MARK.
WRITE / STRING.
WRITE: / 'SY-FDPOS:', SY-FDPOS.
OFF = POS + SY-FDPOS -1.
WRITE: / 'Off:', OFF.
该过程的输 出如下：
This is a fast first example.
SY-FDPOS: 10
This is a fast FIRST example.
SY-FDPOS: 4
Off: 15
请注意，在找到单词' fast' 之后，为了查找包含' ft'的第二个单词，必须在偏移量 SY-FDPOS 上加2，然后从位置 POS 开始查找。否则，会再次找到单词 'fast'。要获得' first' 相对于字段 STRING 开始的偏移量，从 POS 和 SY-FDPOS 计算。
获得字符串长度
要决定字符串到最后一个字符而不是 SPACE 的长度，请使用内部函数 STRLEN，用法如下：
语法
[COMPUTE] <n> = STRLEN( <c> ).
STRLEN 将操作数 <c> 作为字符数据类型处理，而不考虑其实际类型。不进行转换。
关键字 COMPUTE 可选。有关内部函数的详细信息，参见使用数学函数(页 49) 。
DATA: INT TYPE I,
WORD1(20) VALUE '12345'.
WORD2(20).
WORD3(20) VALUE ' 4 '.
INT = STRLEN( WORD1 ). WRITE INT.
INT = STRLEN( WORD2 ). WRITE / INT.
INT = STRLEN( WORD3 ). WRITE / INT.
结果分别是 5，0 和 4。
*-------------------------------------------------------------------------------------*
Standard Report
一个典型的报表程序是由许多的程序区块(Code Block)所组成，在区块间最好能加上一些说明以利程序可读性，一个典型的报表程序格式如下:
* PROGRAM SOURCE HEADER : 说明程序名称及目的
* Program Name:
* Description:
* Date/Author:
* Table Update:
* Special Logic:
* Include:
*-------------------------------------------------------------------------------------*
* MODIFICATION LOG : 程序修改更新记录
*-------------------------------------------------------------------------------------*
* ChangeDate Programmer Request Description
*-------------------------------------------------------------------------------------*
* NEW PROGRAM
*-------------------------------------------------------------------------------------*
* REPORT NAME : 声明程序名称及报表格式,
*-------------------------------------------------------------------------------------*
REPORT Z_____
NO STANDARD PAGE HEADING
MESSAGE-ID __ " 所使用的MESSAGE
LINE-COUNT ___ " 每页报表列数
LINE-SIZE ___. " 每页报表宽度
* TABLE DESCRIPTION : 声明程序会使用的TABLE
*-------------------------------------------------------------------------------------*
TABLES:
* DATA : 声明程序所使用的变量及自定型态
*-------------------------------------------------------------------------------------*
TYPES:
DATA:
* SELECTION SCREEN / OPTION / PARAMETER : 屏幕输入报表筛选条件
*-------------------------------------------------------------------------------------*
SELECTION-SCREEN BEGIN OF BLOCK ____
SELECT-OPTIONS:
SELECTION-SCREEN END OF BLOCK ___
* INITIALIZATION : 启动程序开始执行, 如SELECT-OPTION及PARAMETER
*-------------------------------------------------------------------------------------*
INITIALIZATION.
INCLUDE ____.
* AT START SELECTION : 输入结束后启动的区块, 如按下<F8>
*-------------------------------------------------------------------------------------*
START-OF-SELECTION.
SET PF-STATUS ____. " 指定报表执行时所用的 GUI-STATUS名称
PERFORM READ_DATA.
PERFORM PROCESS_DATA.
PERFORM PRINT_DATA.
PERFORM PRINT_SUMMARY.
* AT USER Commaand : 执行在GUI-STATUS中自定的命令
*-------------------------------------------------------------------------------------*
AT USER_COMMAND.
* AT LINE SELECTION : 由在报表中按下<F2>或Double-Click启动
*-------------------------------------------------------------------------------------*
AT LINE-SELECTION.
* TOP OF PGAE : 每页开始列印时执行, 用于定义报表表头
*-------------------------------------------------------------------------------------*
* END OF PAGE : 报表列印完最后一页后启动
*-------------------------------------------------------------------------------------*
END-OF-PAGE
* END OF SELECTION : 在结束列印资料后启动, 如可用来印出USER输入的条件
*-------------------------------------------------------------------------------------*
END-OF-SELECTION.
INCLUDE _____
* FORM : 撰写程序中所使用到的副程序
*-------------------------------------------------------------------------------------*
* Read Data : 自TABLE读取资料放入Internal Table
*-------------------------------------------------------------------------------------*
FORM READ_DATA.
SELECT * FROM ______
INTO _______
WHERE _______.
IF SY-SUBRC = 0.
ENDIF.
APPEND _____. " 增加Internal Table元素
ENDSELECT.
ENDFORM.
* Process Data : 处理Internal Table的资料, 如排序及汇总
*-------------------------------------------------------------------------------------*
FORM PROCESS_DATA.
ENDFORM.
* Print Data : 依序输出 Internal Table的资料
*-------------------------------------------------------------------------------------*
FORM PRINT_DATA.
ENDFORM.
* Print Summary : 印出数值资料加总
*-------------------------------------------------------------------------------------*
FORM PRINT_SUMMARY.
ENDFORM.
* Include Program : 列出所含入的其它程序source code, 如副程序
*-------------------------------------------------------------------------------------*
INCLUDE _____
INCLUDE _____
*-------------------------------------------------------------------------------------*
*
REPORT rep.
Additions:
1. ... NO STANDARD PAGE HEADING
2. ... LINE-SIZE col
3. ... LINE-COUNT n(m)
表单输出每页由n行，其中的m行作为页脚；
4. ... MESSAGE-ID mid 消息对象
5. ... DEFINING DATABASE ldb
使用逻辑数据库，自动产生
*
事件块
INITIALIZATION
AT SELECTION-SCREEN
START-OF-SELECTION
GET
END-OF-SELECTION
TOP-OF-PAGE
END-OF-PAGE
*
事件块的简单处理过程：
*
ABAP程序运行的时候，INITIALIZATION首先被调用；
经过初始化的输入屏幕会显示在表示服务器；
用户离开输入屏幕的时候，START-OF-SELCTION事件会被自动调用；
结果数据会以列表的形式显示在第二个屏幕上；
*
源代码中的事件块顺序不影响它们的执行顺序
*
事件块编码规则(1)
INITIALIZATION
通常在此事件块中设定输入屏幕字段的初始值
*
事件块编码规则(2)
AT SELECTION-SCREEN
通常在此事件块中进行用户输入数据的合法性检查，发现错误则以消息的形式给出警示，直到用户输入正确的数值
例如： AT SELECTION-SCREEN .
IF P_DATE = SPACE .
MESSAGE E001 .
ENDIF.
效果：如果字段P_DATE为空，则程序会用消息001“日期字段不能为空！”来提示用户必须输入一个日期。而且输入屏幕会等待用户输入，知道该字段数值合法
*
事件块编码规则(3)
START-OF-SELCTION
通常在此事件中针对业务需求进行系统数据的查询
例如：
start-of-selection .
perform get_data_for_oil .
效果：
在输入屏幕用户按下执行按钮后，子程序get_data_for_oil被执行，在其中获得业务相关的数据存放到内表或者其它变量，这些数据在END-OF-SELECTION事件块中被输出
*
事件块编码规则(4)
END-OF-SELCTION
通常在此事件中进行结果清单的输出
例如：
end-of-selection .
write : 23(1) sy-vline,
24(20) tab-gas_plan right-justified ,
效果：
数据以清单的形式输出
*
事件块编码规则(5)
GET
从逻辑数据库中得到数据(较少用)
TOP-OF-PAGE
在此事件块中设计输出清单的页头
TOP-OF-PAGE
write : /1(240) '汽柴油日出厂情况表' centered .
write : /20(8) '日期：' ,
29(10) s_date ,
180(6) '单位：' ,
190(10) '吨' .
*
事件块编码规则(6)
END-OF-PAGE
在此事件中设定输出清单的页脚
例如：
END-OF-PAGE .
Write : ‘制作人’ , p_name .
*-------------------------------------------------------------------------------------*
*
比较所有的字段类型
要比较所有的字段类型，可以在逻辑表达式中使用下列运算符：
<运算符> 含义
EQ 等于
= 等于
NE 不等于
<> 不等于
>< 不等于
LT 小于
------------------转自360文档