【POJ1149&BZOJ1280】PIGS（最大流）

题意：Emmy在一个养猪场工作。这个养猪场有M个锁着的猪圈，但Emmy并没有钥匙。

顾客会到养猪场来买猪，一个接着一个。每一位顾客都会有一些猪圈的钥匙，他们会将这些猪圈打开并买走固定数目的猪。

所有顾客有的钥匙和他们需要买猪的数量在事先都告诉了Emmy，于是Emmy要订一个计划，使得卖出去的猪最多。

买卖的过程是这样的：一个顾客前来，并打开所有他可以打开的猪圈。

然后Emmy从这些猪圈里牵出固定数目的猪卖给顾客（最多只能和顾客需要数相等），并可以重新安排这些开着的猪圈中的猪。

每个猪圈可以存放任意数目的猪。 写一个程序，使得Emmy能够卖出去尽可能多的猪。

1 ≤ M ≤ 1000
1 ≤ N ≤ 100

思路：RYZ作业

考虑到如果有两个人拥有同一个猪圈的钥匙，则前一个人可以分配任意（不能超过他自己能拿到上限）数量的猪给后一个人

前一个人——>后一个人 OO

又发现他们之间不用全部两两连边，只需要按到来顺序，相邻连边

猪圈其实就是从源点出来的容量上限

源点——>某猪圈第一个人 a[i]

最后还有每个人购买的限制

每个人——>汇点 b[i]

也是网络流经典模型之一

var head,vet,next,len,dis,gap,fan:array[0..110000]of longint;
    a,last:array[1..10000]of longint;
    m,n,i,j,x,y,z,tot,s,source,src:longint;

procedure add(a,b,c:longint);
begin
 inc(tot);
 next[tot]:=head[a];
 vet[tot]:=b;
 len[tot]:=c;
 head[a]:=tot;

 inc(tot);
 next[tot]:=head[b];
 vet[tot]:=a;
 len[tot]:=0;
 head[b]:=tot;
end;

function min(x,y:longint):longint;
begin
 if x<y then exit(x);
 exit(y);
end;

function dfs(u,aug:longint):longint;
var e,v,t,flow,val:longint;
begin
 if u=src then exit(aug);
 e:=head[u]; flow:=0; val:=s-1;
 while e<>0 do
 begin
  v:=vet[e];
  if len[e]>0 then
  begin
   if dis[u]=dis[v]+1 then
   begin
    t:=dfs(v,min(len[e],aug-flow));
    len[e]:=len[e]-t;
    len[fan[e]]:=len[fan[e]]+t;
    flow:=flow+t;
    if dis[source]>=s then exit(flow);
    if aug=flow then break;
   end;
   val:=min(val,dis[v]);
  end;
  e:=next[e];
 end;
 if flow=0 then
 begin
  dec(gap[dis[u]]);
  if gap[dis[u]]=0 then dis[source]:=s;
  dis[u]:=val+1;
  inc(gap[dis[u]]);
 end;
 exit(flow);
end;

function maxflow:longint;
var ans:longint;
begin
 fillchar(gap,sizeof(gap),0);
 fillchar(dis,sizeof(dis),0);
 gap[0]:=s; ans:=0;
 while dis[source]<s do ans:=ans+dfs(source,maxlongint);
 exit(ans);
end;

begin
 assign(input,'bzoj1280.in'); reset(input);
 assign(output,'bzoj1280.out'); rewrite(output);
 readln(m,n);
 for i:=1 to m do read(a[i]);
 for i:=1 to 110000 do
  if i and 1=1 then fan[i]:=i+1
   else fan[i]:=i-1;
 source:=n+1; src:=n+2; s:=n+2;
 for i:=1 to n do
 begin
  read(x);
  for j:=1 to x do
  begin
   read(y);
   if last[y]=0 then
   begin
    add(source,i,a[y]);
    last[y]:=i;
   end
    else
    begin
     add(last[y],i,maxlongint);
     last[y]:=i;
    end;
  end;
  read(z);
  add(i,src,z);
 end;
 writeln(maxflow);
 close(input);
 close(output);
end.