只要是会java的都知道++和—操作符的用法,如
- int i = 1;
- int j = i++;
- int k = ++i;
结果i为3,j为1,k为3。
那如下代码:
- int j = 0;
- for (int i = 0; i < 100; i++) {
- j = j++;
- }
- System.out.println(j);
输出结果又是多少呢?100?0?
正确答案是0。为什么呢?
要想搞明白这个问题,那来看看这段代码生成的字节码:
- 0: iconst_0
- 1: istore_1
- 2: iconst_0
- 3: istore_2
- 4: goto 15
- 7: iload_1
- 8: iinc 1, 1
- 11: istore_1
- 12: iinc 2, 1
- 15: iload_2
- 16: bipush 100
- 18: if_icmplt 7
- 21: getstatic #16; //Field java/lang/System.out:Ljava/io/PrintStream;
- 24: iload_1
- 25: invokevirtual #22; //Method java/io/PrintStream.println:(I)V
- 28: return
j = j++;的字节码为:
- 7: iload_1
- 8: iinc 1, 1
- 11: istore_1
iload_1 意思是把局部变量表中位置1的变量取出来放到操作数栈中;
iinc 1, 1 这是执行j++操作,把局部变量表中位置1的变量加1;
istore_1 这是把操作数栈顶的值弹出放到局部变量表位置1的变量中。
问题就在innc这个指令,指令格式为:
innc vindex const
这个指令只能操作int类型的变量,有两个操作数,第一个操作数vindex指示局部变量在局部表中的位置索引,第二个操作数const表示要相加的整型常量。如
innc 2 100
表示把局部变量表中位置2的变量加上100。
具体的过程是,把局部变量表中位置2的变量取出来,加上100后,然后再放回到局部变量表中。
而const这个常量值的范围是-128~127,如果超出这个范围,使用指令iinc_w。如:
- int x = 1;
- x = x + -128;
- x = x + -129;
- x = x + 127;
- x = x + 128;
生成字节码如下:
- 0: iconst_1
- 1: istore_1
- 2: iinc 1, -128 //x = x + -128;
- 5: iinc_w 1, -129 //x = x + -129;
- 11: iinc 1, 127 //x = x + 127;
- 14: iinc_w 1, 128 //x = x + 128;
- 20: return
上面把innc指令的基本意思说清楚了,现在是最重要的一点:
innc指令操作的是局部变量表中的变量,而不是当前操作数栈栈顶的数据(iinc指令实现有没有用到操作数栈已经不重要了)。
上面j = j++;的字节码
- 7: iload_1
- 8: iinc 1, 1
- 11: istore_1
iload_1 先把j的值取出来放到栈顶,此时值为0,执行iinc 1, 1这个指令时,是操作的局部变量表中变量(值为0),把它加1,此时值为1,istore_1指令把当前操作数栈顶的值(还是0),又放回局部变量表位置1的变量中,那局部变量表位置1的变量的值又从1变为0了。
所以,不管怎么循环,j的值永远是0。
下面说说i++和++i的问题:
都知道i++是先使用i的值,再把i的值加1;而++i是先把i的值加1,再使用i的值。
但是实际上是怎么回事呢?其实i++和++i都是使用iinc vindex, 1指令,区别在于,i++是先把局部变量取出来放到操作数栈顶,再把局部变量表中的变量值加1,而++i是先把局部变量表中的变量值加1,再把局部变量取出来放到操作数栈顶。如下代码:
- int j = 0;
- int x = j++;
- x = ++j;
字节码如下:
- 0: iconst_0 //把常量0放到操作数栈顶
- 1: istore_1 //int j = 0;
- 2: iload_1 //先取出j的值0
- 3: iinc 1, 1 //j++,把局部变量表中j的值加1,j=1,此时操作数栈顶的值还是0
- 6: istore_2 //把操作数栈顶的值0放加局部变量表中,此时x=0
- 7: iinc 1, 1 //++j,先把局部变量表中j的值加1,此时j=2
- 10: iload_1 //取出j的值2
- 11: istore_2 //x=2
- 12: return //方法返回
以上说的都是++操作符,--的操作也是一样的,就不再多说。