杀掉那些死锁的进程

　　前些天，同事遇到一个死锁的问题，走过去看看，一下子不知道怎么写，又想起三年前面试的时候问的一个with(nolock)相关的问题，忙活了一会，弄出个东东　　

　　核心主要是视图sys.SysProcesses，它源自于系统表sysprocesses，前者是微软推荐的用法，因为后者在未来SQL Server版本中可能会被隐藏。视图字段含义见这里。然后是kill 命令，它加上进程id就可以杀掉相应进程，它的简单用法如下：

use Test
go
-- 列出所有进程信息
EXEC sp_who2
go

-- 执行杀掉进程命令
KILL 29
go

 准备工作：

　　1. 

CREATE TABLE  TestDead
(
    id INT IDENTITY(1,1) PRIMARY KEY,
    name NVARCHAR(10) NOT NULL
)
GO

CREATE TABLE  TestDead2
(
    id INT IDENTITY(1,1) PRIMARY KEY,
    name NVARCHAR(10) NOT NULL
)
GO

INSERT INTO TestDead(name)
VALUES ('name01'), 
       ('name02'),
       ('name03')
GO

INSERT INTO TestDead2(name)
VALUES ('name01'), 
       ('name02'),
       ('name03')
GO

BEGIN TRAN  -- 打开一个更新事务，不提交, 锁住第一个表

UPDATE TestDead SET name = 'nameXX' WHERE id = 1

GO


BEGIN TRAN  --开始一个事务，不提交，锁住第二个表

UPDATE TestDead2 SET name = 'nameXX' WHERE id = 1

GO

　　2. 创建了表之后，开始一个更新数据的事务并锁住了表，然后新建多个查询窗口，在各个不同窗口中，分别执行下面两条语句：

-- 查询第一个表

select * from TestDead


-- 查询第二个表

select * from TestDead2

　　3. 现在由于表被锁住，是查询不出数据，除非在后面加上 with(nolock)，如：

select * from TestDead2 with(nolock)

 

列出并杀掉那些死锁的进程：

 

=============================================
-- Author:      Mike Deng
-- Create date: 2014/05/14
-- Description: 杀掉死锁进程
=============================================

DECLARE @toKill BIT = 0 --0 或 NULL 只显示， 1.杀掉

BEGIN
    DECLARE @sql NVARCHAR(MAX);
    DECLARE @fromSql NVARCHAR(MAX);

    SET @fromSql = '
    DECLARE @cmd NVARCHAR(MAX);
    ;with CTE as(
          SELECT distinct Type = ''死锁的进程''
         , a.spid
         , blockId = 0
         , DBName = DB_NAME(a.dbid)
         , a.HostName
         , ProgramName = a.Program_Name
         , Dead = 1
          FROM SYS.SYSPROCESSES a JOIN 
                SYS.SYSPROCESSES as b ON a.spid = b.blocked
                      WHERE a.blocked = 0
            UNION ALL
        SELECT  distinct Type = ''被阻塞进程''
            , a.spid
            , blockId = a.blocked
            , DBName = DB_NAME(a.dbid)
            , a.HostName
            , ProgramName = a.Program_Name
            , Dead = 0
        FROM SYS.SYSPROCESSES a WHERE blocked <> 0
    )  '

    IF(ISNULL(@toKill, 0) = 1)
        BEGIN
            SET @sql = @fromSql 
                + 'SELECT @cmd =  (
                        SELECT  ('' KILL '' + LTRIM(str(spid))) FROM cte WHERE dead = 1
                            FOR XML PATH('''')
                    )
            IF(ISNULL(@cmd, '''') <> '''')
                BEGIN
                    EXEC (@cmd);
                    PRINT ''已执行kill死锁命令【'' + @cmd + ''】， 锁已解除'';
                END 
            ELSE IF(@@RowCount = 0)
                BEGIN
                    PRINT ''未发现死锁, 不能杀掉'';
                END'
        END
    ELSE
        BEGIN
            SET @sql = @fromSql + ' SELECT * FROM cte ';
        END

    EXEC SP_EXECUTESQL @sql
END

 

 

查询结果：

设置参数 @toKill = 1，杀掉它们。

完工！