【POJ3680】Intervals（费用流）

题意：有n条线段，每条有起点，终点和一个权值

要求选取一些线段，使它们的权值和最大，并且使每一个点被覆盖不超过k次

1 ≤ K ≤ N ≤ 200

1 ≤ a_i < b_i ≤ 100,000, 1 ≤ w_i ≤ 100,000

思路：RYZ作业

费用流（经典？）模型之一

离散化后对于线段(a[i],b[i],w[i])，从a[i]到b[i]连容量为1,费用为w[i]的边

(i,i+1)之间都连容量为K，费用为0的边，以达到限制max<=k的效果

S——>1和N——>T之间都连容量为K，费用为0的边

跑最大费用最大流

var head,vet,next,len1,len2,a,b,c,d,fan:array[1..100000]of longint;
    inq:array[1..30000]of boolean;
    q:array[0..30000]of longint;
    pre:array[1..30000,1..2]of longint;
    dis:array[1..30000]of longint;
    n,m,k,up,i,tot,ans,s,source,src,cas,v,x,y:longint;

procedure swap(var x,y:longint);
var t:longint;
begin
 t:=x; x:=y; y:=t;
end;

procedure qsort(l,r:longint);
var i,j,mid:longint;
begin
 i:=l; j:=r; mid:=d[(l+r)>>1];
 repeat
  while mid>d[i] do inc(i);
  while mid<d[j] do dec(j);
  if i<=j then
  begin
   swap(d[i],d[j]);
   inc(i); dec(j);
  end;
 until i>j;
 if l<j then qsort(l,j);
 if i<r then qsort(i,r);
end;

function min(x,y:longint):longint;
begin
 if x<y then exit(x);
 exit(y);
end;

function hash(x:longint):longint;
var l,r,mid:longint;
begin
 l:=1; r:=up;
 while l<=r do
 begin
  mid:=(l+r)>>1;
  if d[mid]=x then exit(mid);
  if d[mid]<x then l:=mid+1
   else r:=mid-1;
 end;
end;

procedure add(a,b,c,d:longint);
begin
 inc(tot);
 next[tot]:=head[a];
 vet[tot]:=b;
 len1[tot]:=c;
 len2[tot]:=d;
 head[a]:=tot;

 inc(tot);
 next[tot]:=head[b];
 vet[tot]:=a;
 len1[tot]:=0;
 len2[tot]:=-d;
 head[b]:=tot;
end;

function spfa:boolean;
var u,e,v,i,top:longint;
begin
 for i:=1 to s do
 begin
  dis[i]:=-(maxlongint>>1);
  inq[i]:=false;
 end;
 top:=1; q[1]:=source; dis[source]:=0; inq[source]:=true;
 while top>0 do
 begin
  u:=q[top]; dec(top); inq[u]:=false;
  e:=head[u];
  while e<>0 do
  begin
   v:=vet[e];
   if (len1[e]>0)and(dis[u]+len2[e]>dis[v]) then
   begin
    dis[v]:=dis[u]+len2[e];
    pre[v,1]:=u;
    pre[v,2]:=e;
    if not inq[v] then
    begin
     inc(top); q[top]:=v; inq[v]:=true;
    end;
   end;
   e:=next[e];
  end;
 end;
 if dis[src]=-(maxlongint>>1) then exit(false);
 exit(true);
end;

procedure mcf;
var k,e,t:longint;
begin
 k:=src; t:=maxlongint;
 while k<>source do
 begin
  t:=min(t,len1[pre[k,2]]);
  k:=pre[k,1];
 end;
 k:=src;
 while k<>source do
 begin
  e:=pre[k,2];
  len1[e]:=len1[e]-t;
  len1[fan[e]]:=len1[fan[e]]+t;
  ans:=ans+t*len2[e];
  k:=pre[k,1];
 end;
end;

begin
 assign(input,'poj3680.in'); reset(input);
 assign(output,'poj3680.out'); rewrite(output);
 readln(cas);
 for i:=1 to 100000 do
  if i and 1=1 then fan[i]:=i+1
   else fan[i]:=i-1;
 for v:=1 to cas do
 begin
  for i:=1 to s do head[i]:=0;
  s:=0; tot:=0; ans:=0;
  //fillchar(head,sizeof(head),0);
  read(n,k); m:=0;
  for i:=1 to n do
  begin
   read(a[i],b[i],c[i]);
   inc(m); d[m]:=a[i];
   inc(m); d[m]:=b[i];
  end;
  qsort(1,m);
  up:=1;
  for i:=2 to m do
   if d[i]<>d[up] then begin inc(up); d[up]:=d[i]; end;
  for i:=1 to n do
  begin
   x:=hash(a[i]); y:=hash(b[i]);
   add(x,y,1,c[i]);
  end;
  source:=up+1; src:=up+2; s:=up+2;
  add(source,1,k,0);
  add(up,src,k,0);
  for i:=1 to up-1 do add(i,i+1,k,0);
  while spfa do mcf;
  writeln(ans);
 end;
 close(input);
 close(output);
end.