zoukankan html css js c++ java

Oracle Cusor

Ref:http://blog.csdn.net/yhmhappy2006/article/details/5552574

一概念
游标是SQL的一个内存工作区，由系统或用户以变量的形式定义。游标的作用就是用于临时存储从数据库中提取的数据块。在某些情况下，需要把数据从存放在磁盘的表中调到计算机内存中进行处理，最后将处理结果显示出来或最终写回数据库。这样数据处理的速度才会提高，否则频繁的磁盘数据交换会降低效率。
二类型
Cursor类型包含三种: 隐式Cursor，显式Cursor和Ref Cursor（动态Cursor）。
1．隐式Cursor:
1).对于Select …INTO…语句，一次只能从数据库中获取到一条数据，对于这种类型的DML Sql语句，就是隐式Cursor。例如：Select /Update / Insert/Delete操作。
2)作用：可以通过隐式Cusor的属性来了解操作的状态和结果，从而达到流程的控制。Cursor的属性包含：
SQL%ROWCOUNT 整型代表DML语句成功执行的数据行数
SQL%FOUND 布尔型值为TRUE代表插入、删除、更新或单行查询操作成功
SQL%NOTFOUND 布尔型与SQL%FOUND属性返回值相反
SQL%ISOPEN 布尔型 DML执行过程中为真，结束后为假
3) 隐式Cursor是系统自动打开和关闭Cursor.
下面是一个Sample：

View Code

 1 Set Serveroutput on;
 2 
 3 begin
 4     update t_contract_master set liability_state = 1 where policy_code = '123456789';
 5     
 6     if SQL%Found then
 7        dbms_output.put_line('the Policy is updated successfully.');
 8        commit;
 9     else
10       dbms_output.put_line('the policy is updated failed.');
11     end if;
12 
13 end;
14 
15 /

2．显式Cursor：
（1）对于从数据库中提取多行数据，就需要使用显式Cursor。显式Cursor的属性包含：
游标的属性   返回值类型   意    义
%ROWCOUNT   整型获得FETCH语句返回的数据行数
%FOUND 布尔型最近的FETCH语句返回一行数据则为真，否则为假
%NOTFOUND   布尔型与%FOUND属性返回值相反
%ISOPEN 布尔型游标已经打开时值为真，否则为假

（2）对于显式游标的运用分为四个步骤：
 定义游标---Cursor [Cursor Name] IS;
 打开游标---Open [Cursor Name];
 操作数据---Fetch [Cursor name]
 关闭游标---Close [Cursor Name],这个Step绝对不可以遗漏。
（3）以下是三种常见显式Cursor用法。

View Code

 1 Set serveroutput on;
 2 
 3 declare 
 4     ---define Cursor
 5     Cursor cur_policy is
 6      select cm.policy_code, cm.applicant_id, cm.period_prem,cm.bank_code,cm.bank_account
 7      from t_contract_master cm
 8      where cm.liability_state = 2
 9      and cm.policy_type = 1
10      and cm.policy_cate in ('2','3','4')
11      and rownum < 5
12      order by cm.policy_code desc;
13     curPolicyInfo cur_policy%rowtype;---定义游标变量
14 Begin
15    open cur_policy; ---open cursor
16    Loop 
17      --deal with extraction data from DB
18      Fetch cur_policy into curPolicyInfo;
19      Exit when cur_policy%notfound;
20          
21      Dbms_Output.put_line(curPolicyInfo.policy_code);
22    end loop;
23    Exception 
24      when others then
25          close cur_policy;
26          Dbms_Output.put_line(Sqlerrm);
27          
28    if cur_policy%isopen then  
29     --close cursor 
30       close cur_policy;
31    end if;
32 end;
33 
34 /
35 ------------------------
36 
37 Set serveroutput on;
38 
39 declare 
40     Cursor cur_policy is
41      select cm.policy_code, cm.applicant_id, cm.period_prem,cm.bank_code,cm.bank_account
42      from t_contract_master cm
43      where cm.liability_state = 2
44      and cm.policy_type = 1
45      and cm.policy_cate in ('2','3','4')
46      and rownum < 5
47      order by cm.policy_code desc;
48      v_policyCode t_contract_master.policy_code%type;
49      v_applicantId t_contract_master.applicant_id%type;
50      v_periodPrem t_contract_master.period_prem%type;
51      v_bankCode t_contract_master.bank_code%type;
52      v_bankAccount t_contract_master.bank_account%type;
53 Begin
54    open cur_policy;
55    Loop 
56      Fetch cur_policy into v_policyCode,
57                            v_applicantId,
58                            v_periodPrem,
59                            v_bankCode,
60                            v_bankAccount;
61      Exit when cur_policy%notfound;
62          
63      Dbms_Output.put_line(v_policyCode);
64    end loop;
65    Exception 
66      when others then
67          close cur_policy;
68          Dbms_Output.put_line(Sqlerrm);
69          
70    if cur_policy%isopen then   
71       close cur_policy;
72    end if;
73 end;
74 /
75 --------------------------------
76 Set serveroutput on;
77 
78 declare 
79     Cursor cur_policy is
80      select cm.policy_code, cm.applicant_id, cm.period_prem,cm.bank_code,cm.bank_account
81      from t_contract_master cm
82      where cm.liability_state = 2
83      and cm.policy_type = 1
84      and cm.policy_cate in ('2','3','4')
85      and rownum < 5
86      order by cm.policy_code desc;
87 Begin
88    For rec_Policy in cur_policy loop
89        Dbms_Output.put_line(rec_policy.policy_code);
90    end loop;
91    Exception 
92      when others then
93          Dbms_Output.put_line(Sqlerrm);
94          
95 end;
96 
97 /

