【BZOJ3669】魔法森林（LCT）

题意：有一张无向图，每条边有两个权值。求选取一些边使1和n连通，且max(a[i])+max(b[i])最小

2<=n<=50,000

0<=m<=100,000

1<=ai ,bi<=50,000

思路：LCT模板

将a[i]排序，维护路径上b[i]的最大值

因为是无向图且连通情况不变，不用findroot检查是否连通，并查集即可

也许是OI生涯最后一次打LCT

var t:array[0..300000,0..1]of longint;
    rev,fa,mx,w,a,b,f,q,x,y:array[0..300000]of longint;
    n,m,i,j,u,v,ans,tmp,top:longint;

procedure swap(var x,y:longint);
var t:longint;
begin
 t:=x; x:=y; y:=t;
end;

function min(x,y:longint):longint;
begin
 if x<y then exit(x);
 exit(y);
end;

function isroot(x:longint):boolean;
begin
 if (t[fa[x],0]<>x)and(t[fa[x],1]<>x) then exit(true);
 exit(false);
end;

procedure pushup(p:longint);
var l,r:longint;
begin
 l:=t[p,0]; r:=t[p,1];
 mx[p]:=p;
 if w[mx[l]]>w[mx[p]] then mx[p]:=mx[l];
 if w[mx[r]]>w[mx[p]] then mx[p]:=mx[r];
end;

procedure pushdown(p:longint);
var l,r:longint;
begin
 l:=t[p,0]; r:=t[p,1];
 if rev[p]=1 then
 begin
  rev[p]:=0; rev[l]:=rev[l] xor 1; rev[r]:=rev[r] xor 1;
  swap(t[p,0],t[p,1]);
 end;
end;

procedure rotate(x:longint);
var y,z,l,r:longint;
begin
 y:=fa[x]; z:=fa[y];
 if t[y,0]=x then l:=0
  else l:=1;
 r:=l xor 1;
 if not isroot(y) then
 begin
  if t[z,0]=y then t[z,0]:=x
   else t[z,1]:=x;
 end;
 fa[x]:=z; fa[y]:=x; fa[t[x,r]]:=y;
 t[y,l]:=t[x,r]; t[x,r]:=y;
 pushup(y);
 pushup(x);
end;

procedure splay(x:longint);
var y,z,k:longint;
begin
 inc(top); q[top]:=x;
 k:=x;
 while not isroot(k) do
 begin
  inc(top); q[top]:=fa[k];
  k:=fa[k];
 end;
 while top>0 do
 begin
  pushdown(q[top]);
  dec(top);
 end;

 while not isroot(x) do
 begin
  y:=fa[x]; z:=fa[y];
  if not isroot(y) then
  begin
   if (t[y,0]=x)xor(t[z,0]=y) then rotate(x)
    else rotate(y);
  end;
  rotate(x);
 end;
end;

procedure access(x:longint);
var k:longint;
begin
 k:=0;
 while x>0 do
 begin
  splay(x); t[x,1]:=k; pushup(x);
  k:=x; x:=fa[x];
 end;
end;

procedure makeroot(x:longint);
begin
 access(x); splay(x); rev[x]:=rev[x] xor 1;
end;

procedure link(x,y:longint);
begin
 makeroot(x); fa[x]:=y;
end;

procedure split(x,y:longint);
begin
 makeroot(x); access(y); splay(y);
end;

procedure cut(x,y:longint);
begin
 makeroot(x); access(y); splay(y); t[y,0]:=0; fa[x]:=0;
 pushup(y);
end;

function query(x,y:longint):longint;
begin
 split(x,y);
 exit(mx[y]);
end;

procedure qsort(l,r:longint);
var i,j,mid:longint;
begin
 i:=l; j:=r; mid:=a[(l+r)>>1];
 repeat
  while mid>a[i] do inc(i);
  while mid<a[j] do dec(j);
  if i<=j then
  begin
   swap(a[i],a[j]);
   swap(b[i],b[j]);
   swap(x[i],x[j]);
   swap(y[i],y[j]);
   inc(i); dec(j);
  end;
 until i>j;
 if l<j then qsort(l,j);
 if i<r then qsort(i,r);
end;

function find(k:longint):longint;
begin
 if f[k]<>k then f[k]:=find(f[k]);
 exit(f[k]);
end;

begin
 assign(input,'bzoj3669.in'); reset(input);
 assign(output,'bzoj3669.out'); rewrite(output);
 readln(n,m);
 for i:=1 to n do f[i]:=i;
 for i:=1 to m do read(x[i],y[i],a[i],b[i]);
 qsort(1,m);
 ans:=maxlongint;

 for i:=1 to m do
 begin
  u:=x[i]; v:=y[i];
  if find(u)=find(v) then
  begin
   tmp:=query(u,v);
   if w[tmp]>b[i] then
   begin
    cut(tmp,x[tmp-n]);
    cut(tmp,y[tmp-n]);
   end
    else
    begin
     if find(1)=find(n) then
     begin
      tmp:=query(1,n);
      ans:=min(ans,w[tmp]+a[i]);
     end;
     continue;
    end;
  end
   else f[find(u)]:=find(v);
  w[i+n]:=b[i]; mx[i+n]:=i+n;
  link(u,i+n); link(v,i+n);
  if find(1)=find(n) then
  begin
   tmp:=query(1,n);
   ans:=min(ans,w[tmp]+a[i]);
  end;
 end;
 if ans=maxlongint then writeln(-1)
  else writeln(ans);
 close(input);
 close(output);
end.