【汇总】flash单个文件上传

之前有朋友给我发送email，询问我是否有单个文件上传的源代码，因为当时写这个好像是在09年，所以放哪了一时也没找着。后来整理硬盘的时候，找到了源码，所以决定来个汇总（之前写过的关于flash+js上传文件的例子）：

1、定位flash上传出现IO Error #2038的错误

2、as3+php上传图片的三种方式

3、as3与php 上传单个图片demo

4、as3与php 上传多张图片demo

5、51JS上的“[原创] flash单个文件上传代码+示例”

在这里面，我决定把所有的源码：html、js、php、fla、as3以及使用说明一并打包，并直接提供下载。

先还是讲一下flash按钮的控制问题：

1)、需要三张图片，新建一个影片剪辑，也就是按钮的三种状态：正常、hover、disabled，如下图所示（三种状态的图片，分别位于第一帧、第二帧和第三帧，每一帧上写上脚本stop())

2)、在库中右击选中刚刚的btn(影片剪辑)，然后右击选择“属性”，勾选“为第一帧导出”以及“为ActionScript导出“，如图所示：

3)、编写类UploadButtonCom类，它继承于基类MovieClip，目的是为了方便调用者直接调用一个方法便可很方便地控制按钮的状态，比如：mouseover、mouseout等

UploadButtonCom类的完整代码如下：

package
{
    import flash.display.MovieClip;
    import flash.events.MouseEvent;

    public class UploadButtonCom extends MovieClip
    {
        public function UploadButtonCom()
        {
            super();
            init();
        }

        private function init():void
        {
            enabledButton();
            this.addEventListener(MouseEvent.MOUSE_OVER , overHandle);
            this.addEventListener(MouseEvent.MOUSE_OUT  , outHandle)
        }

        private function overHandle(e:MouseEvent):void
        {
            this.gotoAndStop(2)
        }

        private function outHandle(e:MouseEvent):void
        {
            this.gotoAndStop(1)
        }

        public function disenable():void
        {
            this.gotoAndStop(3);
            this.buttonMode = false
            this.mouseChildren = false;
            this.mouseEnabled  = false
        }

        public function enabledButton():void
        {
            this.gotoAndStop(1);
            this.buttonMode = true
            this.mouseChildren = true;
            this.mouseEnabled  = true
        }
    }
}

提供给外部仅二个方法来控制按钮是否可以被点击。

4)、从库中将“按钮”这个MovieClip拖至舞台中，指定一个名称“btn_mc“，编写一个文档类“UploadFile.as”

package
{
    import flash.display.MovieClip;
    import flash.events.DataEvent;
    import flash.events.Event;
    import flash.events.IOErrorEvent;
    import flash.events.MouseEvent;
    import flash.events.ProgressEvent;
    import flash.external.ExternalInterface;
    import flash.net.FileFilter;
    import flash.net.FileReference;
    import flash.net.URLRequest;
    import flash.text.TextField;

    public class UploadFile extends MovieClip
    {
        public function UploadFile()
        {
            super();
            init();
        }

        private var tipTxt:TextField;
        private var uploadButton:UploadButtonCom;

        private var file:FileReference;
        private var fileType:String = '*.*';
        private var fileTypeStr:String = 'All Files'
        private var fileMaxSize:Number = 10*1024;
        private var uploadURL:String = '';
        private static var CALL_FUNCTION_NAME = "SWFSingleUpload.instance.";

        private function init():void
        {
            tipTxt = this.txt_mc;
            tipTxt.mouseEnabled = false;
            tipTxt.mouseWheelEnabled = false;
            tipTxt.selectable = false;

            uploadButton = this.btn_mc;
            uploadButton.addEventListener(MouseEvent.CLICK , browseFile);

            addJScall();
            this.addEventListener(Event.ADDED_TO_STAGE , createComplete);

            file = new FileReference();
            file.addEventListener(Event.SELECT, selectHandler);
            file.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            file.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            file.addEventListener(Event.COMPLETE, completeHandler);
            file.addEventListener(DataEvent.UPLOAD_COMPLETE_DATA,dataHandler);
        }

        private function createComplete(e:Event):void
        {
            ExternalInterface.call(CALL_FUNCTION_NAME + "initComplete");
        }

        private function addJScall():void
        {
            ExternalInterface.addCallback("setValue",setValue);
        }

        private function setValue(t:String,_fileType:String,_fileTypeStr:String,fileMax:Number,url:String):void
        {
            tipTxt.htmlText = t;
            fileMaxSize = fileMax;
            fileType    = _fileType;
            fileTypeStr = _fileTypeStr;
            uploadURL   = url;
        }

        private function startUploadFile():void
        {
            if(file.size/1024 > fileMaxSize)
            {
                ExternalInterface.call(CALL_FUNCTION_NAME + "limitError","文件超出最大限制");
                return ;
            }
            ExternalInterface.call(CALL_FUNCTION_NAME + "startUpload");
            uploadButton.disenable();
            var uploadReq:URLRequest = new URLRequest(uploadURL)
            file.upload(uploadReq);
        }

        private function selectHandler(e:Event):void
        {
            startUploadFile();
        }

        private function browseFile(e:Event):void
        {
            var fileFilter:FileFilter = new FileFilter(fileTypeStr, fileType);
             file.browse([fileFilter]);
        }

        private function ioErrorHandler(e:IOErrorEvent):void
        {
            ExternalInterface.call(CALL_FUNCTION_NAME + "ioError",e.text);
            uploadButton.enabledButton();
        }

        private function progressHandler(event:ProgressEvent):void
        {
            ExternalInterface.call(CALL_FUNCTION_NAME + "progress",event.bytesLoaded,event.bytesTotal);
        }

        private function completeHandler(e:Event):void
        {
            ExternalInterface.call(CALL_FUNCTION_NAME + "uploadComplete");
            uploadButton.enabledButton();
        }

        private function dataHandler(data:DataEvent):void
        {
            ExternalInterface.call(CALL_FUNCTION_NAME + "uploadSuccess",data.data);
        }
    }
}

