【Tyvj1601】魔兽争霸（主席树，树套树）

题意：要求在N个数的序列中支持以下操作：

1：将第X个元素加上Y

2：询问当前K大值

n<=30000,m<=50000

思路：树状数组套主席树

Tyvj又炸了，还不知道对不对

var t:array[0..12000000]of record
                           l,r,s:longint;
                          end;
    d:array[1..50000,1..3]of longint;
    a,save,q,root,hash:array[0..100000]of longint;
    b:array[1..200000]of longint;
    n,m,i,j,x,cnt,u,que,s,sum,tmp,len:longint;
    ch:string;

function lowbit(x:longint):longint;
begin
 exit(x and (-x));
end;

procedure update(l,r:longint;var p:longint;x,v:longint);
var mid:longint;
begin
 inc(cnt); t[cnt]:=t[p];
 p:=cnt; t[p].s:=t[p].s+v;
 if l=r then exit;
 mid:=(l+r)>>1;
 if x<=mid then update(l,mid,t[p].l,x,v)
  else update(mid+1,r,t[p].r,x,v);
end;

function query(l,r,k:longint):longint;
var mid,s,i:longint;
begin
 if l=r then exit(l);
 s:=0;
 mid:=(l+r)>>1;
 for i:=1 to len do s:=s+t[t[q[i]].l].s;
 if s>=k then
 begin
  for i:=1 to len do q[i]:=t[q[i]].l;
  exit(query(l,mid,k));
 end
  else
  begin
   for i:=1 to len do q[i]:=t[q[i]].r;
   exit(query(mid+1,r,k-s));
  end;
end;

procedure swap(var x,y:longint);
var t:longint;
begin
 t:=x; x:=y; y:=t;
end;

procedure qsort(l,r:longint);
var i,j,mid:longint;
begin
 i:=l; j:=r; mid:=b[(l+r)>>1];
 repeat
  while mid<b[i] do inc(i);
  while mid>b[j] do dec(j);
  if i<=j then
  begin
   swap(b[i],b[j]);
   inc(i); dec(j);
  end;
 until i>j;
 if l<j then qsort(l,j);
 if i<r then qsort(i,r);
end;

function find(x:longint):longint;
var l,r,mid:longint;
begin
 l:=1; r:=u;
 while l<=r do
 begin
  mid:=(l+r)>>1;
  if hash[mid]=x then exit(mid);
  if hash[mid]>x then l:=mid+1
   else r:=mid-1;
 end;
end;

begin
 assign(input,'tyvj1601.in'); reset(input);
 assign(output,'tyvj1601.out'); rewrite(output);
 readln(n);
 for i:=1 to n do
 begin
  read(a[i]); b[i]:=a[i];
 end;
 que:=n;
 for i:=1 to n do save[i]:=a[i];
 readln(m);
 for i:=1 to m do
 begin
  readln(ch); x:=0;
  if ch[1]='Q' then
  begin
   for j:=3 to length(ch) do x:=x*10+ord(ch[j])-ord('0');
   d[i,1]:=1; d[i,2]:=x; continue;
  end;
  d[i,1]:=2; s:=2;
  for j:=3 to length(ch) do
  begin
   if ch[j]=' ' then inc(s)
    else d[i,s]:=d[i,s]*10+ord(ch[j])-ord('0');
  end;
  if ch[1]='A' then d[i,3]:=-d[i,3];
 end;
 for i:=1 to m do
  if d[i,1]=2 then
  begin
   a[d[i,2]]:=a[d[i,2]]+d[i,3];
   if a[d[i,2]]>0 then
   begin
    inc(que); b[que]:=a[d[i,2]];
   end;
  end;
 qsort(1,que);
 hash[1]:=b[1]; u:=1;
 for i:=2 to que do
  if b[i]<>b[i-1] then begin inc(u); hash[u]:=b[i]; end;
 sum:=n;
 for i:=1 to n do
 begin
  tmp:=find(save[i]);
  j:=i;
  while j<=n do
  begin
   update(1,u,root[j],tmp,1);
   j:=j+lowbit(j);
  end;
 end;
 for i:=1 to m do
  if d[i,1]=1 then
  begin
   len:=0; j:=n;
   while j>0 do
   begin
    inc(len); q[len]:=root[j];
    j:=j-lowbit(j);
   end;
   if sum<d[i,2] then writeln(-1)
    else writeln(hash[query(1,u,d[i,2])]);
  end
   else
   begin
    tmp:=find(save[d[i,2]]);
    j:=d[i,2];
    while j<=n do
    begin
     update(1,u,root[j],tmp,-1);
     j:=j+lowbit(j);
    end;
    save[d[i,2]]:=save[d[i,2]]+d[i,3];
    if save[d[i,2]]>0 then
    begin
     tmp:=find(save[d[i,2]]);
     j:=d[i,2];
     while j<=n do
     begin
      update(1,u,root[j],tmp,1);
      j:=j+lowbit(j);
     end;
    end
     else dec(sum);
   end;

 writeln(sum);
 close(input);
 close(output);
end.