as3 object与dictionary区别

AS3中的Dictionary类（flash.utils.Dictionary）是一个新的AS类。Dictionary类和Object唯一的区别在于：Dictionary对象可以使用非字符串作为键值对的键。例如：

var obj:Object = new Object();
obj["name"] = 1; // 键是字符串"name"
obj[1] = 2; // 键是1 (被转换成字符串"1")
obj[new Object()] = 3; // 键是new Object()，被转传成字符串"[object Object]"

for (var prop:String in obj) {
      trace(prop); // 输出：[object Object], 1, name
      trace(obj[prop]); // 输出：3, 2, 1
}

也就是说，无论用什么类型的变量作为键，都将被转换成字符串。同时，如果你使用了不同的对象作为键，都会被转换成字符串"[object Object]"作为键，因此而指向了同一个数据。例如：

var a:Object = new Object();   
var b:Object = new Object();   

var obj:Object = new Object();   
obj[a] = 1; // obj["[object Object]"] = 1;   
obj[b] = 2; // obj["[object Object]"] = 2;   

for (var prop:String in obj) {   
      trace(prop); // traces: [object Object]   
      trace(obj[prop]); // traces: 2   
}

Dictionary类将没有这个限制，你可以将键设置成任何一种数据类型。例如：

import flash.utils.Dictionary;

var a:Object = new Object();
var b:Object = new Object();

var dict:Dictionary = new Dictionary();
dict[a] = 1; // dict[a] = 1;
dict[b] = 2; // dict[b] = 2;

for (var prop:* in dict) {
      trace(prop); // traces: [object Object], [object Object]
      trace(dict[prop]); // traces: 1, 2
}

注意：

1、虽然在trace的时候，输出的还是[object Object]，但是这个结果是对象的toString的结果。在Dictionary对象中，代表的是不同的对象引用。

2、这里的prop的类型是*。这是很重要的，因为dict对象中的键可能是任何数据类型的。

 

以下是本人对Dictionary与Object的不同之处的一个小结：

1、Object的键必须是字符串，或表示字符串的表达式(变量或函数)，若不是字符串的表达式，则将调用toString()方法，将其转化为字符串；

2、与Object不同的是，Dictionary使用的键是对象的引用，而不是字符串，且非原始对象键调用之前是通过全等运算符(===)来进行判断，并不会将数据类型强制转换之后再进行判断。

转载：http://blog.sina.com.cn/s/blog_637b214b0100u1l1.html