HNOI2008 玩具装箱

1D1D动态规划，方程很容易写出来，

f[i]=min{f[j]+(i-(j+1)+s[i]-s[j]-l)^2} 红色的地方要注意，因为j已经装进去了，所以是从j+1到i。

通过函数性质，方程满足决策单调性，可以用二分法降到nlogn

注意要用int64

program hnoi2008_toy(input,output);
type
   node    = record
         x,y,pos : longint;
      end;         
var
   f   : array[0..55000] of int64;
   q   : array[0..55000] of node;
   n,l : longint;
   c   : array[-1..55000] of int64;
function calc(xx,yy: longint ):int64;
begin
   calc:=sqr(xx-(yy+1)+(c[xx]-c[yy])-l)+f[yy];
end; { calc }
procedure init;
var
   i : longint;
begin
   readln(n,l);
   fillchar(c,sizeof(c),0);
   for i:=1 to n do
   begin
      readln(c[i]);
      inc(c[i],c[i-1]);
   end;
end; { init }
procedure main;
var
   head,tail : longint;
   ll,rr,mid : longint;
   i         : longint;
begin
   fillchar(f,sizeof(f),63);
   f[0]:=0;
   head:=1;
   tail:=1;
   q[1].x:=1; q[1].y:=n; q[1].pos:=0;

   for i:=1 to n do
   begin
      f[i]:=calc(i,q[head].pos);
      inc(q[head].x);
      if q[head].x>q[head].y then
     inc(head);

      while (head<=tail)and(calc(q[tail].x,q[tail].pos)>calc(q[tail].x,i)) do
     dec(tail);
      if head>tail then
      begin
     inc(tail);
     q[tail].x:=i+1;
     q[tail].y:=n;
     q[tail].pos:=i;
     continue;
      end;

      ll:=q[tail].x;
      rr:=q[tail].y+1;
      while ll+1<rr do
      begin
     mid:=(ll+rr)>>1;
     if calc(mid,i)<calc(mid,q[tail].pos) then
        rr:=mid
     else
        ll:=mid;
      end;
      if rr=n+1 then
     continue;
      q[tail].y:=ll;
      inc(tail);
      q[tail].x:=rr;
      q[tail].y:=n;
      q[tail].pos:=i;
   end;
   writeln(f[n]);
end; { main }
begin
   init;
   main;
end.

最近学了斜率优化，O(n)算法放在这里了

program toys(input,output);
var
    q               :array[0..60000] of longint;
    f,g,s,w         :array[0..60000] of int64;
    n,l             :longint;
procedure init;
var
    i:longint;
begin
    readln(n,l);
    for i:=1 to n do
    begin
        readln(s[i]);
        s[i]:=s[i]+s[i-1]+1;
    end;
end;{ init }
function K(x,y:longint):double;
begin
    exit(double(g[x]-g[y])/double(w[x]-w[y]));
end;{ K }
procedure main;
var
    i        :longint;
    head,tail:longint;
    bestk    :double;
begin
    head:=1;
    tail:=1;
    q[1]:=0;
    f[0]:=0;
    for i:=1 to n do
    begin
        bestk:=double(s[i]);
        while (tail>head)and(K(q[head],q[head+1])<=bestk) do
            inc(head);
        f[i]:=int64(f[q[head]])+int64(s[i]-s[q[head]]-l-1)*int64(s[i]-s[q[head]]-l-1);
        w[i]:=2*s[i];
        g[i]:=f[i]+2*(l+1)*s[i]+s[i]*s[i];
        while (tail>head)and(K(q[tail-1],q[tail])>K(q[tail],i)) do
            dec(tail);
        inc(tail);
        q[tail]:=i;
    end;
end;{ main }
procedure print;
begin
    writeln(f[n]);
end;{ print }
begin
    init;
    main;
    print;
end.