大数分解模板

program j01;
const times=50;
var n:int64;
    fac:array[0..6000]of int64;
    num:array[0..6000]of record w,m:int64;end;
    ans:int64;
    i,cnt,top:longint;
 
procedure sort(l,r:longint);
var i,j:longint;x,y:int64;
begin
  i:=l;j:=r;x:=fac[(i+j)div 2];
  repeat
    while fac[i]<x do inc(i);
    while x<fac[j] do dec(j);
    if i<=j then
    begin
      y:=fac[i];fac[i]:=fac[j];fac[j]:=y;
      inc(i);dec(j);
    end;
  until i>j;
  if i<r then sort(i,r);
  if l<j then sort(l,j);
end;
 
function mul(a,b,mo:int64):int64;
begin
  mul:=0;
  while b>0 do
  begin
    if b and 1=1 then mul:=(mul+a)mod mo;
    b:=b>>1;a:=(a+a)mod mo;
  end;
end;
 
function pow(a,i,mo:int64):int64;
begin
  pow:=1;
  while i>0 do
  begin
    if i and 1=1 then pow:=mul(pow,a,mo);
    i:=i>>1;a:=mul(a,a,mo);
  end;
end;
 
function miller_rabin(n:int64):boolean;
var i,j:longint;a,x,y,m,k:int64;
begin
  if n=2 then exit(true);
  m:=n-1;k:=0;
  while m and 1=0 do
  begin
    m:=m>>1;inc(k);
  end;
  for i:=1 to times do
  begin
    a:=random(n-1)+1;
    x:=pow(a,m,n);y:=0;
    for j:=1 to k do
    begin
      y:=mul(x,x,n);
      if(y=1)and(x<>1)and(x<>n-1)then exit(false);
      x:=y;
    end;
    if y<>1 then exit(false);
  end;
  exit(true);
end;
 
function gcd(a,b:int64):int64;
begin
  if b=0 then exit(a) else exit(gcd(b,a mod b));
end;
 
function rho(n,c:int64):int64;
var i,k,x,y,tmp,d:int64;
begin
  i:=1;k:=2;
  x:=random(n-1)+1;y:=x;
  while true do
  begin
    inc(i);
    x:=(mul(x,x,n)+c)mod n;
    tmp:=(y-x+n)mod n;
    d:=gcd(tmp,n);
    if(d>1)and(d<n)then exit(d);
    if y=x then exit(n);
    if i=k then
    begin
      k:=k+k;y:=x;
    end;
  end;
end;
 
procedure find(n:int64);
var p:int64;
begin
  if n=1 then exit;
  if miller_rabin(n) then
  begin
    inc(cnt);fac[cnt]:=n;exit;
  end;
  p:=n;
  while p>=n do p:=rho(p,random(n-1)+1);
  find(p);find(n div p);
end;
 
begin
  readln(n);
  if n=1 then begin writeln(1);halt;end; 
  find(n);
  sort(1,cnt);
  top:=1;num[top].w:=fac[1];num[top].m:=1;
  for i:=2 to cnt do
    if fac[i]=fac[i-1] then inc(num[top].m) else
    begin
      inc(top);num[top].w:=fac[i];num[top].m:=1;
    end;
  for i:=1 to top do writeln(num[i].w,' ',num[i].m);
end.