3． Ref Cursor（动态游标）：
1）与隐式Cursor,显式Cursor的区别：Ref Cursor是可以通过在运行期间传递参数来获取数据结果集。而另外两种Cursor，是静态的，在编译期间就决定数据结果集。
2） Ref cursor的使用:
 Type [Cursor type name] is ref cursor
 Define 动态的Sql语句
 Open cursor
 操作数据---Fetch [Cursor name]
 Close Cursor
下面是一个Sample：

View Code

 1 Set serveroutput on;
 2 
 3 Declare
 4     ---define cursor type name
 5     type cur_type is ref cursor;
 6     cur_policy cur_type;
 7     sqlStr varchar2(500);
 8     rec_policy t_contract_master%rowtype;
 9 begin
10    ---define 动态Sql
11    sqlStr := 'select cm.policy_code, cm.applicant_id, cm.period_prem,cm.bank_code,cm.bank_account from t_contract_master cm
12      where cm.liability_state = 2 
13      and cm.policy_type = 1 
14      and cm.policy_cate in (2,3,4) 
15      and rownum < 5 
16      order by cm.policy_code desc ';
17 ---Open Cursor
18   open cur_policy for sqlStr;
19   loop
20        fetch cur_policy into rec_policy.policy_code, rec_policy.applicant_id, rec_policy.period_prem,rec_policy.bank_code,rec_policy.bank_account;
21        exit when cur_policy%notfound;
22        
23        Dbms_Output.put_line('Policy_code:'||rec_policy.policy_code);
24   
25   end loop;
26 close cur_policy;    
27 
28 end;
29 /

4.常见Exception

View Code

01. 错 误 名 称 错误代码    错 误 含 义     
02.  CURSOR_ALREADY_OPEN ORA_06511   试图打开已经打开的游标     
03.  INVALID_CURSOR  ORA_01001   试图使用没有打开的游标     
04.  DUP_VAL_ON_INDEX    ORA_00001   保存重复值到惟一索引约束的列中     
05.  ZERO_DIVIDE ORA_01476   发生除数为零的除法错误     
06.  INVALID_NUMBER  ORA_01722   试图对无效字符进行数值转换     
07.  ROWTYPE_MISMATCH    ORA_06504   主变量和游标的类型不兼容     
08   VALUE_ERROR ORA_06502   转换、截断或算术运算发生错误     
09.  TOO_MANY_ROWS   ORA_01422   SELECT…INTO…语句返回多于一行的数据     
10.  NO_DATA_FOUND   ORA_01403   SELECT…INTO…语句没有数据返回     
11.  TIMEOUT_ON_RESOURCE ORA_00051   等待资源时发生超时错误     
12.  TRANSACTION_BACKED_OUT  ORA_00060   由于死锁，提交失败     
13.  STORAGE_ERROR   ORA_06500   发生内存错误     
14.  PROGRAM_ERROR   ORA_06501   发生PL/SQL内部错误     
15.  NOT_LOGGED_ON   ORA_01012   试图操作未连接的数据库     
16.  LOGIN_DENIED    ORA_01017   在连接时提供了无效用户名或口令

附：使用游标