之后，我在此基本上封装了一层，写了一个名为“swf_single_upload.js”的JS文件，主要目的是为了方便调用者使用它。

主要包含如下内容：

函数定义：(仅提供给网页调用的接口，与flash无关)
new SWFSingleUpload({
    flash_url : "",//上传文件的URL地址
    upload_url : "",//文件上传的目标地址
    post_params : "",//传递的参数
    file_size_limit : "",//文件上限，默认为；10*1024(以字节为单位)
    file_types : "",//文件类型，以;进行分隔，例如：*.jpg;*.png
    file_types_description : "",//文件上传的描述文字，例如：图片
    debug : true,//是否显示调试信息
    upload_panel_id : "",//上传按钮放置的文件
    upload_btn_text : "",//上传按钮的文字
    upload_loaded_handler : "",//上传组件初始化完成
    upload_start_handler : "",//开始上传的处理方法
    upload_progress_handler : "",//正在上传时的方法
    upload_complete_handler : "",//上传完成的方法
    upload_success_handler : "",//上传成功的方法
    upload_error_handler : ""//上传发生错误调用的方法
);
总共有15个参数
    获取组件的版本号：SWFSingleUpload.version
    获取组件实例对象：SWFSingleUpload.instance指向实例本身
    组件当前swf对象：this.swfObject
    其它全部采用回调的机制进行操作，其中错误信息有：   
        １、超过指定的大小
        ２、其它的IO错误，例如404或是其它

Flash与JS调用的方法说明：
Flash调用JS以SWFSingleUpload.instance.方法名开头
默认限制上传文件类型为：*.* 说明为All Files 最大上传的文件大小为10*1024字节

Flash提供setValue方法给JS调用，以便传入上述参数。
this.addEventListener(Event.ADDED_TO_STAGE,createComplete);//flash初始化完成

flash调用JS的四个方法：
//文件超出最大上限
ExternalInterface.call(CALL_FUNCTION_NAME + "limitError","文件超出最大限制");
//上传进度
ExternalInterface.call(CALL_FUNCTION_NAME,"progress",event.bytesLoaded,event.bytesTotal);
//上传完成
ExternalInterface.call(CALL_FUNCTION_NAME + "uploadComplete");
//上传成功
ExternalInterface.call(CALL_FUNCTION_NAME,"uploadSuccess",data.data);
//上传出现IO错误
ExternalInterface.call(CALL_FUNCTION_NAME + "ioError",e.text);

页面正常运行，选择文件（以图片为例），示意图如下：

本想在新浪的SAE上部署测试一下，可是上传那一块失败了，也就没再继续折腾下去了。还是放一个地址，在线查看示例>>

本示例中所有完整的源代码下载>>

未经本人授权，本文谢绝转载。