【ZJOI2017 Round2练习&BZOJ4827】D1T3 gift（FFT）

题意：

思路：可以看出题目所要最小化的是这样一个形式：

拆出每一项之后发现会变化的项只有sigma a[i]*b[i+t]与c^2,c*(a[i]-b[i])

c可以在外层枚举，剩下的只有sigma a[i]*b[i+t] (i=0..n-1)

因为FFT只能解决simga a[i]*b[n-i]

所以我们可以把a翻转，这样就化成了如上的形式

c[n+t+1]=a[n-i+1]*b[i+t] (i=0..n-1)

取出最小（大）的c[i]，与外层枚举的c共同求出答案，取最小值

FFT模板，值得一背

type cp=record
         x,y:extended;
        end;
     arr=array[0..510000]of cp;
var c,d,cur:arr;
    a,b:array[0..510000]of longint;
    n,i,m:longint;
    ans,sum,s1,s2:int64;

procedure swap(var x,y:cp);
var t:cp;
begin
 t:=x; x:=y; y:=t;
end;

function jia(a,b:cp;f:longint):cp;
begin
 if f=-1 then
 begin
  b.x:=-b.x; b.y:=-b.y;
 end;
 jia.x:=a.x+b.x;
 jia.y:=a.y+b.y;
end;

function mult(a,b:cp):cp;
begin
 mult.x:=a.x*b.x-a.y*b.y;
 mult.y:=a.x*b.y+a.y*b.x;
end;

function min(x,y:int64):int64;
begin
 if x<y then exit(x);
 exit(y);
end;

function max(x,y:int64):int64;
begin
 if x>y then exit(x);
 exit(y);
end;

procedure fft(var a:arr;n,f:longint);
var i,j,k,m:longint;
    w,u,v:cp;
begin
 i:=n>>1; j:=1;
 while j<n do
 begin
  if i<j then swap(a[i],a[j]);
  k:=n>>1;
  while k and i>0 do
  begin
   i:=i xor k;
   k:=k>>1;
  end;
  i:=i xor k;
  inc(j);
 end;
 m:=2;
 while m<=n do
 begin
  w.x:=cos(2*pi*f/m); w.y:=sin(2*pi*f/m);
  cur[0].x:=1; cur[0].y:=0;
  for i:=1 to m-1 do cur[i]:=mult(cur[i-1],w);
  i:=0;
  while i<n do
  begin
   j:=i;
   while j<i+(m>>1) do
   begin
    u:=a[j]; v:=mult(a[j+(m>>1)],cur[j-i]);
    a[j]:=jia(u,v,1);
    a[j+(m>>1)]:=jia(u,v,-1);
    inc(j);
   end;
   i:=i+m;
  end;
  m:=m<<1;
 end;
end;

procedure solve;
var i,j,len:longint;
begin
 for i:=0 to n-1 do c[i].x:=a[i];
 for i:=0 to n-1 do d[i].x:=b[i];
 i:=0; j:=n-1;
 while i<=j do
 begin
  swap(d[i],d[j]);
  inc(i); dec(j);
 end;
 len:=1;
 while len<=n+n do len:=len<<1;
 for i:=n to len-1 do
 begin
  c[i].x:=0; d[i].x:=0;
 end;
 for i:=0 to len-1 do
 begin
  c[i].y:=0; d[i].y:=0;
 end;
 fft(c,len,1);
 fft(d,len,1);
 for i:=0 to len-1 do c[i]:=mult(c[i],d[i]);
 fft(c,len,-1);
 for i:=0 to len-1 do c[i].x:=trunc(c[i].x/len+0.5);
 for i:=n to len-1 do c[i mod n].x:=c[i mod n].x+c[i].x;
 sum:=-(1<<62);
 for i:=0 to n-1 do sum:=max(sum,round(c[i].x));
 sum:=-sum*2;
end;

begin
 assign(input,'bzoj4827.in'); reset(input);
 assign(output,'bzoj4827.out'); rewrite(output);
 readln(n,m);
 for i:=0 to n-1 do read(a[i]);
 for i:=0 to n-1 do read(b[i]);
 ans:=1<<62;
 solve;
 for i:=0 to n-1 do
 begin
  s1:=s1+a[i]-b[i];
  s2:=s2+a[i]*a[i]+b[i]*b[i];
 end;
 for i:=-m to m do ans:=min(ans,int64(n)*i*i+2*s1*i+s2+sum);
 writeln(ans);
 close(input);
 close(output);
end.