利用多线程解除耦合/线程解耦合/DeAfterCreate/DeClose

当软件启动时，我们希望从配置文件中加载参数，然后用这些参数，改变窗口的状态大小，或者组件的属性。

通常的做法是在 TForm 的 OnCreate 事件中或者 OnFirstShow 事件中执行这些任务。 但是，但某些改变窗口的语句，

在这些事件中执行时，是会发生冲突的。比如：在 OnShow 事件中，不能去改变 visiable 属性。因此，我们需要一个真正解除耦合的事件，

此处将其定义为 DeAfterCreate , 即称为 解除耦合的 AfteCreate 事件。 同样地，也实现了一个 DeClose 事件。

本例源代码(delphi 10.3.2)

unit uFrmDeBase;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs;

type
  TFrmDeBase = class(TForm)
    procedure FormShow(Sender: TObject);
  private
    { Private declarations }
    FNotFirstShow: Boolean; // 取名为这样是利用默认值为 false, 减少去 create 事件中去赋值。
  protected
    procedure DeAfterCreate(); virtual;
    procedure DeClose();
  public
    { Public declarations }
  end;

implementation

{$R *.dfm}

procedure TFrmDeBase.DeAfterCreate;
begin
end;

procedure TFrmDeBase.DeClose;
begin
  TThread.CreateAnonymousThread(
    procedure
    begin
      TThread.Queue(nil,
        procedure
        begin
          Self.Close;
        end);
    end).Start; // 创建一个匿名线程
    // 在匿名线程中，再排队执行主线程时空的代码
end;

procedure TFrmDeBase.FormShow(Sender: TObject);
begin
  // 我们利用 FirstOnShow 这个时机，创造一个解除耦合的 DeAfterCreate 事件。
  if not FNotFirstShow then
  begin
    FNotFirstShow := true;
    TThread.CreateAnonymousThread(
      procedure
      begin
        TThread.Queue(nil,
          procedure
          begin
            DeAfterCreate;
          end);

      end).Start;
  end;
end;

end.

unit uFrmMain;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, uFrmDeBase, Vcl.StdCtrls;

type
  TFrmMain = class(TFrmDeBase)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
  protected
    procedure DeAfterCreate(); override;
  public
    { Public declarations }
  end;

var
  FrmMain: TFrmMain;

implementation

{$R *.dfm}
{ TFrmMain }

procedure TFrmMain.Button1Click(Sender: TObject);
begin
  inherited;
  DeClose;
  // 你可以在各种事件中(OnClose事件中除外)，执行 DeClose 函数。
  // 不必担心耦合问题。
  // 这个相当于“延时执行” Close 动作。
  // ***
  // 如果没有解除耦合,就可能在 Close 动作之后，返回到别的事件函数中，执行了比如设置组件信息操作。导致出错。
  // “延时执行”，相当于此函数不在“任何函数中调用的。“完全独立”。
  // 解除耦合，是很重要的编程思维，可以让多任务，复杂关系调用简单化。
end;

procedure TFrmMain.DeAfterCreate;
begin
  // 此处是解耦合的 AfterCreate 事件
  // 在此时，窗口已经真正创建完毕
  // 可以在此处加载各种参数
  // 可以设置窗口大小，位置，等信息而不会发生错误。
  /// *****************
  // 比如：你直接在 OnShow / OnCreate 等其它事件中
  // 因为没有解除耦合，下面的功能会发生错误
  self.Position := poScreenCenter;
  self.Visible := false;
  self.Visible := true;
  self.BringToFront;
end;

end.