使用[frame()]数据标签制作的纯AS preLoader

2010-03-23 16:20

原理的话就是使用[frame()]标签，改变文档类指向。具体操作大家可以去网路上查一下，这方面资料很多，我这里只将源码贴出来，和大家一同分享。

默认程序入口：

 package
{
 import flash.display.Sprite;
 import mx.core.BitmapAsset;

[Frame(factoryClass="SystemManager",label="hello")]

public class MyApplication extends Sprite {
  
   [Embed(source="test.png")]
   private var bigPicCls:Class;
  
   public function MyApplication() {
    var b:BitmapAsset = new bigPicCls() as BitmapAsset;
    addChild(b);
   }
}
}

被指向的主文档类：

package {
import flash.display.DisplayObject;
import flash.display.MovieClip;
import flash.display.StageAlign;
import flash.display.StageScaleMode;
import flash.events.Event;
import flash.events.ProgressEvent;
import flash.utils.getDefinitionByName;

public class SystemManager extends MovieClip 
{
   private var preLoader:PreLoader;
  
   public function SystemManager() {
    stage.scaleMode = StageScaleMode.NO_SCALE;
    stage.align = StageAlign.TOP_LEFT;
   
    stop();
   
    preLoader = new PreLoader();
    addChild(preLoader);
   
    preLoader.x = stage.stageWidth/2 - preLoader.width/2;
    preLoader.x = stage.stageHeight/2 - preLoader.height/2;
   
    loaderInfo.addEventListener(ProgressEvent.PROGRESS,progressHandle);
    loaderInfo.addEventListener(Event.COMPLETE,completeHandler);
   }
  
   private function progressHandle(e:ProgressEvent):void 
   {
    preLoader.setProgress(e.bytesLoaded,e.bytesTotal);
   }
  
   private function completeHandler(e:Event):void {
    loaderInfo.removeEventListener(ProgressEvent.PROGRESS,progressHandle);
    loaderInfo.removeEventListener(Event.COMPLETE,completeHandler);
   
    removeChild(preLoader);
    preLoader = null;
   
    nextFrame();
   
    initApplication();
   }
  
   private function initApplication():void {
    /**这里不能直接写成：
    var app:Application = new Application();
    这样的由于引用到 Application，Application中所有的资源都会被编译到第一帧来
    这样的话 PreLoader就没有意义了，你也看不到PreLoader，就跳到第二帧了
    **/
    var appCls:Class = getDefinitionByName("MyApplication") as Class;
    var app:DisplayObject = new appCls() as DisplayObject;
    addChild(app);
   }
}
}

进度条：

package 
{
import flash.display.Sprite;
import flash.text.TextField;

public class PreLoader extends Sprite 
{
   public function PreLoader() 
   {
    var t:TextField = new TextField();
    t.border = true;
    t.text = "loading......";
   
    addChild(t);
   }
  
   public function setProgress(loaded:uint,total:uint):void 
   {
    var t:TextField = getChildAt(0) as TextField;
    t.text = "load: "+ loaded/1000 + "/" + total/1000;
   
    trace("load: "+ loaded/1000 + "/" + total/1000);
   }
}
}