【SAS NOTES】ods

data mysas.mmsone;
    infile 'E:\SAS\mysas\MMS1.txt' dlm='09'x firstobs=2;
    input date city $ wangnei wangjian guoji shangxing wangneid wangjiand 
            guojid alld allwangnei allwangjian allguoji allall upfeetiao downfeetiao;
run;
proc sort data=mysas.mmsone;
    by city;
run;

ods trace on;
proc means data=mysas.mmsone;
    by city;
    ods select  Means.ByGroup21.Summary;
run;
ods trace off;

1、文本类变量一定要加上$

2、Ods output deliver system 

使用ods trace on +ods trace off来确定输出内容有哪些。用ods select +输出内容 来选中特定的内容输出。

ods trace on;
proc tabulate data=mysas.mmsone;
    class city date;
    var wangnei wangjian;
    table city all,date,(wangnei wangjian)*max;
    ods output Tabulate.Report.Table=mysas.reportmms;
    run;
ods trace off;
proc print data=mysas.reportmms;
run;

用ods trace确定输出的内容后可以用ods output ***=dataset 来实现将处理结果输出到新数据集。

ods html file='E:\SAS\mysas\outputhtml.html';
ods noproctitle;
    proc tabulate data=mysas.mmstwo;
        class city date;
        var wangnei wangjian;
        table city all,date,(wangnei*mean wangjian*min);
    run;
ods html close;

用ods html file +ods noproctitle+ods html close 来将中间圈定的输出用html来展现。

ods rtf file='E:\SAS\mysas\outputrtf.rtf';
ods noproctitle;
    proc means data=mysas.mmstwo;
        class city date;
        var wangnei wangjian;
        by city;
    run;
ods rtf close;

类似生成html ods 也可以用来生成rtf格式（即word格式）的文件，区别在于将html 换成rtf

 同样原理，ods可以生成pdf pcl ps格式的文档。

ods rtf file='E:\SAS\mysas\outputrtf.rtf';
ods noproctitle;
    proc means data=mysas.mmstwo;
        class city date;
        var wangnei wangjian;
        by city;
        title color=green 'this' bcolor=navy 'is' height=1cm 'a' justify=center bold 'title.';
    run;
ods rtf close;

对title 和footnotes的字体等控制。

ods html file='E:\SAS\mysas\style.html';
proc print data=mysas.mmstwo
    style(data)={background=pink};
    var city wangnei wangjian date;
    var wangnei/style(data)={font_weight=bold};
    id city;
    run;
ods html close;

在proc print 和var 中通过加入style（data）or /style(data)={}来实现对背景或某个变量的单独控制。

ods pdf file='E:\SAS\mysas\stylepdf1.pdf';
proc tabulate data=mysas.mmstwo
    style={background=silver};
    class city/style={background=green};
    var  wangnei wangjian;
    table city all,(sum*wangnei*all N*wangjian*all*{style={background=white}});
run;
    ods pdf close;

在proc report和proc tabulate 中同样可以使用style={}来改变输出的样式，注意style在report和tabulate中不同位置的写法。class为 /style table为*style{}