【笔记】DE2 硬件和处理器范例2 External SRAM interface （DE2）（digital logic）（verilog hdl）

Introduction

    本项目练习使用外部的61LV25616 SRAM，实现以下目标：

• 用KEY0作为时钟输入，驱动一个4位的计数器，以产生一个地址码，然后在前面补充14个0扩展成18位的地址码。这个地址码作为存储器的地址在HEX4和绿色的LED上显示。
• 使用SWITCH[15:0]作为写入SRAM的数据。
• 使用KEY1作为写使能。注意写使能低电平有效，即按钮按下时。
• 在红色LED和HEX3-0上显示存储器总线（读或写）。
• 这个双向的总线可用以下语句配置读或写，注意在Altera的Cyclone II系列，只用FPGA的I/O引脚可作为三态设备。如果指定内部三态，将例化为多路选择器。

        assign SRAM_DQ=(key[1]?16’hzzzz:SW[15:0]);

Design

IS61LV25616简介

    ISSI IS61LV25616是高速SRAM,容量为512KB。DE2上用的是TSOP封装的。引脚图和说明如下：

代码

//Top Module
  //project 2 External SRAM interface
 
 module SRAM_IO(
                            input [1:0] KEY,                    //pushbutton [1:0]
                            input [15:0] SW,                     //toggle switch[15:0]
                            output [6:0] HEX0,         //7-seg display
                            output [6:0] HEX1,         //7-seg display
                            output [6:0] HEX2,         //7-seg display
                            output [6:0] HEX3,         //7-seg display
                            output [6:0] HEX4,         //7-seg display
                            output [6:0] HEX5,         //7-seg display
                            output [6:0] HEX6,         //7-seg display
                            output [3:0] LEDG,        //led green[3:0]
                            output [15:0] LEDR,       //led red[15:0]
                            inout [15:0] SRAM_DQ,            //SRAM data bus 16 bits
                            output [17:0] SRAM_ADDR,    //SRAM address bus 18 bits
                            output SRAM_UB_N,                    //SRAM high-byte data mask
                            output SRAM_LB_N,         //SRAM low-byte data mask
                            output SRAM_WE_N,         //SRAM write enable
                            output SRAM_CE_N,         //SRAM chip enable
                            output SRAM_OE_N         //SRAM output enable
                            );
                            
reg [3:0] shortCount;

assign HEX5=7'b011_1111;    //-
assign HEX6=7'b011_1111;  //-
assign HEX6=7'b011_1111;  //-

//memeory address
//connect KEY0 switch to led to upcount and display
always @(negedge KEY[0])
begin
    shortCount<=shortCount+1;
end
assign LEDG[3:0]=shortCount;    
//display the hex value of the short counter
//this is also the memory address
HexDigit Digit4(HEX4,shortCount);

//SRAM Interface
assign SRAM_ADDR={14'h0,shortCount};    //SRAM Address bus 18 bits
assign SRAM_UB_N=0;                                        //hi byte select enabled
assign SRAM_LB_N=0;                                        //lo byte select enabled
assign SRAM_CE_N=0;                                        //chip is enabled
assign SRAM_WE_N=KEY[1];                            //write when KEY1 is pressed
assign SRAM_OE_N=0;                                        //output enable is overidden by WE
//if KEY1 is not pressed, then float bus, so that SRAM can drive it (read)
//if KEY1 is pressed, drive it with data from SW[15:0] to be stored in SRAM (write)
assign SRAM_DQ=(KEY[1]?16'hzzzz:SW[15:0]);
//show memory on the LEDs and 7-seg display
assign LEDR[15:0]=SRAM_DQ;
HexDigit Digit0(HEX0,SRAM_DQ[3:0]); 
HexDigit Digit1(HEX1,SRAM_DQ[7:4]); 
HexDigit Digit2(HEX2,SRAM_DQ[11:8]); 
HexDigit Digit3(HEX3,SRAM_DQ[15:12]); 

endmodule

//Decode one hex digit for LED 7-seg display

module HexDigit(segs,num
                                //input [3:0] num,
                                //output reg [6:0] segs
                                );
input [3:0] num;
output [6:0] segs;
reg [6:0] segs;
                                
always @(num)
begin
    case(num)
        4'h0: segs = 7'b1000000;
        4'h1: segs = 7'b1111001;
        4'h2: segs = 7'b0100100;
      4'h3: segs = 7'b0110000;
        4'h4: segs = 7'b0011001;
        4'h5: segs = 7'b0010010;
        4'h6: segs = 7'b0000010;
        4'h7: segs = 7'b1111000;
        4'h8: segs = 7'b0000000;
        4'h9: segs = 7'b0010000;
        4'ha: segs = 7'b0001000;
        4'hb: segs = 7'b0000011;
        4'hc: segs = 7'b1000110;
        4'hd: segs = 7'b0100001;
        4'he: segs = 7'b0000110;
        4'hf: segs = 7'b0001110;
        default segs = 7'b1111111;    
    endcase
end

endmodule

Results and Analysis

    经下载测试，按KEY0来产生一个时钟脉冲，驱动4位的计数器，计数输出显示在HEX4和绿色的LED上。当没按下KEY1时，HEX3-0的显示是浮动的，这时SRAM执行的读操作，按下KEY1，HEX3-0显示当前SW[15:0]的值，当然同样的值也显示在红色的LED上，这时为写SRAM。由上面的真值表可知通过KEY1控制WE的高低，进而控制读写。都由

assign SRAM_WE_N=KEY[1];

 

assign SRAM_DQ = (KEY[1]? 16'hzzzz : SW[15:0]);

实现。

Conclusion

    因为本例采用按KEY0产生时钟脉冲的方法来验证SRAM的读写操作。大大简化了时序控制的问题。IS61LV25616共7种端口，16位的双向的数据总线SRAM_DQ；18位的地址总线SRAM_ADDR；高/低8位标记SRAM_UB_N和SRAM_LB_N；读写使能SRAM_WE_N；片选使能SRAM_CE_N;输出使能SRAM_OE_N;标识符里的_N表示低电平有效。本例比较投机的地方就是关于4位计数器生成的地址码，总共16个地址码，便于验证，可每按一次KEY0，设置一次SW[15:0]作为输入数据，再按一次KEY1记录当前数据。连续记录16个数据后，可通过按KEY0观察HEX3-0的输出。

Reference

1> 61LV25616_SRAM data sheet

2> ECE 576 Cornell University

3> Terasic’s DE2 user manual and code example