【BZOJ3295】动态逆序对（BIT套动态加点线段树）

题意：对于序列A，它的逆序对数定义为满足i<j，且A_i>A_j的数对(i,j)的个数。

给1到n的一个排列，按照某种顺序依次删除m个元素，你的任务是在每次删除一个元素之前统计整个序列的逆序对数。

N<=100000 M<=50000

思路：树套树即可，第i棵树维护前i位中1-j的个数，支持区间求和

外面要套BIT来实现区间加

本来维护剩下的数就可以，但初始化可能要开(n log^2 n) 个个节点，这题又只有128MB……

所以只能维护删除的数了，如果256MB乱搞就行了……

var t:array[0..5100000,0..1]of longint;
    sum:array[0..5100000]of int64;
    root,a,b,a1,a2,c:array[0..110000]of longint;
    n,m,i,x,cnt,l,r,j:longint;
    ans:int64;


procedure pushup(x:longint);
begin
 l:=t[x,0]; r:=t[x,1];
 sum[x]:=sum[l]+sum[r];
end;

procedure update(l,r,x,v:longint;var p:longint);
var mid:longint;
begin
 if p=0 then
 begin
  inc(cnt); p:=cnt;
 end;
 if l=r then
 begin
  sum[p]:=sum[p]+v; exit;
 end;
 mid:=(l+r)>>1;
 if x<=mid then update(l,mid,x,v,t[p,0]);
 if x>mid then update(mid+1,r,x,v,t[p,1]);
 pushup(p);
end;

function query(l,r,x,y,p:longint):int64;
var mid:longint;
begin
 if p=0 then exit(0);
 if (l>=x)and(r<=y) then exit(sum[p]);
 mid:=(l+r)>>1;
 query:=0;
 if x<=mid then query:=query+query(l,mid,x,y,t[p,0]);
 if y>mid then query:=query+query(mid+1,r,x,y,t[p,1]);
 pushup(p);
end;

function lowbit(x:longint):longint;
begin
 exit(x and (-x));
end;

procedure change(i,j,v:longint);
var k:longint;
begin
 k:=i;
 while k<=n do
 begin
  update(1,n,j,v,root[k]);
  k:=k+lowbit(k);
 end;
end;

function getsum(x:longint):longint;
begin
 getsum:=0;
 while x>0 do
 begin
  getsum:=getsum+c[x];
  x:=x-lowbit(x);
 end;
end;

function ask(i,j,x,y:longint):int64;
var k:longint;
begin
 ask:=0;
 if i>j then exit(0);
 if x>y then exit(0);
 k:=j;
 while k>0 do
 begin
  ask:=ask+query(1,n,x,y,root[k]);
  k:=k-lowbit(k);
 end;
 k:=i-1;
 while k>0 do
 begin
  ask:=ask-query(1,n,x,y,root[k]);
  k:=k-lowbit(k);
 end;
end;

begin
 assign(input,'bzoj3295.in'); reset(input);
 assign(output,'bzoj3295.out'); rewrite(output);
 readln(n,m);

 for i:=1 to n do
 begin
  read(a[i]);
  b[a[i]]:=i;
  a1[i]:=getsum(n)-getsum(a[i]);
  ans:=ans+a1[i];
  j:=a[i];
  while j<=n do
  begin
   inc(c[j]);
   j:=j+lowbit(j);
  end;
 end;

 fillchar(c,sizeof(c),0);
 for i:=n downto 1 do
 begin
  a2[i]:=getsum(a[i]-1);
  j:=a[i];
  while j<=n do
  begin
   inc(c[j]);
   j:=j+lowbit(j);
  end;
 end;

{ for i:=1 to n do write(a1[i],' ');
 writeln;
 for i:=1 to n do write(a2[i],' ');  }
 for i:=1 to m do
 begin
  readln(x);
  writeln(ans);
  j:=b[x];
  ans:=ans-(a1[j]+a2[j]-ask(1,j-1,x+1,n)-ask(j+1,n,1,x-1));
  change(j,x,1);
 end;


 close(input);
 close(output);
end.