查找担保圈-step1-担保圈表函数

USE [test];
GO
/****** Object:  UserDefinedFunction [dbo].[f_findrecycle]    Script Date: 2019/7/8 14:37:08 ******/
SET ANSI_NULLS ON;
GO
SET QUOTED_IDENTIFIER ON;
GO
ALTER FUNCTION [dbo].[f_findrecycle]
(
    @cname NVARCHAR(100), --起点
    @nlevel INT           --递归的层数
)
RETURNS TABLE
AS
RETURN
(
    WITH cte_A (kmmc, bzrmc, isrecycle, full_path, nlevel)
    AS (SELECT [KHMC],
               [BZRMC],
               0 AS isrecycle,
               CAST(KHMC + '<' + BZRMC AS NVARCHAR(MAX)) AS full_path,
               1 AS nlevel
        FROM [dbo].[dbgx]
        WHERE KHMC = @cname
        UNION ALL
        SELECT s.KHMC,
               s.BZRMC,
               CASE
                   WHEN s.BZRMC = @cname THEN
                       1 --如果下层找到了起点，就停止递归
                   ELSE
                       0
               END AS isrecycle,
               CAST(p.full_path + '<' + s.BZRMC AS NVARCHAR(MAX)) AS full_path,
               p.nlevel + 1 AS nlevel
        FROM [dbo].[dbgx] AS s
            INNER JOIN cte_A AS p
                ON s.KHMC = p.bzrmc
        WHERE CHARINDEX(s.BZRMC, p.full_path) IN ( 0, 1 ) --防止找到起点（担保圈）后继续进行递归查找
              AND p.isrecycle = 0 --上层没有找到起点，继续递归
              AND p.nlevel <= @nlevel --递归的层数
    )
    SELECT a.kmmc,
           a.bzrmc,
           a.isrecycle,
           a.full_path,
           a.nlevel
    FROM cte_A AS a
    WHERE a.isrecycle = 1
);