View Code

  1 15-1:使用标量变量接收游标数据
  2     DECLARE
  3       CURSOR emp_cursor IS
  4         SELECT ename,job,sal FROM emp WHERE deptno=&dno;
  5       v_ename emp.ename%TYPE;
  6       v_sal emp.sal%TYPE;
  7       v_job emp.job%TYPE;
  8     BEGIN
  9       OPEN emp_cursor;
 10       LOOP
 11         FETCH emp_cursor INTO v_ename,v_job,v_sal;
 12         EXIT WHEN emp_cursor%NOTFOUND;
 13         dbms_output.put_line('姓名：'||v_ename||'，岗位：'||v_job||'，工资：'||v_sal);
 14       END LOOP;
 15       CLOSE emp_cursor;
 16     END;
 17     /
 18 15-2:使用pl/sql纪录变量接收游标数据
 19     DECLARE
 20       CURSOR emp_cursor IS
 21         SELECT ename,sal FROM emp ORDER BY sal DESC;
 22       emp_record emp_cursor%ROWTYPE;
 23     BEGIN
 24       OPEN emp_cursor;
 25       LOOP
 26         FETCH emp_cursor INTO emp_record;
 27         EXIT WHEN emp_cursor%NOTFOUND OR emp_cursor%ROWCOUNT>&n;
 28         dbms_output.put_line('姓名：'||emp_record.ename||
 29          '，工资：'||emp_record.sal);
 30       END LOOP;
 31       CLOSE emp_cursor;
 32     END;
 33     /
 34 15-3:使用pl/sql集合变量接收游标数据
 35     DECLARE
 36       CURSOR emp_cursor IS SELECT ename,sal FROM emp
 37         WHERE lower(job)=lower('&job');
 38       TYPE emp_table_type IS TABLE OF emp_cursor%ROWTYPE
 39         INDEX BY BINARY_INTEGER;
 40       emp_table emp_table_type;
 41       i INT;
 42     BEGIN
 43       OPEN emp_cursor;
 44       LOOP
 45         i:=emp_cursor%ROWCOUNT+1;
 46         FETCH emp_cursor INTO emp_table(i);
 47         EXIT WHEN emp_cursor%NOTFOUND;
 48         dbms_output.put_line('姓名：'||emp_table(i).ename||
 49           '，工资：'||emp_table(i).sal);
 50       END LOOP;
 51       CLOSE emp_cursor;
 52     END;
 53     /
 54 15-4:在游标for循环中引用已定义游标
 55     DECLARE
 56       CURSOR emp_cursor IS SELECT ename,hiredate FROM emp
 57         ORDER BY hiredate DESC;
 58     BEGIN
 59       FOR emp_record IN emp_cursor LOOP
 60         dbms_output.put_line('姓名：'||emp_record.ename
 61           ||',工作日期：'||emp_record.hiredate);
 62         EXIT WHEN emp_cursor%ROWCOUNT=&n;
 63       END LOOP;
 64     END;
 65     /
 66 15-5:在游标for循环中直接引用子查询
 67     BEGIN
 68       FOR emp_record IN (SELECT ename,hiredate,rownum FROM emp
 69         ORDER BY hiredate) LOOP
 70         dbms_output.put_line('姓名：'||emp_record.ename
 71          ||',工作日期：'||emp_record.hiredate);
 72         EXIT WHEN emp_record.rownum=&n;
 73       END LOOP;
 74     END;
 75     /
 76 15-6:参数游标
 77     DECLARE
 78       CURSOR emp_cursor(dno NUMBER) IS
 79         SELECT ename,job FROM emp WHERE deptno=dno;
 80     BEGIN
 81       FOR emp_record IN emp_cursor(&dno) LOOP
 82         dbms_output.put_line('姓名：'||emp_record.ename
 83           ||',岗位：'||emp_record.job);
 84       END LOOP;
 85     END;
 86     /
 87 15-7:更新游标行
 88     DECLARE
 89       CURSOR emp_cursor IS
 90         SELECT ename,sal,deptno FROM emp FOR UPDATE;
 91       dno INT:=&no;
 92     BEGIN
 93       FOR emp_record IN emp_cursor LOOP
 94         IF emp_record.deptno=dno THEN
 95            dbms_output.put_line('姓名:'||emp_record.ename
 96             ||',原工资:'||emp_record.sal);
 97            UPDATE emp SET sal=sal*1.1 WHERE CURRENT OF emp_cursor;
 98         END IF;
 99       END LOOP;
