cross socket tcp client demo

cross socket tcp client demo

/// <author>cxg 2020-8-13</author>
/// cross socket tcp client demo

unit Unit1;

interface

uses
  MsgPack, uCmd, uCrossTcpClient,
  System.SysUtils, System.Types, System.UITypes, System.Classes, System.Variants,
  FMX.Types, FMX.Controls, FMX.Forms, FMX.Graphics, FMX.Dialogs,
  FMX.Controls.Presentation, FMX.Edit, FMX.StdCtrls, System.Rtti, FMX.Grid.Style,
  FMX.ScrollBox, FMX.Grid, Data.DB, Datasnap.DBClient, Data.Bind.EngExt,
  Fmx.Bind.DBEngExt, Fmx.Bind.Grid, System.Bindings.Outputs, Fmx.Bind.Editors,
  Data.Bind.Components, Data.Bind.Grid, Data.Bind.DBScope;

type
  TForm1 = class(TForm)
    Edit1: TEdit;
    Edit2: TEdit;
    Button1: TButton;
    Button2: TButton;
    StringGrid1: TStringGrid;
    StringGrid2: TStringGrid;
    ClientDataSet1: TClientDataSet;
    ClientDataSet2: TClientDataSet;
    BindSourceDB1: TBindSourceDB;
    BindingsList1: TBindingsList;
    LinkGridToDataSourceBindSourceDB1: TLinkGridToDataSource;
    BindSourceDB2: TBindSourceDB;
    LinkGridToDataSourceBindSourceDB2: TLinkGridToDataSource;
    Button3: TButton;
    OpenDialog1: TOpenDialog;
    Timer1: TTimer;
    Button4: TButton;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure Button3Click(Sender: TObject);
    procedure Timer1Timer(Sender: TObject);
    procedure Button4Click(Sender: TObject);
  private
    { Private declarations }
    fClient: TCrossTcpClient;
    procedure query(pack: TMsgPack);   //因为cross tcp是全异步，所以回叫方法处理远程方法返回结果
    procedure save(pack: TMsgPack);
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.fmx}

{ TForm1 }

procedure TForm1.Button1Click(Sender: TObject);
//连接中间件
begin
  fClient.Connect(Edit1.Text, StrToInt(Edit2.Text));
  Button1.Enabled := False;
end;

procedure TForm1.Button2Click(Sender: TObject);
//查询
begin
  var pack: TMsgPack := TMsgPack.Create;
  pack.Force('accountno').AsString := '1';    //帐套号
  pack.Force('plugid').AsInteger :=9999;      //插件编号
  pack.Force('funcid').AsInteger := cmd_query; //查询
  pack.Force('sql1').AsString := 'select * from tgoods';
  pack.Force('sql2').AsString := 'select * from tunit';
  pack.Force('tablenum').AsInteger := 2;   //查询2个表
  pack.Force('cmd').AsInteger := cmd_plugbin;  //二进制序列
  fClient.Send(pack);
end;

procedure TForm1.Button3Click(Sender: TObject);
//上传文件
begin
  if OpenDialog1.Execute then begin
    var pack: TMsgPack := TMsgPack.Create;
    pack.Force('filenum').AsInteger := 1;     //上传几个文件
    pack.Force('file1').LoadBinaryFromFile(OpenDialog1.FileName); //文件
    pack.Force('filename1').AsString := ExtractFileName(OpenDialog1.FileName);  //文件名称
    pack.Force('plugid').AsInteger := 8888;   //插件编号
    pack.Force('funcid').AsInteger := cmd_up;  //上传文件
    pack.Force('cmd').AsInteger := cmd_plugbin;  //二进制序列
    fClient.Send(pack);
  end;
end;

procedure TForm1.Button4Click(Sender: TObject);
//保存修改的数据
begin
  if ClientDataSet2.State in [dsInsert, dsEdit] then
    ClientDataSet2.Post;
  if ClientDataSet2.ChangeCount = 0 then
    Exit;
  var pack: TMsgPack := TMsgPack.Create;
  pack.Force('accountno').AsString := '1';   //帐套号
  pack.Force('plugid').AsInteger :=9999;     //插件编号
  pack.Force('funcid').AsInteger := cmd_save;  //保存修改的数据
  pack.Force('tablenum').AsInteger := 1;       //保存几个表
  pack.Force('tablename1').AsString := 'tunit';  //待保存表名
  pack.Force('delta1').AsVariant := ClientDataSet2.Delta;  //修改的数据
  pack.Force('cmd').AsInteger := cmd_plugbin; //二进制序列
  fClient.Send(pack);
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  fClient := TCrossTcpClient.Create;
  fClient.OnQuery := query;
  fClient.OnSave := save;
//  Button1Click(nil);
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  fClient.Free;
end;

procedure TForm1.query(pack: TMsgPack);
//查询返回结果处理
begin
  ClientDataSet1.Data := pack.Force('dataset1').AsVariant;
  ClientDataSet2.Data := pack.Force('dataset2').AsVariant;
end;

procedure TForm1.save(pack: TMsgPack);
//保存数据返回结果处理
begin
  if pack.Force('return').AsBoolean then
  begin
    ClientDataSet2.MergeChangeLog;
    ShowMessage('保存成功');
  end
  else
  begin
    ClientDataSet2.Cancel;
    ShowMessage('保存失败');
  end;
end;

procedure TForm1.Timer1Timer(Sender: TObject);
begin
  Button2Click(nil);
end;

end.