每天开机关机，除了“等”之外，你得了解你的操作系统开机的时候真正做了什么？
一. 书上都是这么讲的
CPU自身初始化：硬件初始工作，以PC/IP寄存器跳转到BIOS首地址为结束标志。
->加电自检（Power On Self Test）:硬件检测，内存检测，系统总线检测，以开始从总线读取第一段程序为结束标志。
->加载内核引导程序：这里是由BIOS确定了引导设备之后，从设备的第一个扇区启动的程序，GRUB的工作就是属于这个过程，以选择完一个启动的系统为结束标志。
->主引导程序：由操作系统定义的，第一个512字节的内容进行的引导，包括对分区表（MBR,GPT）的扫描，但实际上不属于操作系统，以一次长跳转作为结束表述。
->次引导程序：加载linux操作系统映像，以将控制权交给映像作为结束标志。
->内核：各种初始化，包括一个init进程的创建，初始化完成后操作系统开始完全工作。（如果内核是压缩过的话，初始化之前的自解压过程也属于这部分）
二. 代码都是这么写的
在BIOS开始工作之前的硬件工作就不在我们的讨论范围之内了，在BIOS中我们完成了对第一启动设备的选择之后，我们还会做以下的事情：
为了帮助理解，附上一张引导过程之中内存的分布映射图 （于linux源码中的Documentation/x86/boot.txt中）
0A0000 +------------------------+
| Reserved for BIOS | Do not use. Reserved for BIOS EBDA.
09A000 +------------------------+
| Command line |
| Stack/heap | For use by the kernel real-mode code.
098000 +------------------------+
| Kernel setup | The kernel real-mode code.
090200 +------------------------+
| Kernel boot sector | The kernel legacy boot sector.
090000 +------------------------+
| Protected-mode kernel | The bulk of the kernel image.
010000 +------------------------+
| Boot loader | <- Boot sector entry point 0000:7C00（这里是AT&T汇编段址：偏移于NASM和MASM是反过来的，要注意！）
001000 +------------------------+
| Reserved for MBR/BIOS |
000800 +------------------------+
| Typically used by MBR |
000600 +------------------------+
| BIOS use only |
000000 +------------------------+
1.MBR引导过程：
这部分的引导过程一般有两种的稍微不同的办法：
第一种办法是在于渊在《自己动手写操作系统》中的例子中大部分使用到，是利用FAT12文件系统来帮助我们进行引导过程，具体的做法是在软盘之中加入几个用于文件系统定义划分的字段，这样一来由于字段地址的限制，我们需要在MBR的前几个字节直接进行一次短跳转，然后进入一般在扇区中部的真正入口，现在的linux发行源码中实际也都是这么做的，第一步直接执行短跳转，而且这个跳转是用汇编的硬编码做的，具体原因很有趣，大家自行Google。到达入口之后我们需要将进一步来进行引导的文件加载到内存之中的9000:0200地址之上，如上图所示就是Kernel Setup部分，FAT12文件系统在这里就帮助我们在软盘之中有效率的找到了外存中的二进制映像，为什么这里不把这个映像直接加载到9000：0000这个整齐的地址之上呢？我想原因应该大概是节省MBR512K中进行数据访问的代码，直接连同最初在7c00:0000到7C00:0200的这一个扇区的数据一起拷贝到高位地址上。
; FAT12 磁盘的头 ; ---------------------------------------------------------------------- BS_OEMName DB 'ForrestY' ; OEM String, 必须 8 个字节 BPB_BytsPerSec DW 512 ; 每扇区字节数 BPB_SecPerClus DB 1 ; 每簇多少扇区 BPB_RsvdSecCnt DW 1 ; Boot 记录占用多少扇区 BPB_NumFATs DB 2 ; 共有多少 FAT 表 BPB_RootEntCnt DW 224 ; 根目录文件数最大值 BPB_TotSec16 DW 2880 ; 逻辑扇区总数 BPB_Media DB 0xF0 ; 媒体描述符 BPB_FATSz16 DW 9 ; 每FAT扇区数 BPB_SecPerTrk DW 18 ; 每磁道扇区数 BPB_NumHeads DW 2 ; 磁头数(面数) BPB_HiddSec DD 0 ; 隐藏扇区数 BPB_TotSec32 DD 0 ; 如果 wTotalSectorCount 是 0 由这个值记录扇区数 BS_DrvNum DB 0 ; 中断 13 的驱动器号 BS_Reserved1 DB 0 ; 未使用 BS_BootSig DB 29h ; 扩展引导标记 (29h) BS_VolID DD 0 ; 卷序列号 BS_VolLab DB 'OrangeS0.02'; 卷标, 必须 11 个字节 BS_FileSysType DB 'FAT12 ' ; 文件系统类型, 必须 8个字节 ;------------------------------------------------------------------------
第二种办法是抛开文件系统直接通过BIOS的INT13H中断来进行对扇区数据的访问，这样做只能说更灵活吧（我也找不出其他优点了..），在林纳斯的创造的linux0.11内核版本中引导部分就是使用的这种办法，我在实践这种办法时候碰到了非常严重的问题（至今未解决..）就是使用INT13H读取软盘中第二个扇区中的引导代码的时候，就是返回代码为01H的错误，有经验的大神希望能为我指点迷津。以下是NASM版本的linux0.11的引导代码：
.globl begtext, begdata, begbss, endtext, enddata, endbss ! 定义了6 个全局标识符；
.text ! 文本段；
begtext:
.data ! 数据段；
begdata:
.bss ! 堆栈段；
begbss:
.text ! 文本段；
SETUPLEN = 4 ! nr of setup-sectors
! setup 程序的扇区数(setup-sectors)值；
BOOTSEG = 0x07c0 ! original address of boot-sector
! bootsect 的原始地址（是段地址，以下同）；
INITSEG = 0x9000 ! we move boot here - out of the way
! 将bootsect 移到这里 -- 避开；
SETUPSEG = 0x9020 ! setup starts here
! setup 程序从这里开始；
SYSSEG = 0x1000 ! system loaded at 0x10000 (65536).
! system 模块加载到0x10000（64 kB）处；
ENDSEG = SYSSEG + SYSSIZE ! where to stop loading
! 停止加载的段地址；
! ROOT_DEV: 0x000 - same type of floppy as boot.
! 根文件系统设备使用与引导时同样的软驱设备；
! 0x301 - first partition on first drive etc
! 根文件系统设备在第一个硬盘的第一个分区上，等等；
ROOT_DEV = 0x306 ! 指定根文件系统设备是第2 个硬盘的第1 个分区。这是Linux 老式的硬盘命名
! 方式,具体值的含义如下：
! 设备号=主设备号*256 + 次设备号（也即dev_no = (major<<8) + minor ）
! （主设备号：1-内存,2-磁盘,3-硬盘,4-ttyx,5-tty,6-并行口,7-非命名管道）
! 0x300 - /dev/hd0 - 代表整个第1 个硬盘；
! 0x301 - /dev/hd1 - 第1 个盘的第1 个分区；
! …
! 0x304 - /dev/hd4 - 第1 个盘的第4 个分区；
! 0x305 - /dev/hd5 - 代表整个第2 个硬盘盘；
! 0x306 - /dev/hd6 - 第2 个盘的第1 个分区；
! …
! 0x309 - /dev/hd9 - 第2 个盘的第4 个分区；
! 从linux 内核0.95 版后已经使用与现在相同的命名方法了。
entry start ! 告知连接程序，程序从start 标号开始执行。
start: ! 47--56 行作用是将自身(bootsect)从目前段位置0x07c0(31k)
! 移动到0x9000(576k)处，共256 字（512 字节），然后跳转到
! 移动后代码的go 标号处，也即本程序的下一语句处。
mov ax,#BOOTSEG ! 将ds 段寄存器置为0x7C0；
mov ds,ax
mov ax,#INITSEG ! 将es 段寄存器置为0x9000；
mov es,ax
mov cx,#256 ! 移动计数值=256 字；
sub si,si ! 源地址 ds:si = 0x07C0:0x0000
sub di,di ! 目的地址 es:di = 0x9000:0x0000
rep ! 重复执行，直到cx = 0
movw ! 移动1 个字；
jmpi go,INITSEG ! 间接跳转。这里INITSEG 指出跳转到的段地址。
go: mov ax,cs ! 将ds、es 和ss 都置成移动后代码所在的段处(0x9000)。
mov ds,ax ！由于程序中有堆栈操作(push,pop,call)，因此必须设置堆栈。
mov es,ax
! put stack at 0x9ff00. ! 将堆栈指针sp 指向0x9ff00(即0x9000:0xff00)处
mov ss,ax
mov sp,#0xFF00 ! arbitrary value >>512
! 由于代码段移动过了，所以要重新设置堆栈段的位置。
! sp 只要指向远大于512 偏移（即地址0x90200）处
! 都可以。因为从0x90200 地址开始处还要放置setup 程序，
! 而此时setup 程序大约为4 个扇区，因此sp 要指向大
! 于（0x200 + 0x200 * 4 + 堆栈大小）处。
! load the setup-sectors directly after the bootblock.
! Note that 'es' is already set up.
! 在bootsect 程序块后紧根着加载setup 模块的代码数据。
! 注意es 已经设置好了。（在移动代码时es 已经指向目的段地址处0x9000）。
load_setup:
! 68--77 行的用途是利用BIOS 中断INT 0x13 将setup 模块从磁盘第2 个扇区
! 开始读到0x90200 开始处，共读4 个扇区。如果读出错，则复位驱动器，并
! 重试，没有退路。INT 0x13 的使用方法如下：
! 读扇区：
! ah = 0x02 - 读磁盘扇区到内存；al = 需要读出的扇区数量；
! ch = 磁道(柱面)号的低8 位； cl = 开始扇区(0-5 位)，磁道号高2 位(6-7)；
! dh = 磁头号； dl = 驱动器号（如果是硬盘则要置位7）；
! es:bx ??指向数据缓冲区； 如果出错则CF 标志置位。
mov dx,#0x0000 ! drive 0, head 0
mov cx,#0x0002 ! sector 2, track 0
mov bx,#0x0200 ! address = 512, in INITSEG
mov ax,#0x0200+SETUPLEN ! service 2, nr of sectors
int 0x13 ! read it
jnc ok_load_setup ! ok - continue
mov dx,#0x0000
mov ax,#0x0000 ! reset the diskette
int 0x13
j load_setup
ok_load_setup:
! Get disk drive parameters, specifically nr of sectors/track
! 取磁盘驱动器的参数，特别是每道的扇区数量。
! 取磁盘驱动器参数INT 0x13 调用格式和返回信息如下：
! ah = 0x08 dl = 驱动器号（如果是硬盘则要置位7 为1）。
! 返回信息：
! 如果出错则CF 置位，并且ah = 状态码。
! ah = 0， al = 0， bl = 驱动器类型（AT/PS2）
! ch = 最大磁道号的低8 位，cl = 每磁道最大扇区数(位0-5)，最大磁道号高2 位(位6-7)
! dh = 最大磁头数， dl = 驱动器数量，
! es:di -?? 软驱磁盘参数表。
mov dl,#0x00
mov ax,#0x0800 ! AH=8 is get drive parameters
int 0x13
mov ch,#0x00
seg cs ! 表示下一条语句的操作数在cs 段寄存器所指的段中。
mov sectors,cx ! 保存每磁道扇区数。
mov ax,#INITSEG
mov es,ax ! 因为上面取磁盘参数中断改掉了es 的值，这里重新改回。
! Print some inane message ! 在显示一些信息('Loading system ...'回车换行，共24 个字符)。
mov ah,#0x03 ! read cursor pos
xor bh,bh ! 读光标位置。
int 0x10
mov cx,#24 ! 共24 个字符。
mov bx,#0x0007 ! page 0, attribute 7 (normal)
mov bp,#msg1 ! 指向要显示的字符串。
mov ax,#0x1301 ! write string, move cursor
int 0x10 ! 写字符串并移动光标。
! ok, we've written the message, now
! we want to load the system (at 0x10000) ! 现在开始将system 模块加载到0x10000(64k)处。
mov ax,#SYSSEG
mov es,ax ! segment of 0x010000 ! es = 存放system 的段地址。
call read_it ! 读磁盘上system 模块，es 为输入参数。
call kill_motor ! 关闭驱动器马达，这样就可以知道驱动器的状态了。
! After that we check which root-device to use. If the device is
! defined (!= 0), nothing is done and the given device is used.
! Otherwise, either /dev/PS0 (2,28) or /dev/at0 (2,8), depending
! on the number of sectors that the BIOS reports currently.
! 此后，我们检查要使用哪个根文件系统设备（简称根设备）。如果已经指定了设备(!=0)
! 就直接使用给定的设备。否则就需要根据BIOS 报告的每磁道扇区数来
! 确定到底使用/dev/PS0 (2,28) 还是 /dev/at0 (2,8)。
! 上面一行中两个设备文件的含义：
! 在Linux 中软驱的主设备号是2(参见第43 行的注释)，次设备号 = type*4 + nr，其中
! nr 为0-3 分别对应软驱A、B、C 或D；type 是软驱的类型（2??1.2M 或7??1.44M 等）。
! 因为7*4 + 0 = 28，所以 /dev/PS0 (2,28)指的是1.44M A 驱动器,其设备号是0x021c
! 同理 /dev/at0 (2,8)指的是1.2M A 驱动器，其设备号是0x0208。
seg cs
mov ax,root_dev ! 将根设备号
cmp ax,#0
jne root_defined
seg cs
mov bx,sectors ! 取上面第88 行保存的每磁道扇区数。如果sectors=15
! 则说明是1.2Mb 的驱动器；如果sectors=18，则说明是
! 1.44Mb 软驱。因为是可引导的驱动器，所以肯定是A 驱。
mov ax,#0x0208 ! /dev/ps0 - 1.2Mb
cmp bx,#15 ! 判断每磁道扇区数是否=15
je root_defined ! 如果等于，则ax 中就是引导驱动器的设备号。
mov ax,#0x021c ! /dev/PS0 - 1.44Mb
cmp bx,#18
je root_defined
undef_root: ! 如果都不一样，则死循环（死机）。
jmp undef_root
root_defined:
seg cs
mov root_dev,ax ! 将检查过的设备号保存起来。
! after that (everyting loaded), we jump to
! the setup-routine loaded directly after
! the bootblock:
! 到此，所有程序都加载完毕，我们就跳转到被
! 加载在bootsect 后面的setup 程序去。
jmpi 0,SETUPSEG ! 跳转到0x9020:0000(setup.s 程序的开始处)。
!!!! 本程序到此就结束了。!!!!
! 下面是两个子程序。
! This routine loads the system at address 0x10000, making sure
! no 64kB boundaries are crossed. We try to load it as fast as
! possible, loading whole tracks whenever we can.
!
! in: es - starting address segment (normally 0x1000)
!
! 该子程序将系统模块加载到内存地址0x10000 处，并确定没有跨越64KB 的内存边界。我们试图尽快
! 地进行加载，只要可能，就每次加载整条磁道的数据。
! 输入：es – 开始内存地址段值（通常是0x1000）
sread: .word 1+SETUPLEN ! sectors read of current track
! 当前磁道中已读的扇区数。开始时已经读进1 扇区的引导扇区
! bootsect 和setup 程序所占的扇区数SETUPLEN。
head: .word 0 ! current head !当前磁头号。
track: .word 0 ! current track !当前磁道号。
read_it:
! 测试输入的段值。必须位于内存地址64KB 边界处，否则进入死循环。清bx 寄存器，用于表示当前段内
! 存放数据的开始位置。
mov ax,es
test ax,#0x0fff
die: jne die ! es must be at 64kB boundary ! es 值必须位于64KB 地址边界!
xor bx,bx ! bx is starting address within segment ! bx 为段内偏移位置。
rp_read:
! 判断是否已经读入全部数据。比较当前所读段是否就是系统数据末端所处的段(#ENDSEG)，如果不是就
! 跳转至下面ok1_read 标号处继续读数据。否则退出子程序返回。
mov ax,es
cmp ax,#ENDSEG ! have we loaded all yet? ! 是否已经加载了全部数据？
jb ok1_read
ret
ok1_read:
! 计算和验证当前磁道需要读取的扇区数，放在ax 寄存器中。
! 根据当前磁道还未读取的扇区数以及段内数据字节开始偏移位置，计算如果全部读取这些未读扇区，所
! 读总字节数是否会超过64KB 段长度的限制。若会超过，则根据此次最多能读入的字节数(64KB – 段内
! 偏移位置)，反算出此次需要读取的扇区数。
seg cs
mov ax,sectors ! 取每磁道扇区数。
sub ax,sread ! 减去当前磁道已读扇区数。
mov cx,ax ! cx = ax = 当前磁道未读扇区数。
shl cx,#9 ! cx = cx * 512 字节。
add cx,bx ! cx = cx + 段内当前偏移值(bx)
! = 此次读操作后，段内共读入的字节数。
jnc ok2_read ! 若没有超过64KB 字节，则跳转至ok2_read 处执行。
je ok2_read
xor ax,ax ! 若加上此次将读磁道上所有未读扇区时会超过64KB，则计算
sub ax,bx ! 此时最多能读入的字节数(64KB – 段内读偏移位置)，再转换
shr ax,#9 ! 成需要读取的扇区数。
ok2_read:
call read_track
mov cx,ax ! cx = 该次操作已读取的扇区数。
add ax,sread ! 当前磁道上已经读取的扇区数。
seg cs
cmp ax,sectors ! 如果当前磁道上的还有扇区未读，则跳转到ok3_read 处。
jne ok3_read
! 读该磁道的下一磁头面(1 号磁头)上的数据。如果已经完成，则去读下一磁道。
mov ax,#1
sub ax,head ! 判断当前磁头号。
jne ok4_read ! 如果是0 磁头，则再去读1 磁头面上的扇区数据。
inc track ! 否则去读下一磁道。
ok4_read:
mov head,ax ! 保存当前磁头号。
xor ax,ax ! 清当前磁道已读扇区数。
ok3_read:
mov sread,ax ! 保存当前磁道已读扇区数。
shl cx,#9 ! 上次已读扇区数*512 字节。
add bx,cx ! 调整当前段内数据开始位置。
jnc rp_read ! 若小于64KB 边界值，则跳转到rp_read(156 行)处，继续读数据。
! 否则调整当前段，为读下一段数据作准备。
mov ax,es
add ax,#0x1000 ! 将段基址调整为指向下一个64KB 段内存。
mov es,ax
xor bx,bx ! 清段内数据开始偏移值。
jmp rp_read ! 跳转至rp_read(156 行)处，继续读数据。
! 读当前磁道上指定开始扇区和需读扇区数的数据到es:bx 开始处。参见第67 行下对BIOS 磁盘读中断
! int 0x13，ah=2 的说明。
! al – 需读扇区数；es:bx – 缓冲区开始位置。
read_track:
push ax
push bx
push cx
push dx
mov dx,track ! 取当前磁道号。
mov cx,sread ! 取当前磁道上已读扇区数。
inc cx ! cl = 开始读扇区。
mov ch,dl ! ch = 当前磁道号。
mov dx,head ! 取当前磁头号。
mov dh,dl ! dh = 磁头号。
mov dl,#0 ! dl = 驱动器号(为0 表示当前驱动器)。
and dx,#0x0100 ! 磁头号不大于1。
mov ah,#2 ! ah = 2，读磁盘扇区功能号。
int 0x13
jc bad_rt ! 若出错，则跳转至bad_rt。
pop dx
pop cx
pop bx
pop ax
ret
! 执行驱动器复位操作（磁盘中断功能号0），再跳转到read_track 处重试。
bad_rt: mov ax,#0
mov dx,#0
int 0x13
pop dx
pop cx
pop bx
pop ax
jmp read_track
/*
* This procedure turns off the floppy drive motor, so
* that we enter the kernel in a known state, and
* don't have to worry about it later.
*/
! 这个子程序用于关闭软驱的马达，这样我们进入内核后它处于已知状态，以后也就无须担心它了。
kill_motor:
push dx
mov dx,#0x3f2 ! 软驱控制卡的驱动端口，只写。
mov al,#0 ! A 驱动器，关闭FDC，禁止DMA 和中断请求，关闭马达。
outb ! 将al 中的内容输出到dx 指定的端口去。
pop dx
ret
sectors:
.word 0 ! 存放当前启动软盘每磁道的扇区数。
msg1:
.byte 13,10 ! 回车、换行的ASCII 码。
.ascii "Loading system ..."
.byte 13,10,13,10 ! 共24 个ASCII 码字符。
.org 508 ! 表示下面语句从地址508(0x1FC)开始，所以root_dev
! 在启动扇区的第508 开始的2 个字节中。
root_dev:
.word ROOT_DEV ! 这里存放根文件系统所在的设备号(init/main.c 中会用)。
boot_flag:
.word 0xAA55 ! 硬盘有效标识。
.text
endtext:
.data
enddata:
.bss
endbss:
在完成了从最初的7c00:0000到9000:0200的跳转之后，我们的引导过程就进入了一个新的阶段：
二. 内核加载准备
在这个阶段里我们要具体做的事情有：
1.突破实模式，进入保护模式
2.完成对内存的分页和分段
保护模式的运行离不开专设的硬件的支持，其中最主要的包括GDTR全局描述符向量寄存器和LDTR局部描述符向量寄存器，而我们所做的工作主要包括以下几项：
1.准备GDT，其实就是定义几个段来为保护模式的运行制定一些规则
2.用lgdt指令加载GDTR
3.打开A20（A20是地址线的名字，http://blog.csdn.net/yunsongice/article/details/6110648）
4.置CR0寄存器的PE置
5.跳转进入保护模式
根据head.s中第114行的.org 0x1000可知，物理地址0x1000之前的所有数据都将被页目录表覆盖(这个覆盖，是指更改了内存中的内核镜像文件，而不是磁盘上的内核镜像文件)。
1、首先，Linux从0x00000地址开始对五页内存进行清零。(1页页目录表+4页页表)
| 1 | setup_paging: |
| 2 | movl $1024*5,%ecx /* 5 pages - pg_dir+4 page tables */ |
| 3 | xorl %eax,%eax |
| 4 | xorl %edi,%edi /* pg_dir is at 0x000 */ |
| 5 | cld;rep;stosl |
2、接着，填写页目录表(页目录表的位置为0x00000-0x00fff,大小为4K，每一项占4字节)。因为只有4个页表，所以只填写了前四项。
| 1 movl $pg0+7,pg_dir /* set present bit/user r/w */ |
| 2 movl $pg1+7,pg_dir+4 /* --------- " " --------- */ |
| 3 movl $pg2+7,pg_dir+8 /* --------- " " --------- */ |
| 4 movl $pg3+7,pg_dir+12 /* --------- " " --------- */ |
这里，4个页目录项的内容分别是$pg0(1,2,3)+7，分别是4个页表的物理地址+111B。前面的$pg0(1,2,3)是页表的物理地址，而111B则代表这4个页表权限为可读写。
3、填写页表项的内容
| 1 movl $pg3+4092,%edi |
| 2 movl $0xfff007,%eax /* 16Mb - 4096 + 7 (r/w user,p) */ |
| 3 std |
| 4 1: stosl /* fill pages backwards - more efficient :-) */ |
| 5 subl $0x1000,%eax |
| 6 jge 1b |
这里的填写是逆序填写的，也就是首先将16M物理内存最后一页的启始地址+权限(16M-4K+111B)填写到第4张页表的最后一项。地址 为$pg3+4092，其中$pg3为(第4张页表的起始地址)，4092是因为1024*4(1024项，每项占用4字节)-4(最后一项页占用4字 节)。所以第4张页表的最后一项是(16M-4K)0xfff000+111B=0xfff007。
最终，std以4递减edi寄存器 (一个页表项占4字节，edi指向正在操作的页表项)，subl $0x1000,%eax将减去0x1000(一页内存的大小，eax指向正在操作的内存边界)，l:stosl是填写页表项，知道eax的内容为0，这 样就填写完了4个页表。
这样，内存中的页目录表和页表分布就是：
| 物理内存地址 | 所含信息及备注 | 单元内容 |
| 0X00FF FFFC …… |
…… …… |
|
| 0X0000 4FFC 0X0000 4FF8 … … 0X0000 4004 0X0000 4000 |
页表4 4K (0X00004000-0X00004FFC) 4字节为一项 |
0X00FF F000+7 0X00FF E000+7 … … 0X00C0 2000+7 0X00C0 1000+7 0X00C0 0000+7 |
| 0X0000 3FFC 0X0000 3FF8 … … 0X0000 3004 0X0000 3000 |
页表3 4K (0X00003000-0X00003FFC) 4字节为一项 |
0X00BF F000+7 0X00BF E000+7 … … 0X0080 2000+7 0X0080 1000+7 0X0080 0000+7 |
| 0X0000 2FFC 0X0000 2FF8 … … 0X0000 2004 0X0000 2000 |
页表2 4K (0X00002000-0X00002FFC) 4字节为一项 |
0X007F F000+7 0X007F E000+7 … … 0X0040 2000+7 0X0040 1000+7 0X0040 0000+7 |
| 0X0000 1FFC 0X0000 1FF8 … … 0X0000 1004 0X0000 1000 |
页表1 4K (0X00001000-0X00001FFC) 4字节为一项 |
0X003F F000+7 0X003F E000+7 … … 0X0000 2000+7 0X0000 1000+7 0X0000 0000+7 |
| 0X0000 0FFC 0X0000 0FF8 … … 0X0000 0004 0X0000 0000 |
PDT(页目录表) 4K (0X000000-0X00000FFF) 只有前四项有内容 |
… 0x0000 4000+7 0x0000 3000+7 0x0000 2000+7 0x0000 1000+7 |
最后，把页目录表的地址(0x000000)写到控制寄存器CR3，然后置控制寄存器CR0的PG位，这样就开启了内存的分页管理功能。
Linux0.11在分页机制下的寻址(两级表寻址)
第一级表称为页目录。
存放在1页4k页面中。具有1k个4字节长度的表项。这些表项指向第二级表。线性地址的最高10位(位31-22)用作一级表(页目录)中的索引值来选择某个页目录项，用以选择某个二级表。
第二级表称为页表。
长度也是1个页面，每个表含有1k个4字节的表项。每个4字节表项含有相关页面的20位物理地址。二级页表使用线性地址中间的10位(位21-12)作为表 项索引值，在表内索引含有页面20位物理地址的表项。该20位页面物理地址和线性地址中的低12位(页内偏移)组合在一起就得到了分页转换中的输出值，也 就是最终的物理地址。
也就是说：
线性地址高10位---------索引页目录表----------->找到相应页表
线性地址中间10位---------索引页表----------->得到页表中相应的项，其中的高20位就是物理地址的高20位
线性地址低12位-------------------->物理地址的低12位
