【BZOJ2049】洞穴勘测（LCT）

题意：一张图，要求支持以下操作：

1.加边

2.删边

3.询问两点之间是否联通

100%的数据满足n≤10000, m≤200000 

思路：LCT裸题，不需要维护任何信息

var t:array[0..500000,0..1]of longint;
    fa,rev,q:array[0..500000]of longint;
    n,m,i,x,y,k,j,top,s:longint;
    ch:string;

procedure swap(var x,y:longint);
var t:longint;
begin
 t:=x; x:=y; y:=t;
end;

function isroot(x:longint):boolean;
begin
 if (t[fa[x],0]<>x)and(t[fa[x],1]<>x) then exit(true);
 exit(false);
end;

procedure pushdown(x:longint);
var l,r:longint;
begin
 l:=t[x,0]; r:=t[x,1];
 if rev[x]>0 then
 begin
  rev[x]:=rev[x] xor 1; rev[l]:=rev[l] xor 1; rev[r]:=rev[r] xor 1;
  swap(t[x,0],t[x,1]);
 end;
end;

procedure rotate(x:longint);
var y,z,l,r:longint;
begin
 y:=fa[x]; z:=fa[y];
 if t[y,0]=x then l:=0
  else l:=1;
 r:=l xor 1;
 while not isroot(y) do
 begin
  if t[z,0]=y then t[z,0]:=x
   else t[z,1]:=x;
 end;
 fa[x]:=z; fa[y]:=x; fa[t[x,r]]:=y;
 t[y,l]:=t[x,r]; t[x,r]:=y;
end;

procedure splay(x:longint);
var y,z,k:longint;
begin
 inc(top); q[top]:=x;
 k:=x;
 while not isroot(k) do
 begin
  inc(top); q[top]:=fa[k];
  k:=fa[k];
 end;

 while top>0 do
 begin
  pushdown(q[top]);
  dec(top);
 end;

 while not isroot(x) do
 begin
  y:=fa[x]; z:=fa[y];
  if not isroot(y) then
  begin
   if (t[y,0]=x)xor(t[z,0]=y) then rotate(x)
    else rotate(y);
  end;
  rotate(x);
 end;
end;

procedure access(x:longint);
var last:longint;
begin
 last:=0;
 while x>0 do
 begin
  splay(x); t[x,1]:=last;
  last:=x; x:=fa[x];
 end;
end;

procedure makeroot(x:longint);
begin
 access(x); splay(x); rev[x]:=rev[x] xor 1;
end;

procedure link(x,y:longint);
begin
 makeroot(x); fa[x]:=y;
end;

procedure cut(x,y:longint);
begin
 makeroot(x); access(y); splay(y); t[y,0]:=0; fa[x]:=0;
end;

function findroot(x:longint):longint;
var k:longint;
begin
 access(x); splay(x);
 k:=x;
 while t[k,0]<>0 do k:=t[k,0];
 exit(k);
end;

begin
 assign(input,'bzoj2049.in'); reset(input);
 assign(output,'bzoj2049.out'); rewrite(output);
 readln(n,m);
 for i:=1 to m do
 begin
  readln(ch); k:=length(ch); s:=0; x:=0; y:=0; j:=1;
  repeat
   if (ch[j]=' ') then
   begin
    inc(s);
    while ch[j]=' ' do inc(j);
    continue;
   end;
   if (ch[j]>='0')and(ch[j]<='9') then
   begin
    case s of
     1:x:=x*10+ord(ch[j])-ord('0');
     2:y:=y*10+ord(ch[j])-ord('0');
    end;
   end;
   inc(j);
  until j>k;
  case ch[1] of
   'C':link(x,y);
   'D':cut(x,y);
   'Q':
    if findroot(x)<>findroot(y) then writeln('No')
     else writeln('Yes');
  end;
 end;


 close(input);
 close(output);
end.