Actionscript(flash)中的延迟调用和间隔调用

2010-04-29 16:42

昨天写项目时有个地方用到了延时调用，我不知道flash api中自带这种功能于是自己写了一个

package com.zs
{
 import flash.display.Sprite;
 import flash.events.TimerEvent;
 import flash.utils.Timer;

 public class AppWaiter
{
   private var _delayFunction:Function;         //延时执行的函数
   private var timer:Timer;            //定时器
  
   public function AppWaiter(guest:Sprite)
   {
   }
  
   public function callLater(seconds:Number,callFun:Function):void
   {
    _delayFunction = callFun;
    timer = new Timer(seconds*1000,1);
    timer.addEventListener(TimerEvent.TIMER,callDelayFuntion);
    timer.start();
   }
  
   public function stopCallLater():void
   {
    if(timer){
     timer.stop();
     timer.removeEventListener(TimerEvent.TIMER,callDelayFuntion);
     timer = null;
    }
   }
  
   private function callDelayFuntion(e:TimerEvent):void
   {
    _delayFunction.call();
    stopCallLater();
   }
}
}

方法名是：setTimeout() ，取消调用的方法是clearTimeout()；具体使用方法引用帮助文档的例子

package {
    import flash.display.Sprite;
    import flash.utils.*;

    public class ClearTimeoutExample extends Sprite {
        private var delay:Number = 1000; // delay before calling myDelayedFunction
        private var intervalId:uint;
        private var count:uint = 1000000;
        
        public function ClearTimeoutExample() {
            intervalId = setTimeout(myDelayedFunction, delay);
            startCounting();
        }

        public function startCounting():void {
            var i:uint = 0;
            do {
                if(i == count-1) {
                    clearTimeout(intervalId);
                    trace("Your computer can count to " + count + " in less than " + delay/1000 + " seconds.");    
                }
                i++;
            } while(i < count)            
        }
        
        public function myDelayedFunction():void {
            trace("Time expired.");
        }
    }

同时发现还有一个间隔调用和取消，函数

间隔调用：setInterval () 取消调用：clearInterval ()

使用方法：

今天查帮组文档偶尔发现，原来flash api自带了一个延时调用，和取消延时调用的方法

package {
    import flash.display.Sprite;
    import flash.utils.*;

    public class ClearIntervalExample extends Sprite {
        private var intervalDuration:Number = 1000; // duration between intervals, in milliseconds
        private var intervalId:uint;
        private var counter:uint     = 0;
        private var stopCount:uint     = 3;
        
        public function ClearIntervalExample() {
            intervalId = setInterval(myRepeatingFunction, intervalDuration, "Hello", "World");
        }

        public function myRepeatingFunction():void {
            trace(arguments[0] + " " + arguments[1]);

            counter++;
            if(counter == stopCount) {
                trace("Clearing Interval");
                clearInterval(intervalId);    
            }
        }
    }
}

需要注意的是，这两个方法和Timer类如果不取消，和停止，即使你删除了他们所在的对象，该对象还会占用着内存。