移动的云朵

package antCodes
{
    import flash.display.Sprite;
    import flash.utils.getDefinitionByName;

    public class SampleCloud extends Sprite
    {
        //笔者习惯以双下划线开头的属性表示与库中元件相关
        private var __CloudA:Class;
        private var __CloudB:Class;
        private var __Sky:Class;
        public function SampleCloud() {
            initView();
            var sky:Sprite = new __Sky();
            //三朵云彩，使用基类CloudMovieClip做为类型
            var cloudABig    :CloudMovieClip = new __CloudA();
            var cloudASmall    :CloudMovieClip = new __CloudA();
            var cloudB        :CloudMovieClip = new __CloudB();
            //分别调整三朵云彩的位置、大小和速度
            cloudABig.speed = 1.5;
            cloudABig.x = 300;
            
            cloudASmall.speed = 1;
            cloudASmall.scaleX = 0.5;            
            cloudASmall.scaleY = 0.5;
            cloudASmall.x = 200;
            cloudASmall.y = 125;
            cloudASmall.alpha = 0.5;
                        
            cloudB.y = 150;
            cloudB.x = 500;
            cloudB.speed = 0.5;
            //加入显示列表
            addChild(sky);
            addChild(cloudB);
            addChild(cloudABig);
            addChild(cloudASmall);            
        }        
        private function initView():void {
            __CloudA = getDefinitionByName("CloudA") as Class;
            __CloudB = getDefinitionByName("CloudB") as Class;
            __Sky      = getDefinitionByName("SkySprite") as Class;
        }
        
    }
}

package antCodes
{
    import flash.display.MovieClip;
    import flash.events.Event;
    public class CloudMovieClip extends MovieClip
    {
        private var _speed:Number = 1;
        //speed是云彩移动的速度
        public function CloudMovieClip(){
            super();
            //添加动画效果
            addEventListener(Event.ENTER_FRAME, move);
        }
        public function set speed(nS:Number):void {
            _speed = nS;
        }
        //每帧的云彩移动
        private function move(evt:Event):void {
            this.x -= _speed;
        }        
    }
}