100     END;
101     /
102 15-8:删除游标行
103     DECLARE
104       CURSOR emp_cursor IS
105         SELECT ename FROM emp FOR UPDATE;
106       name VARCHAR2(10):=lower('&name');
107     BEGIN
108       FOR emp_record IN emp_cursor LOOP
109         IF lower(emp_record.ename)=name THEN
110            DELETE FROM emp WHERE CURRENT OF emp_cursor;
111         ELSE
112            dbms_output.put_line('姓名:'||emp_record.ename);
113         END IF;
114       END LOOP;
115     END;
116     /
117 15-9:使用of子句在特定表上加行共享锁．
118     DECLARE
119       CURSOR emp_cursor IS
120         SELECT a.dname,b.ename FROM dept a JOIN emp b
121         ON a.deptno=b.deptno
122         FOR UPDATE OF b.deptno;
123       name VARCHAR2(10):=LOWER('&name');
124     BEGIN
125       FOR emp_record IN emp_cursor LOOP
126         IF LOWER(emp_record.dname)=name THEN
127           dbms_output.put_line('姓名:'||emp_record.ename);
128           DELETE FROM emp WHERE CURRENT OF emp_cursor;
129         END IF;
130       END LOOP;
131     END;
132     /
133 15-10:使用无返回类型的游标变量
134     DECLARE
135       TYPE ref_cursor_type IS REF CURSOR;
136       ref_cursor ref_cursor_type;
137       v1 NUMBER(6);
138       v2 VARCHAR2(10);
139     BEGIN
140       OPEN ref_cursor FOR
141         SELECT &col1 col1,&col2 col2 FROM &table WHERE &cond;
142       LOOP
143         FETCH ref_cursor INTO v1,v2;
144         EXIT WHEN ref_cursor%NOTFOUND;
145         dbms_output.put_line('col1='||v1||',col2='||v2);
146       END LOOP;
147       CLOSE ref_cursor;
148     END;
149     /
150 15-11:使用有返回类型的游标变量
151     DECLARE
152       TYPE emp_cursor_type IS REF CURSOR RETURN emp%ROWTYPE;
153       emp_cursor emp_cursor_type;
154       emp_record emp%ROWTYPE;
155     BEGIN
156       OPEN emp_cursor FOR SELECT * FROM emp
157         WHERE deptno=&dno;
158       LOOP
159         FETCH emp_cursor INTO emp_record;
160         EXIT WHEN emp_cursor%NOTFOUND;
161         dbms_output.put_line('姓名:'||emp_record.ename||
162           ',工资:'||emp_record.sal);
163       END LOOP;
164       CLOSE emp_cursor;
165     END;
166     /
167 15-12:使用fetch...bulk collect提取所有数据
168     DECLARE
169       CURSOR emp_cursor IS
170         SELECT * FROM emp WHERE LOWER(job)=LOWER('&job');
171       TYPE emp_table_type IS TABLE OF emp%ROWTYPE;
172       emp_table emp_table_type;
173     BEGIN
174       OPEN emp_cursor;
175       FETCH emp_cursor BULK COLLECT INTO emp_table;
176       CLOSE emp_cursor;
177       FOR i IN 1.. emp_table.COUNT LOOP
178         dbms_output.put_line('姓名:'||emp_table(i).ename
179           ||',工资:'||emp_table(i).sal);
180       END LOOP;
181     END;
182     /
183 15-13:使用limit子句限制提取行数
184     DECLARE
185       CURSOR emp_cursor IS SELECT * FROM emp;
186       TYPE emp_array_type IS VARRAY(5) OF emp%ROWTYPE;
187       emp_array emp_array_type;
188     BEGIN
189       OPEN emp_cursor;
190       LOOP
191         FETCH emp_cursor BULK COLLECT INTO emp_array LIMIT &rows;
192         FOR i IN 1..emp_array.COUNT LOOP
193           dbms_output.put_line('姓名:'||emp_array(i).ename
194             ||',工资:'||emp_array(i).sal);
195         END LOOP;
196         EXIT WHEN emp_cursor%NOTFOUND;
197       END LOOP;
198       CLOSE emp_cursor;
199     END;
200     /
201 15-14:使用cursor表达式
202     DECLARE
203       CURSOR dept_cursor(no NUMBER) IS
204          SELECT a.dname,CURSOR(SELECT * FROM emp
205          WHERE deptno=a.deptno)
206          FROM dept a WHERE a.deptno=no;
207       TYPE ref_cursor_type IS REF CURSOR;
208       emp_cursor ref_cursor_type;
209       emp_record emp%ROWTYPE;
210       v_dname dept.dname%TYPE;
211     BEGIN
212       OPEN dept_cursor(&dno);
213       LOOP
214          FETCH dept_cursor INTO v_dname,emp_cursor;
215          EXIT WHEN dept_cursor%NOTFOUND;
216          dbms_output.put_line('部门名:'||v_dname);
217          LOOP
218            FETCH emp_cursor INTO emp_record;
219            EXIT WHEN emp_cursor%NOTFOUND;
220            dbms_output.put_line('----雇员名:'||emp_record.ename
221             ||',岗位:'||emp_record.job);
222          END LOOP;
223       END LOOP;
224       CLOSE dept_cursor;
225     END;
226     /

查看全文

相关阅读:
福大软工1816 · 第四次作业
 福大软工1816 · 第三次作业
 福大软工1816 · 第二次作业
 福大软工1816 · 第四次作业
 福大软工1816 · 第三次作业
 Alpha 冲刺（4/10）
Alpha 冲刺（3/10）
Alpha 冲刺（2/10）
Alpha 冲刺（1/10）
项目需求分析

原文地址：https://www.cnblogs.com/kevinkim/p/2363408.html